0 BEGIN PGM 1065_NL MM 
1 ;Programma om op verschillende posities te centreren,
2 ;een voorboorgat te maken en dit dan dieper te boren.
3 ;De posities en andere boorparameters zijn in een tabel
4 ;opgeslagen
5 ;
6 BLK FORM 0.1 Z X+0 Y+0 Z-100
7 BLK FORM 0.2  X+100  Y+100  Z+0
8 ;
9 ; Tabel met boorparameters definiëren
10 FN 26: TABOPEN 10651_nl.tab
11 ;
12 ;Gereedschapsoproep centerboor
13 TOOL CALL 203 Z S2000
14 ;
15 CYCL DEF 203 UNIVERSEEL-BOREN ~
   Q200=+2    ;VEILIGHEIDSAFSTAND ~
   Q201=-3    ;DIEPTE ~
    Q206=+150  ;AANZET DIEPTEVERPL. ~
    Q202=+5    ;DIEPTEVERPLAATSING ~
    Q210=+0    ;STILSTANDSTIJD BOVEN ~
    Q203=+0    ;COORD. OPPERVLAK ~
    Q204=+50   ;2E VEILIGHEIDSAFST. ~
    Q212=+0    ;AFNAMEWAARDE ~
    Q213=+0    ;AANT. SPAANBREKEN ~
    Q205=+0    ;MIN. DIEPTEVERPL. ~
    Q211=+0    ;STILSTANDSTIJD ONDER ~
    Q208=+30000 ;AANZET TERUGTREKKEN ~
    Q256=+0.2  ;TERUGTR.HGT SPAANBR.
16 ;
17 ;De te gebruiken regels van de tabel definiëren
18 FN 0: Q51 =+0 ;STARTREGEL
19 FN 0: Q52 =+4 ;OVERIGE REGELS
20 ;
21 CALL LBL 12
22 ;
23 STOP
24 ;
25 ;Gereedschapsoproep boor voor voorboorgat
26 TOOL CALL 227 Z S2000
27 ;
28 ;Te wijzigen parameter uit de boorcyclus definiëren
29 FN 0: Q201 =-10 ;Nieuwe diepte
30 ;
31 CALL LBL 12
32 ;
33 STOP
34 ;
35 ;Gereedschapsoproep voor het diepboren
36 TOOL CALL 226 Z
37 ;
38 ;Vastleggen parameterwaarde voor het diepboren
39 FN 0: Q1 =+0 ;Bovenkant
40 FN 0: Q2 =+0 ;Voorboordiepte
41 FN 0: Q3 =-10 ;Spaantransporthoogte
42 FN 0: Q4 =+1000 ;Aanzet voor het insteken
43 FN 0: Q5 =+200 ;Aanzet voor het boren
44 FN 0: Q6 =+2000 ;Toerental
45 FN 0: Q7 =+5 ;Verplaatsing
46 FN 0: Q8 =+0 ;Diepte
47 FN 0: Q9 =+0.5 ;Wachttijd
48 FN 0: Q10 =+1 ;Spaanbreukwaarde
49 FN 0: Q11 =+2 ;Veiligheidswaarde 1 (incrementeel)
50 FN 0: Q12 =+30 ;Veiligheidswaarde 2 (incrementeel)
51 FN 0: Q13 =+5 ;Aantal verplaatsingen
52 ;
53 ;PGM 10652_nl.h als cyclus definiëren
54 CYCL DEF 12.0 PGM CALL
55 CYCL DEF 12.1 PGM 10652_nl.h
56 ;
57 CALL LBL 12
58 ;
59 ;Terugtrekken en programma-einde
60 L  X+0  Y+0  Z+100 FMAX M2
61 ;
62 ;Posities benaderen
63 LBL 12
Q61 = Q51 ;Tabelregel van de eerste positie definiëren
64 LBL 11
65 CALL LBL 10
66 FN 1: Q61 =+Q61 + +1 ;Tabelregel doorrekenen
67 CALL LBL 11 REPQ52
68 LBL 0
69 ;
70 ;Leescommando's, positie naderen en cyclus oproepen
71 LBL 10
72 FN 28: TABREAD Q41 =Q61 /"X"
73 FN 28: TABREAD Q42 =Q61 /"Y"
74 FN 28: TABREAD Q1 =Q61 /"Z"
75 FN 28: TABREAD Q8 =Q61 /"Depth"
76 FN 28: TABREAD Q45 =Q61 /"Distance"
77 FN 28: TABREAD Q46 =Q61 /"Feed_rate"
78 FN 28: TABREAD Q47 =Q61 /"Safe_height"
79 L  X+Q41  Y+Q42 R0 FMAX M13 M99
80 LBL 0
81 END PGM 1065_NL MM