0 BEGIN PGM 1020_NL MM
1 ;Programma voor het definiëren van een
2 ;puntenpatroon in de vorm van rasterlijnen.
3 ;Voor de bewerking wordt op de berekende
4 ;posities een bewerkingscyclus opgeroepen.
5 ;In dit programma een boorcyclus. Na de
6 ;definitie van alle benodigde parameters,
7 ;van het gereedschap en de bewerkingscyclus
8 ;wordt een subprogramma opgeroepen waarin de
9 ;afzonderlijke posities worden berekend en
10 ;genaderd en de cyclus wordt uitgevoerd. 
11 ;
12 ;Invoer parameters
13 FN 0: Q1 =+10 ;STARTPUNT OP DE X-AS
14 FN 0: Q2 =+10 ;STARTPUNT OP DE Y-AS
15 FN 0: Q3 =+9 ;AFSTAND VAN DE BEWERKINGEN OP X
16 FN 0: Q4 =+12 ;AFSTAND VAN DE BEWERKINGEN OP Y
17 FN 0: Q5 =+10 ;AANTAL BEWERKINGEN OP X
18 FN 0: Q6 =+7 ;AANTAL BEWERKINGEN OP Y
19 FN 0: Q7 =+5 ;ROTATIE
20 FN 0: Q8 =+2 ;VEILIGHEIDSAFSTAND
21 ;Einde parameterinvoer
22 ;
23 BLK FORM 0.1 Z X+0 Y+0 Z-25
24 BLK FORM 0.2  X+100  Y+100  Z+0
25 ;
26 ;Gereedschapsoproep boor
27 TOOL CALL 227 Z S1000
28 ;
29 ;Definitie bewerkingscyclus
30 CYCL DEF 1.0 DIEPBOREN
31 CYCL DEF 1.1 AFSTQ8
32 CYCL DEF 1.2 DIEPTE-20
33 CYCL DEF 1.3 VERPL10
34 CYCL DEF 1.4 STTIJD0
35 CYCL DEF 1.5 F100
36 ;
37 CALL LBL 1 ;Oproep subprogramma posities
38 ;
39 ;Terugtrekken en programma-einde
40 L  Z+50 R0 FMAX M2
41 ;
42 LBL 1
43 FN 0: Q21 =+0 ;Actuele positie op de X-as
44 FN 0: Q22 =+0 ;Actuele positie op de Y-as
45 FN 0: Q25 =+0 ;Huidige kolom
46 FN 0: Q26 =+0 ;Actuele regel
47 FN 0: Q23 =+Q3 ;X-stapgrootte
48 ;Nulpunt naar eerste positie verschuiven
49 CYCL DEF 7.0 NULPUNT
50 CYCL DEF 7.1  X+Q1
51 CYCL DEF 7.2  Y+Q2
52 ;Rotatie instellen
53 CYCL DEF 10.0 ROTATIE
54 CYCL DEF 10.1  ROT+Q7
55 LBL 2 ;Positie benaderen
56 L  X+Q21  Y+Q22 R0 F9999 M3 ;Positie benaderen
57 L  Z+Q8 R0 F9999 M99 ;Naar veiligheidsafstand verplaatsen en cyclus oproepen
58 LBL 3 ;Nieuwe positie berekenen
59 FN 1: Q21 =+Q21 + +Q23 ;X-stap
60 FN 1: Q25 =+Q25 + +1 ;Kolom verder tellen
61 FN 12: IF +Q25 LT +Q5 GOTO LBL 2
62 FN 0: Q25 =+0 ;Reset kolomteller
63 FN 1: Q26 =+Q26 + +1 ;Regel verder tellen
64 FN 0: Q23 =-Q23 ;X-stapgrootte omdraaien
65 FN 1: Q21 =+Q21 + +Q23 ;X-stap compenseren
66 FN 1: Q22 =+Q22 + +Q4 ;Y-stap
67 FN 12: IF +Q26 LT +Q6 GOTO LBL 2
68 ;Nulpunt en rotatie terugzetten
69 CYCL DEF 7.0 NULPUNT
70 CYCL DEF 7.1  X+0
71 CYCL DEF 7.2  Y+0
72 CYCL DEF 10.0 ROTATIE
73 CYCL DEF 10.1  ROT+0
74 LBL 0
75 END PGM 1020_NL MM