0 BEGIN PGM 10005_NL MM 
1 ;Frees-draaiwerkstuk
2 ;
3 ;Definitie onbewerkt werkstuk als cilinder
4 BLK FORM CYLINDER Z R60 L100 DIST+1
5 ;
6 ;Referentiepunt activeren
7 CYCL DEF 247 BEZUGSPUNKT SETZEN ~
   Q339=+2    ;BEZUGSPUNKT-NUMMER
8 ;
9 ;Draaibewerking buiten voorbewerken
10 ;Gereedschapsoproep draaigereedschap voorbewerken
11 TOOL CALL "TURN_ROUGH"
12 ;
13 ;Oproep subprogramma draaimodus
14 CALL LBL "TURN"
15 ;Oproep subprogramma Veilige positie benaderen
16 CALL LBL "SAFE"
17 ;
18 ;Draaisysteem aanpassen
19 CYCL DEF 800 KOORD.-SYST.ANPASSEN ~
   Q497=+0    ;PRAEZESSIONSWINKEL ~
    Q498=+0    ;WERKZEUG UMKEHREN ~
    Q530=+0    ;ANGESTELLTE BEARB. ~
    Q531=+0    ;ANSTELLWINKEL ~
    Q532=+750  ;VORSCHUB ~
    Q533=+0    ;VORZUGSRICHTUNG ~
    Q535=+3    ;EXZENTERDREHEN ~
    Q536=+0    ;EXZENTR. OHNE STOPP
20 ;
21 ;Constante snijsnelheid en maximaal toerental definiëren
22 FUNCTION TURNDATA SPIN VCONST:ON VC:400 SMAX800
23 ;
24 ;Zwenkas naar nul verplaatsen en draaispil
25 ;inschakelen
26 L  A+0 R0 FMAX M303
27 ;
28 ;Overdwars draaien
29 CYCL DEF 821 ABSATZ PLAN ~
   Q215=+0    ;BEARBEITUNGS-UMFANG ~
    Q460=+2    ;SICHERHEITS-ABSTAND ~
    Q493=+0    ;KONTURENDE DURCHMESSER ~
    Q494=+0    ;KONTURENDE Z ~
    Q463=+3    ;MAX. SCHNITTTIEFE ~
    Q478=+0.3  ;VORSCHUB SCHRUPPEN ~
    Q483=+0    ;AUFMASS DURCHMESSER ~
    Q484=+0.2  ;AUFMASS Z ~
    Q505=+0.2  ;VORSCHUB SCHLICHTEN ~
    Q506=+0    ;KONTURGLAETTUNG
30 L  X+122  Y+0 R0 FMAX ;Voorpositioneren
31 L  Z+10 R0 FMAX ;Voorpositioneren
32 L  Z+2 R0 F0.5 M99 ;Starthoogte benaderen en cyclusoproep
33 ;
34 ;Overlangs draaien
35 CYCL DEF 811 ABSATZ LAENGS ~
   Q215=+0    ;BEARBEITUNGS-UMFANG ~
    Q460=+2    ;SICHERHEITS-ABSTAND ~
    Q493=+117  ;KONTURENDE DURCHMESSER ~
    Q494=-80   ;KONTURENDE Z ~
    Q463=+3    ;MAX. SCHNITTTIEFE ~
    Q478=+0.3  ;VORSCHUB SCHRUPPEN ~
    Q483=+0.2  ;AUFMASS DURCHMESSER ~
    Q484=+0    ;AUFMASS Z ~
    Q505=+0.2  ;VORSCHUB SCHLICHTEN ~
    Q506=+0    ;KONTURGLAETTUNG
36 L  X+122  Y+0 R0 FMAX ;Voorpositioneren
37 L  Z+10 R0 FMAX ;Voorpositioneren
38 L  Z+2 R0 F0.5 M99 ;Starthoogte benaderen en cyclusoproep
39 ;
40 ;Astap draaien
41 CYCL DEF 811 ABSATZ LAENGS ~
   Q215=+0    ;BEARBEITUNGS-UMFANG ~
    Q460=+2    ;SICHERHEITS-ABSTAND ~
    Q493=+100  ;KONTURENDE DURCHMESSER ~
    Q494=-20   ;KONTURENDE Z ~
    Q463=+3    ;MAX. SCHNITTTIEFE ~
    Q478=+0.3  ;VORSCHUB SCHRUPPEN ~
    Q483=+0.2  ;AUFMASS DURCHMESSER ~
    Q484=+0    ;AUFMASS Z ~
    Q505=+0.2  ;VORSCHUB SCHLICHTEN ~
    Q506=+0    ;KONTURGLAETTUNG
42 L  X+119  Y+0 R0 FMAX ;Voorpositioneren
43 L  Z+10 R0 FMAX ;Voorpositioneren
44 L  Z+2 R0 F0.5 M99 ;Starthoogte benaderen en cyclusoproep
45 ;
46 ;Gereedschapsoproep steekdraaigereedschap axiaal
47 TOOL CALL "TURN_REC_AX_100-150"
48 ;
49 ;Oproep subprogramma draaimodus
50 CALL LBL "TURN"
51 ;Oproep subprogramma Veilige positie benaderen
52 CALL LBL "SAFE"
53 ;
54 ;Draaisysteem aanpassen
55 CYCL DEF 800 KOORD.-SYST.ANPASSEN ~
   Q497=+0    ;PRAEZESSIONSWINKEL ~
    Q498=+0    ;WERKZEUG UMKEHREN ~
    Q530=+0    ;ANGESTELLTE BEARB. ~
    Q531=+0    ;ANSTELLWINKEL ~
    Q532=+750  ;VORSCHUB ~
    Q533=+0    ;VORZUGSRICHTUNG ~
    Q535=+3    ;EXZENTERDREHEN ~
    Q536=+0    ;EXZENTR. OHNE STOPP
56 ;
57 ;Constante snijsnelheid en maximaal
58 ;toerental definiëren
59 FUNCTION TURNDATA SPIN VCONST:ON VC:400 SMAX800
60 ;
61 ;Zwenkas naar nul verplaatsen en
62 ;draaispil inschakelen
63 L  A+0 R0 FMAX M303
64 ;
65 ;Axiale insteek
66 CYCL DEF 852 STECHDR. ERW. AXIAL ~
   Q215=+0    ;BEARBEITUNGS-UMFANG ~
    Q460=+2    ;SICHERHEITS-ABSTAND ~
    Q491=+85   ;KONTURSTART DURCHMESSER ~
    Q492=+0    ;KONTURSTART Z ~
    Q493=+50   ;KONTURENDE DURCHMESSER ~
    Q494=-5    ;KONTURENDE Z ~
    Q495=+0    ;WINKEL FLANKE ~
    Q501=+1    ;TYP ANFANGSELEMENT ~
    Q502=+0.5  ;GROESSE ANFANGSELEMENT ~
    Q500=+0.5  ;RADIUS KONTURECKE ~
    Q496=+0    ;WINKEL ZWEITE FLANKE ~
    Q503=+1    ;TYP ENDELEMENT ~
    Q504=+0.5  ;GROESSE ENDELEMENT ~
    Q478=+0.3  ;VORSCHUB SCHRUPPEN ~
    Q483=+0.4  ;AUFMASS DURCHMESSER ~
    Q484=+0.2  ;AUFMASS Z ~
    Q505=+0.2  ;VORSCHUB SCHLICHTEN ~
    Q463=+3    ;MAX. SCHNITTTIEFE ~
    Q507=+0    ;BEARBEITUNGSRICHTUNG ~
    Q508=+0    ;VERSATZBREITE ~
    Q509=+0    ;TIEFENKORREKTUR
67 L  X+85  Y+0 R0 FMAX ;Voorpositioneren
68 L  Z+10 R0 FMAX ;Voorpositioneren
69 L  Z+2 R0 F0.5 M99 ;Starthoogte benaderen en cyclusoproep
70 ;
71 ;Draaibewerking radiale insteek
72 ;Gereedschapsoproep steekdraaigereedschap radiaal
73 TOOL CALL "TURN_REC_RAD"
74 ;
75 ;Oproep subprogramma draaimodus
76 CALL LBL "TURN"
77 ;Oproep subprogramma Veilige positie benaderen
78 CALL LBL "SAFE"
79 ;
80 ;Draaisysteem aanpassen
81 CYCL DEF 800 KOORD.-SYST.ANPASSEN ~
   Q497=+0    ;PRAEZESSIONSWINKEL ~
    Q498=+0    ;WERKZEUG UMKEHREN ~
    Q530=+0    ;ANGESTELLTE BEARB. ~
    Q531=+0    ;ANSTELLWINKEL ~
    Q532=+750  ;VORSCHUB ~
    Q533=+0    ;VORZUGSRICHTUNG ~
    Q535=+3    ;EXZENTERDREHEN ~
    Q536=+0    ;EXZENTR. OHNE STOPP
82 ;
83 ;Constante snijsnelheid en maximaal
84 ;toerental definiëren
85 FUNCTION TURNDATA SPIN VCONST:ON VC:400 SMAX800
86 ;
87 ;Zwenkas naar nul verplaatsen en draaispil
88 ;inschakelen
89 L  A+0 R0 FMAX M303
90 ;
91 ;Contour roteren
92 CYCL DEF 14.0 KONTUR
93 CYCL DEF 14.1 KONTURLABEL1
94 CYCL DEF 840 STECHDR. KONT. RAD. ~
   Q215=+0    ;BEARBEITUNGS-UMFANG ~
    Q460=+2    ;SICHERHEITS-ABSTAND ~
    Q478=+0.3  ;VORSCHUB SCHRUPPEN ~
    Q488=+0.1  ;VORSCHUB EINTAUCHEN ~
    Q483=+0.4  ;AUFMASS DURCHMESSER ~
    Q484=+0.2  ;AUFMASS Z ~
    Q505=+0.2  ;VORSCHUB SCHLICHTEN ~
    Q479=+0    ;SCHNITTBEGRENZUNG ~
    Q480=+0    ;GRENZWERT DURCHMESSER ~
    Q482=+0    ;GRENZWERT Z ~
    Q463=+3    ;MAX. SCHNITTTIEFE ~
    Q507=+0    ;BEARBEITUNGSRICHTUNG ~
    Q508=+0    ;VERSATZBREITE ~
    Q509=+0    ;TIEFENKORREKTUR ~
    Q499=+0    ;KONTUR UMKEHREN
95 L  X+119  Y+0 R0 FMAX ;Voorpositioneren
96 L  Z+10 R0 FMAX ;Voorpositioneren
97 L  Z+2 R0 F0.5 M99 ;Starthoogte benaderen en cyclusoproep
98 ;
99 ;Radiale insteek
100 CYCL DEF 841 STECHDR. EINFACH R. ~
    Q215=+0    ;BEARBEITUNGS-UMFANG ~
    Q460=+2    ;SICHERHEITS-ABSTAND ~
    Q493=+105  ;KONTURENDE DURCHMESSER ~
    Q494=-40   ;KONTURENDE Z ~
    Q478=+0.3  ;VORSCHUB SCHRUPPEN ~
    Q483=+0.4  ;AUFMASS DURCHMESSER ~
    Q484=+0.2  ;AUFMASS Z ~
    Q505=+0.2  ;VORSCHUB SCHLICHTEN ~
    Q463=+3    ;MAX. SCHNITTTIEFE ~
    Q507=+0    ;BEARBEITUNGSRICHTUNG ~
    Q508=+0    ;VERSATZBREITE ~
    Q509=+0    ;TIEFENKORREKTUR
101 L  X+119  Y+0 R0 FMAX ;Voorpositioneren
102 L  Z+10 R0 FMAX ;Voorpositioneren
103 L  Z-23 R0 F0.5 M99 ;Starthoogte benaderen en cyclusoproep
104 ;
105 ;Freesbewerking boring
106 ;Oproep subprogramma freesmodus
107 CALL LBL "MILL"
108 ;
109 ;Gereedschapsoproep schachtfrees
110 TOOL CALL "MILL_D20_ROUGH" Z S3000 F700
111 ;
112 L  X+0  Y+0  Z+100 R0 FMAX M3 ;Voorpositioneren
113 ;
114 ;Boring frezen
115 CYCL DEF 208 BOHRFRAESEN ~
    Q200=+2    ;SICHERHEITS-ABST. ~
    Q201=-60   ;TIEFE ~
    Q206=+500  ;VORSCHUB TIEFENZ. ~
    Q334=+2.5  ;ZUSTELL-TIEFE ~
    Q203=+0    ;KOOR. OBERFLAECHE ~
    Q204=+50   ;2. SICHERHEITS-ABST. ~
    Q335=+32   ;SOLL-DURCHMESSER ~
    Q342=+0    ;VORGEB. DURCHMESSER ~
    Q351=+1    ;FRAESART
116 M99 ;Cyclusoproep
117 ;
118 ;Oproep subprogramma Veilige positie benaderen
119 CALL LBL "SAFE"
120 ;
121 ;Draaibewerking binnen voorbewerken
122 ;Gereedschapsoproep draaigereedschap voorbewerken
123 TOOL CALL "TURN_ROUGH"
124 ;
125 ;Oproep subprogramma draaimodus
126 CALL LBL "TURN"
127 ;Oproep subprogramma Veilige positie benaderen
128 CALL LBL "SAFE"
129 ;
130 ;Draaisysteem aanpassen
131 CYCL DEF 800 KOORD.-SYST.ANPASSEN ~
    Q497=+0    ;PRAEZESSIONSWINKEL ~
    Q498=+1    ;WERKZEUG UMKEHREN ~
    Q530=+0    ;ANGESTELLTE BEARB. ~
    Q531=+0    ;ANSTELLWINKEL ~
    Q532=+750  ;VORSCHUB ~
    Q533=+0    ;VORZUGSRICHTUNG ~
    Q535=+3    ;EXZENTERDREHEN ~
    Q536=+0    ;EXZENTR. OHNE STOPP
132 ;
133 ;Constante snijsnelheid en maximaal
134 ;toerental definiëren
135 FUNCTION TURNDATA SPIN VCONST:ON VC:400 SMAX800
136 ;
137 ;Zwenkas naar nul verplaatsen en draaispil
138 ;inschakelen (M304, omdat gereedschap omgekeerd is)
139 L  A+0 R0 FMAX M304
140 ;
141 ;Uitsteeksel binnen draaien
142 CYCL DEF 821 ABSATZ PLAN ~
    Q215=+0    ;BEARBEITUNGS-UMFANG ~
    Q460=+2    ;SICHERHEITS-ABSTAND ~
    Q493=+84   ;KONTURENDE DURCHMESSER ~
    Q494=-5    ;KONTURENDE Z ~
    Q463=+3    ;MAX. SCHNITTTIEFE ~
    Q478=+0.3  ;VORSCHUB SCHRUPPEN ~
    Q483=+0.4  ;AUFMASS DURCHMESSER ~
    Q484=+0.2  ;AUFMASS Z ~
    Q505=+0.2  ;VORSCHUB SCHLICHTEN ~
    Q506=+0    ;KONTURGLAETTUNG
143 L  X+30  Y+0 R0 FMAX ;Voorpositioneren
144 L  Z+2 R0 FMAX M99 ;Startpositie benaderen en cyclusoproep
145 ;
146 ;Astap binnen draaien
147 CYCL DEF 822 ABSATZ PLAN ERW. ~
    Q215=+0    ;BEARBEITUNGS-UMFANG ~
    Q460=+2    ;SICHERHEITS-ABSTAND ~
    Q491=+32   ;KONTURSTART DURCHMESSER ~
    Q492=-5    ;KONTURSTART Z ~
    Q493=+75   ;KONTURENDE DURCHMESSER ~
    Q494=-40   ;KONTURENDE Z ~
    Q495=+0    ;WINKEL PLANFLAECHE ~
    Q501=+0    ;TYP ANFANGSELEMENT ~
    Q502=+1    ;GROESSE ANFANGSELEMENT ~
    Q500=+1    ;RADIUS KONTURECKE ~
    Q496=+0    ;WINKEL UMFANGSFLAECHE ~
    Q503=+2    ;TYP ENDELEMENT ~
    Q504=+1    ;GROESSE ENDELEMENT ~
    Q463=+3    ;MAX. SCHNITTTIEFE ~
    Q478=+0.3  ;VORSCHUB SCHRUPPEN ~
    Q483=+0.4  ;AUFMASS DURCHMESSER ~
    Q484=+0.2  ;AUFMASS Z ~
    Q505=+0.2  ;VORSCHUB SCHLICHTEN ~
    Q506=+0    ;KONTURGLAETTUNG
148 L  X+30  Y+0 R0 FMAX ;Voorpositioneren
149 L  Z-3 R0 FMAX M99 ;Startpositie benaderen en cyclusoproep
150 L  Z+10 R0 FMAX ;Vrijzetten
151 ;
152 ;Oproep subprogramma Veilige positie benaderen
153 CALL LBL "SAFE"
154 ;
155 ;Draaibewerking buiten nabewerken
156 ;Gereedschapsoproep draaigereedschap nabewerken
157 TOOL CALL "TURN_FINISH"
158 ;
159 ;Oproep subprogramma draaimodus
160 CALL LBL "TURN"
161 ;
162 ;Activeren van de correctie van het onbewerkte werkstuk
163 ;Onbewerkt werkstuk gedefinieerd in subprogramma Blank
164 FUNCTION TURNDATA BLANK LBL "Blank"
165 ;
166 ;Draaisysteem aanpassen
167 ;Gereedschap wordt schuin ingesteld, omdat een
168 ;insteek wordt gemaakt
169 CYCL DEF 800 KOORD.-SYST.ANPASSEN ~
    Q497=+90   ;PRAEZESSIONSWINKEL ~
    Q498=+0    ;WERKZEUG UMKEHREN ~
    Q530=+2    ;ANGESTELLTE BEARB. ~
    Q531=+30   ;ANSTELLWINKEL ~
    Q532=+750  ;VORSCHUB ~
    Q533=-1    ;VORZUGSRICHTUNG ~
    Q535=+3    ;EXZENTERDREHEN ~
    Q536=+0    ;EXZENTR. OHNE STOPP
170 ;
171 ;Constante snijsnelheid en maximaal
172 ;toerental definiëren
173 FUNCTION TURNDATA SPIN VCONST:ON VC:500 S800
174 ;
175 M303
176 ;Contour nabewerken
177 CYCL DEF 14.0 KONTUR
178 CYCL DEF 14.1 KONTURLABEL3
179 CYCL DEF 810 DREHEN KONTUR LAENGS ~
    Q215=+0    ;BEARBEITUNGS-UMFANG ~
    Q460=+2    ;SICHERHEITS-ABSTAND ~
    Q499=+0    ;KONTUR UMKEHREN ~
    Q463=+3    ;MAX. SCHNITTTIEFE ~
    Q478=+0.3  ;VORSCHUB SCHRUPPEN ~
    Q483=+0.1  ;AUFMASS DURCHMESSER ~
    Q484=+0.1  ;AUFMASS Z ~
    Q505=+0.2  ;VORSCHUB SCHLICHTEN ~
    Q487=+1    ;EINTAUCHEN ~
    Q488=+0    ;VORSCHUB EINTAUCHEN ~
    Q479=+0    ;SCHNITTBEGRENZUNG ~
    Q480=+0    ;GRENZWERT DURCHMESSER ~
    Q482=+0    ;GRENZWERT Z ~
    Q506=+0    ;KONTURGLAETTUNG
180 M99 ;Cyclusoproep
181 ;
182 ;Draaibewerking schroefdraad draaien
183 ;Gereedschapsoproep draadsnijfrees
184 TOOL CALL "TURN_THREAD"
185 ;
186 ;Oproep subprogramma draaimodus
187 CALL LBL "TURN"
188 ;
189 ;Oproep subprogramma Veilige positie benaderen
190 CALL LBL "SAFE"
191 ;
192 ;Draaisysteem aanpassen
193 CYCL DEF 800 KOORD.-SYST.ANPASSEN ~
    Q497=+0    ;PRAEZESSIONSWINKEL ~
    Q498=+0    ;WERKZEUG UMKEHREN ~
    Q530=+0    ;ANGESTELLTE BEARB. ~
    Q531=+0    ;ANSTELLWINKEL ~
    Q532=+750  ;VORSCHUB ~
    Q533=+0    ;VORZUGSRICHTUNG ~
    Q535=+3    ;EXZENTERDREHEN ~
    Q536=+0    ;EXZENTR. OHNE STOPP
194 ;
195 ;Constante snijsnelheid en maximaal
196 ;toerental definiëren
197 FUNCTION TURNDATA SPIN VCONST:ON VC:300 SMAX800
198 ;
199 ;Zwenkas naar nul verplaatsen en draaispil
200 ;inschakelen
201 L  A+0 R0 FMAX M304
202 ;
203 ;Schroefdraad draaien
204 CYCL DEF 831 GEWINDE LAENGS ~
    Q471=+0    ;GEWINDELAGE ~
    Q460=+2    ;SICHERHEITS-ABSTAND ~
    Q491=+95   ;GEWINDEDURCHMESSER ~
    Q472=+1.5  ;GEWINDESTEIGUNG ~
    Q473=+0    ;GEWINDETIEFE ~
    Q492=+0    ;KONTURSTART Z ~
    Q494=-20   ;KONTURENDE Z ~
    Q474=+0    ;GEWINDEAUSLAUF ~
    Q463=+0.3  ;MAX. SCHNITTTIEFE ~
    Q467=+0    ;ZUSTELLWINKEL ~
    Q468=+1    ;ZUSTELLART ~
    Q470=+0    ;STARTWINKEL ~
    Q475=+1    ;GANGANZAHL ~
    Q476=+2    ;ANZAHL LEERSCHNITTE
205 L  X+98  Y+0 R0 FMAX ;Voorpositioneren
206 L  Z+2 R0 FMAX ;Startpositie benaderen
207 M99 ;Cyclusoproep
208 ;
209 ;Draaibewerking radiale insteek
210 ;Gereedschapsoproep steekdraaigereedschap radiaal
211 TOOL CALL "TURN_REC_RAD"
212 ;
213 ;Oproep subprogramma draaimodus
214 CALL LBL "TURN"
215 ;Oproep subprogramma Veilige positie benaderen
216 CALL LBL "SAFE"
217 ;
218 ;Draaisysteem aanpassen
219 CYCL DEF 800 KOORD.-SYST.ANPASSEN ~
    Q497=+0    ;PRAEZESSIONSWINKEL ~
    Q498=+0    ;WERKZEUG UMKEHREN ~
    Q530=+0    ;ANGESTELLTE BEARB. ~
    Q531=+0    ;ANSTELLWINKEL ~
    Q532=+750  ;VORSCHUB ~
    Q533=+0    ;VORZUGSRICHTUNG ~
    Q535=+3    ;EXZENTERDREHEN ~
    Q536=+0    ;EXZENTR. OHNE STOPP
220 ;
221 ;Constante snijsnelheid en maximaal
222 ;toerental definiëren
223 FUNCTION TURNDATA SPIN VCONST:ON VC:400 SMAX800
224 ;
225 ;Zwenkas naar nul verplaatsen en draaispil
226 ;inschakelen
227 L  A+0 R0 FMAX M303
228 ;
229 ;Draaibewerking insteek radiaal
230 ;Contour draaien
231 CYCL DEF 14.0 KONTUR
232 CYCL DEF 14.1 KONTURLABEL4
233 CYCL DEF 840 STECHDR. KONT. RAD. ~
    Q215=+0    ;BEARBEITUNGS-UMFANG ~
    Q460=+2    ;SICHERHEITS-ABSTAND ~
    Q478=+0.3  ;VORSCHUB SCHRUPPEN ~
    Q488=+0.1  ;VORSCHUB EINTAUCHEN ~
    Q483=+0.4  ;AUFMASS DURCHMESSER ~
    Q484=+0.2  ;AUFMASS Z ~
    Q505=+0.2  ;VORSCHUB SCHLICHTEN ~
    Q479=+0    ;SCHNITTBEGRENZUNG ~
    Q480=+0    ;GRENZWERT DURCHMESSER ~
    Q482=+0    ;GRENZWERT Z ~
    Q463=+3    ;MAX. SCHNITTTIEFE ~
    Q507=+0    ;BEARBEITUNGSRICHTUNG ~
    Q508=+0    ;VERSATZBREITE ~
    Q509=+0    ;TIEFENKORREKTUR ~
    Q499=+0    ;KONTUR UMKEHREN
234 L  X+119  Y+0 R0 FMAX ;Voorpositioneren
235 L  Z+10 R0 FMAX ;Voorpositioneren
236 L  Z+2 R0 F0.5 M99 ;Startpositie benaderen en cyclus oproepen
237 ;
238 ;Oproep subprogramma freesmodus
239 CALL LBL "MILL"
240 ;Oproep subprogramma Veilige positie benaderen
241 CALL LBL "SAFE"
242 ;Einde programma
243 M30
244 ;
245 ;Subprogramma Draaimodus
246 LBL "TURN"
247 M140 MB MAX ;Vrijzetten
248 M145 ;Kinematicaberekening opheffen
249 FUNCTION MODE TURN ;Draaimodus activeren
250 M144 ;Kinematicaberekening activeren
251 M136 ;Aanzet omschakelen op mm per omwenteling
252 LBL 0
253 ;
254 ;Subprogramma freesmodus
255 LBL "MILL"
256 M140 MB MAX ;Vrijzetten
257 M145 ;Kinematicaberekening opheffen
258 FUNCTION MODE MILL ;Freesmodus activeren
259 M137 ;Aanzet omschakelen op mm per min
260 ;Subprogramma-oproep Veilige positie benaderen
261 CALL LBL "SAFE"
262 L  C+0  A+0 R0 FMAX ;Zwenkassen naar nul verplaatsen
263 LBL 0
264 ;
265 ;Subprogramma Veilige positie benaderen
266 LBL "SAFE"
267 L  X+400  Y+400 R0 FMAX M91 ;Veilige positie !afhankelijk van machine!
268 LBL 0
269 ;
270 ;Contour voor correctie van het onbewerkte werkstuk
271 LBL "Blank"
272 L  Z+0  X+0
273 L  Z+0  X+100
274 L  Z-20  X+100
275 L  Z-20  X+116.9997
276 L  Z-23  X+117
277 L  Z-23  X+105
278 L  Z-40  X+105
279 L  Z-40  X+116.9997
280 L  Z-43  X+117
281 L  Z-43  X+100
282 L  Z-56.9063  X+100
283 L  Z-56.9063  X+0
284 L  Z-60  X+117
285 L  Z-60  X+0
286 L  Z-80  X+117
287 L  Z-80  X+119.9997
288 L  Z-100  X+120
289 L  Z-100  X+0
290 L  Z+0
291 LBL 0
292 ;
293 ;Kontur1
294 LBL 1
295 L  X+117  Z-43 RL
296 L  X+100
297 L  Z-56.9063
298 L  X+117  Z-60
299 LBL 0
300 ;
301 ;Kontur3
302 LBL 3
303 L  X+90  Z+0
304 L  X+95
305 RND R2
306 L  Z-20
307 UDC THREAD PITCH1.5 R0.8 DEPTH0.8 BREADTH5 ;Draaduitloop
308 L  X+110
309 LBL 0
310 ;
311 ;Kontur4
312 LBL 4
313 L  X+105  Z-23
314 L  Z-27
315 GRV RADIAL CENTER-31.5 R1 DIAM89 BREADTH9 ANG_WIDTH28.072 RND1 FAR_RND1 ;Insteek
316 L  Z-40
317 LBL 0
318 END PGM 10005_NL MM