0 BEGIN PGM 10010_NL MM 
1 ;Frees-draaiwerkstuk
2 ;Het onbewerkte werkstuk komt overeen met
3 ;het werkstuk dat met het programma
4 ;10005_nl.h is gemaakt.
5 ;
6 ;Definitie van het onbewerkte werkstuk als
7 ;rotatiesymmetrische component, waarvan de
8 ;contour in het subprogramma BLANK is
9 ;gedefinieerd
10 BLK FORM ROTATION Z DIM_D LBL "BLANK"
11 ;
12 ;Referentiepunt activeren
13 CYCL DEF 247 BEZUGSPUNKT SETZEN ~
   Q339=+2    ;BEZUGSPUNKT-NUMMER
14 ;
15 ;Draaibewerking buiten voorbewerken
16 ;Gereedschapsoproep draaigereedschap voorbewerken
17 TOOL CALL "TURN_ROUGH"
18 ;
19 ;Oproep subprogramma draaimodus
20 CALL LBL "TURN"
21 ;Oproep subprogramma Veilige positie benaderen
22 CALL LBL "SAFE"
23 ;
24 ;Draaisysteem aanpassen
25 CYCL DEF 800 KOORD.-SYST.ANPASSEN ~
   Q497=+0    ;PRAEZESSIONSWINKEL ~
    Q498=+0    ;WERKZEUG UMKEHREN ~
    Q530=+0    ;ANGESTELLTE BEARB. ~
    Q531=+0    ;ANSTELLWINKEL ~
    Q532=+750  ;VORSCHUB ~
    Q533=+0    ;VORZUGSRICHTUNG ~
    Q535=+3    ;EXZENTERDREHEN ~
    Q536=+0    ;EXZENTR. OHNE STOPP
26 ;
27 ;Constante snijsnelheid en maximaal
28 ;toerental definiëren
29 FUNCTION TURNDATA SPIN VCONST:ON VC:400 SMAX800
30 ;
31 ;Zwenkas naar nul verplaatsen en
32 ;draaispil inschakelen
33 L  A+0 R0 FMAX M303
34 ;
35 ;Overdwars draaien
36 CYCL DEF 821 ABSATZ PLAN ~
   Q215=+0    ;BEARBEITUNGS-UMFANG ~
    Q460=+2    ;SICHERHEITS-ABSTAND ~
    Q493=+0    ;KONTURENDE DURCHMESSER ~
    Q494=+0    ;KONTURENDE Z ~
    Q463=+3    ;MAX. SCHNITTTIEFE ~
    Q478=+0.3  ;VORSCHUB SCHRUPPEN ~
    Q483=+0.4  ;AUFMASS DURCHMESSER ~
    Q484=+0.2  ;AUFMASS Z ~
    Q505=+0.2  ;VORSCHUB SCHLICHTEN ~
    Q506=+0    ;KONTURGLAETTUNG
37 L  X+122  Y+0 R0 FMAX ;Voorpositioneren
38 L  Z+5 R0 FMAX ;Starthoogte benaderen
39 M99 ;Cyclus oproepen
40 ;
41 ;Contour roteren
42 CYCL DEF 14.0 KONTUR
43 CYCL DEF 14.1 KONTURLABEL1
44 CYCL DEF 810 DREHEN KONTUR LAENGS ~
   Q215=+0    ;BEARBEITUNGS-UMFANG ~
    Q460=+2    ;SICHERHEITS-ABSTAND ~
    Q499=+0    ;KONTUR UMKEHREN ~
    Q463=+3    ;MAX. SCHNITTTIEFE ~
    Q478=+0.3  ;VORSCHUB SCHRUPPEN ~
    Q483=+0.4  ;AUFMASS DURCHMESSER ~
    Q484=+0.2  ;AUFMASS Z ~
    Q505=+0.2  ;VORSCHUB SCHLICHTEN ~
    Q487=+1    ;EINTAUCHEN ~
    Q488=+0    ;VORSCHUB EINTAUCHEN ~
    Q479=+0    ;SCHNITTBEGRENZUNG ~
    Q480=+0    ;GRENZWERT DURCHMESSER ~
    Q482=+0    ;GRENZWERT Z ~
    Q506=+0    ;KONTURGLAETTUNG
45 L  X+122  Y+0 R0 FMAX ;Voorpositioneren
46 L  Z+5 R0 FMAX ;Starthoogte benaderen
47 M99 ;Cyclusoproep
48 ;
49 ;Freesbewerking vlakken en boringen
50 ;Oproep subprogramma freesmodus
51 CALL LBL "MILL"
52 ;Oproep subprogramma Veilige positie benaderen
53 CALL LBL "SAFE"
54 ;
55 ;Gereedschapsoproep schachtfrees
56 TOOL CALL "MILL_D20_ROUGH" Z S3000 F500
57 ;
58 ;Boring in het midden
59 L  X+0  Y+0  Z+50 R0 FMAX M3 ;Voorpositioneren
60 CYCL DEF 208 BOHRFRAESEN ~
   Q200=+2    ;SICHERHEITS-ABST. ~
    Q201=-40   ;TIEFE ~
    Q206= AUTO ;VORSCHUB TIEFENZ. ~
    Q334=+1.5  ;ZUSTELL-TIEFE ~
    Q203=+0    ;KOOR. OBERFLAECHE ~
    Q204=+50   ;2. SICHERHEITS-ABST. ~
    Q335=+32   ;SOLL-DURCHMESSER ~
    Q342=+0    ;VORGEB. DURCHMESSER ~
    Q351=+1    ;FRAESART
61 M99 ;Cyclusoproep
62 ;
63 ;Oproep subprogramma Veilige positie benaderen
64 CALL LBL "SAFE"
65 ;
66 ;Gereedschapsoproep schachtfrees
67 TOOL CALL "MILL_D10_ROUGH" Z S12000 F300
68 ;
Q50 = 0 ;Actuele C-hoek
69 ;
70 ;Herhaling voor het naar binnen zwenken en vlakfrezen
71 LBL 2
72 PLANE SPATIAL SPA+0 SPB+0 SPC+Q50 STAY ;Coördinatensysteem naar actuele C-hoek zwenken
73 ;
74 ;Nulpunt naar de zwenkkant schuiven
75 CYCL DEF 7.0 NULLPUNKT
76 CYCL DEF 7.1  X+37
77 ;
78 PLANE RELATIV SPB+60 TURN MB MAX FMAX ;Ten opzichte van C-hoek B naar binnen zwenken
79 ;
80 ;Vlakfrezen
81 L  X+12  Y+0  Z+50 R0 FMAX M3 ;Voorpositioneren
82 CYCL DEF 251 RECHTECKTASCHE ~
   Q215=+0    ;BEARBEITUNGS-UMFANG ~
    Q218=+28   ;1. SEITEN-LAENGE ~
    Q219=+50   ;2. SEITEN-LAENGE ~
    Q220=+0    ;ECKENRADIUS ~
    Q368=+0    ;AUFMASS SEITE ~
    Q224=+0    ;DREHLAGE ~
    Q367=+0    ;TASCHENLAGE ~
    Q207= AUTO ;VORSCHUB FRAESEN ~
    Q351=+1    ;FRAESART ~
    Q201=-12   ;TIEFE ~
    Q202=+5    ;ZUSTELL-TIEFE ~
    Q369=+0    ;AUFMASS TIEFE ~
    Q206= AUTO ;VORSCHUB TIEFENZ. ~
    Q338=+0    ;ZUST. SCHLICHTEN ~
    Q200=+2    ;SICHERHEITS-ABST. ~
    Q203=+12   ;KOOR. OBERFLAECHE ~
    Q204=+50   ;2. SICHERHEITS-ABST. ~
    Q370=+1    ;BAHN-UEBERLAPPUNG ~
    Q366=+0    ;EINTAUCHEN ~
    Q385= AUTO ;VORSCHUB SCHLICHTEN
83 M99 ;Cyclus oproepen
84 ;
85 M140 MB MAX ;Vrijzetten
86 PLANE RESET STAY ;Rekenkundig terugzwenken
87 ;Nulpuntverschuiving resetten
88 CYCL DEF 7.0 NULLPUNKT
89 CYCL DEF 7.1  X+0
90 CYCL DEF 7.2  Y+0
91 CYCL DEF 7.3  Z+0
92 ;
Q50 = Q50 + 60 ;C-hoek verder rekenen
93 CALL LBL 2 REP5 ;Herhalen
94 ;
95 ;Oproep subprogramma Veilige positie benaderen
96 CALL LBL "SAFE"
97 ;
98 ;Fysiek terugzwenken
99 PLANE RESET TURN MB MAX
100 ;
101 ;Naar binnen gezwenkt boren
102 ;Gereedschapsoproep boor
103 TOOL CALL "DRILL_D8" Z S12000 F300
104 ;
Q50 = 0 ;Actuele C-hoek
105 ;
106 ;Herhaling voor naar binnen zwenken en boren
107 LBL 3
108 PLANE SPATIAL SPA+0 SPB+0 SPC+Q50 STAY ;Coördinatensysteem naar actuele C-hoek zwenken
109 ;
110 ;Nulpunt naar de zwenkkant schuiven
111 CYCL DEF 7.0 NULLPUNKT
112 CYCL DEF 7.1  X+37
113 ;
114 PLANE RELATIV SPB+60 TURN MB MAX FMAX ;Ten opzichte van C-hoek B naar binnen zwenken
115 ;
116 L  X+12  Y+0  Z+50 R0 FMAX M3 ;Voorpositioneren
117 CYCL DEF 200 BOHREN ~
    Q200=+3    ;SICHERHEITS-ABST. ~
    Q201=-35   ;TIEFE ~
    Q206= AUTO ;VORSCHUB TIEFENZ. ~
    Q202=+5    ;ZUSTELL-TIEFE ~
    Q210=+0    ;VERWEILZEIT OBEN ~
    Q203=+0    ;KOOR. OBERFLAECHE ~
    Q204=+50   ;2. SICHERHEITS-ABST. ~
    Q211=+0    ;VERWEILZEIT UNTEN
118 M99 ;Cyclusoproep
119 ;
120 M140 MB MAX ;Vrijzetten
121 PLANE RESET STAY ;Rekenkundig terugzwenken
122 ;Nulpuntverschuiving resetten
123 CYCL DEF 7.0 NULLPUNKT
124 CYCL DEF 7.1  X+0
125 CYCL DEF 7.2  Y+0
126 CYCL DEF 7.3  Z+0
127 ;
Q50 = Q50 + 60 ;C-hoek verder rekenen
128 CALL LBL 3 REP5 ;Herhalen
129 ;
130 ;Oproep subprogramma Veilige positie benaderen
131 CALL LBL "SAFE"
132 ;
133 ;Fysiek terugzwenken
134 PLANE RESET TURN MB MAX
135 ;
136 ;Einde programma
137 M30
138 ;
139 ;
140 ;Subprogramma Draaimodus
141 LBL "TURN"
142 M140 MB MAX ;Vrijzetten
143 M145 ;Kinematicaberekening opheffen
144 FUNCTION MODE TURN ;Draaimodus activeren
145 M144 ;Kinematicaberekening activeren
146 M136 ;Aanzet omschakelen op mm per omwenteling
147 LBL 0
148 ;
149 ;Subprogramma freesmodus
150 LBL "MILL"
151 M140 MB MAX ;Vrijzetten
152 M145 ;Kinematicaberekening opheffen
153 FUNCTION MODE MILL ;Freesmodus activeren
154 M137 ;Aanzet omschakelen op mm per min
155 ;Subprogramma-oproep Veilige positie benaderen
156 CALL LBL "SAFE"
157 L  C+0  A+0 R0 FMAX ;Zwenkassen naar nul verplaatsen
158 LBL 0
159 ;
160 ;Subprogramma Veilige positie benaderen
161 LBL "SAFE"
162 L  X+400  Y+400 R0 FMAX M91 ;Veilige positie !afhankelijk van machine!
163 LBL 0
164 ;
165 LBL 1 ;Beschrijving contour
166 L  Z+0  X+80
167 L  Z-17.32  X+100
168 L  Z-28.0925  X+100
169 L  Z-33  X+117
170 LBL 0
171 ;
172 ;Beschrijving onbewerkt werkstuk
173 LBL "BLANK"
174 L  X+0  Z+2
175 L  X+120
176 L  Z-38
177 L  Z-38  X+117
178 L  Z-41.0937  X+100
179 L  Z-55  X+100
180 L  Z-55  X+108.9998
181 L  Z-55.5  X+110
182 L  Z-57.5  X+110
183 L  Z-58  X+109
184 L  Z-58  X+105
185 L  Z-61.2192  X+105
186 CT  Z-62.1894  X+103.4851
187 L  Z-63.8106  X+90.5146
188 CT  Z-64.7808  X+88.9997
189 L  Z-68.2192  X+88.9997
190 CT  Z-69.1894  X+90.5146
191 L  Z-70.8106  X+103.4851
192 CT  Z-71.7808  X+105
193 L  Z-75  X+105
194 L  Z-75  X+108.9998
195 L  Z-75.5  X+110
196 L  Z-77.5  X+110
197 L  Z-78  X+109
198 L  Z-78  X+92.7
199 L  Z-81.2081  X+92.7
200 L  Z-83.2  X+95
201 L  Z-96  X+95
202 CT  Z-98  X+91
203 L  Z-98  X+85
204 L  Z-93
205 L  X+75
206 L  Z-58
207 L  X+32
208 L  Z-38
209 L  X+0
210 L  Z+2
211 LBL 0
212 END PGM 10010_NL MM