BEGIN PGM 1015_NL MM
;Programma voor het definiëren van een
;puntenpatroon in de vorm van een spiraal
;met gelijkblijvende positieafstanden.
;Voor de bewerking wordt op de berekende
;posities een bewerkingscyclus opgeroepen.
;In dit programma een boorcyclus. Na de
;definitie van alle benodigde parameters,
;van het gereedschap en de bewerkingscyclus
;wordt een subprogramma opgeroepen waarin de
;afzonderlijke posities worden berekend en
;genaderd en de cyclus wordt uitgevoerd. 
;
;Invoer parameters
FN 0: Q1 =+45 ;EINDRADIUS
FN 0: Q2 =+5 ;STARTRADIUS
FN 0: Q3 =+60 ;START-HOEKSTAP
FN 0: Q4 =+2.5 ;RADIUS-STAP
FN 0: Q5 =+50 ;MIDDELPUNT OP DE X-AS
FN 0: Q6 =+50 ;MIDDELPUNT OP DE Y-AS
FN 0: Q7 =+2 ;VEILIGHEIDSAFSTAND
FN 0: Q8 =+20 ;ROTATIE
;Einde parameterinvoer
;
BLK FORM 0.1 Z X+0 Y+0 Z-12
BLK FORM 0.2  X+100  Y+95  Z+0
;
;Gereedschapsoproep boor
TOOL CALL 225 Z S2000
;
;Definitie bewerkingscyclus
CYCL DEF 1.0 DIEPBOREN
CYCL DEF 1.1 AFST2
CYCL DEF 1.2 DIEPTE-10
CYCL DEF 1.3 VERPL10
CYCL DEF 1.4 STTIJD0
CYCL DEF 1.5 F1000
;
CC  X+Q5  Y+Q6 ;Midden definiëren
LP  PR+0  PA+0 R0 FMAX M3 ;Voorpositioneren naar het midden
CYCL DEF 10.0 ROTATIE
CYCL DEF 10.1  ROT+Q8
CALL LBL 2 ;Oproep berekeningen
;Terugtrekken en programma-einde
L  Z+100 R0 F9999 M2
;
LBL 2 ;Berekeningen
LP  PR+Q2  PA+0 R0 F9998
L  Z+Q7
FN 0: Q14 =+Q4
FN 0: Q13 =+Q3
FN 3: Q34 =+Q2 * +Q4
FN 3: Q33 =+Q2 * +Q3
FN 0: Q24 =+Q2
FN 0: Q23 =+0
LBL 1
FN 4: Q14 =+Q34 DIV +Q24
FN 4: Q13 =+Q33 DIV +Q24
FN 1: Q24 =+Q24 + +Q14
FN 1: Q23 =+Q23 + +Q13
LP  PR+Q24  PA+Q23 M99 ;Positie benaderen en cyclusoproep
FN 11: IF +Q1 GT +Q24 GOTO LBL 1 ;Vergelijking of eindradius is bereikt
LBL 0
END PGM 1015_NL MM