0 BEGIN PGM 13_002_2_NL MM 
1 ;Programma om de voorzijde van de horlogebehuizing
2 ;te bewerken.
3 ;De scheve ligging van het werkstuk en de
4 ;referentiepunten in X en Y kunnen worden bepaald
5 ;via de boringen die door de achterzijde zijn
6 ;voorgeboord.
7 ;
8 ;
9 BLK FORM 0.1 Z X-49 Y+0 Z-38
10 BLK FORM 0.2  X+49  Y+85  Z+5
11 ;
12 ;Zwenken en nulpunt terugzetten
13 CALL LBL "RESET"
14 ;
15 ;Gereedschapsoproep voor eindvlak, uitsteeksel
16 ;en rondkamer
17 TOOL CALL 11 Z S9550 F2000
18 L  Z+100 R0 FMAX M3
19 ;
20 ;Eindvlak bewerken
21 CYCL DEF 233 VLAKFREZEN ~
   Q215=+0    ;BEWERKINGSOMVANG ~
    Q389=+4    ;FREESSTRATEGIE ~
    Q350=+1    ;FREESRICHTING ~
    Q218=+100  ;LENGTE 1E ZIJKANT ~
    Q219=+100  ;LENGTE 2E ZIJKANT ~
    Q227=+5    ;STARTPUNT 3E AS ~
    Q386=+0    ;EINDPUNT 3E AS ~
    Q369=+0.2  ;OVERMAAT DIEPTE ~
    Q202=+5    ;MAX. DIEPTESTAP ~
    Q370=+1    ;BAANOVERLAPPING ~
    Q207= AUTO ;AANZET FREZEN ~
    Q385= AUTO ;AANZET NABEWERKEN ~
    Q253= MAX ;AANZET VOORPOS. ~
    Q357=+2    ;VEIL.AFST. KANT ~
    Q200=+2    ;VEILIGHEIDSAFSTAND ~
    Q204=+50   ;2E VEILIGHEIDSAFST. ~
    Q347=+0    ;1E BEGRENZING ~
    Q348=+0    ;2E BEGRENZING ~
    Q349=+0    ;3E BEGRENZING ~
    Q220=+0    ;HOEKRADIUS ~
    Q368=+0    ;OVERMAAT ZIJKANT ~
    Q338=+0    ;VERPLAATSING NABEW.
22 L  X-50  Y-7.5 R0 FMAX M99
23 ;
24 ;Uitsteeksel frezen
25 CYCL DEF 233 VLAKFREZEN ~
   Q215=+0    ;BEWERKINGSOMVANG ~
    Q389=+2    ;FREESSTRATEGIE ~
    Q350=+1    ;FREESRICHTING ~
    Q218=+98   ;LENGTE 1E ZIJKANT ~
    Q219=-67   ;LENGTE 2E ZIJKANT ~
    Q227=+0    ;STARTPUNT 3E AS ~
    Q386=-14   ;EINDPUNT 3E AS ~
    Q369=+0.2  ;OVERMAAT DIEPTE ~
    Q202=+5    ;MAX. DIEPTESTAP ~
    Q370=+1    ;BAANOVERLAPPING ~
    Q207= AUTO ;AANZET FREZEN ~
    Q385= AUTO ;AANZET NABEWERKEN ~
    Q253= MAX ;AANZET VOORPOS. ~
    Q357=+2    ;VEIL.AFST. KANT ~
    Q200=+2    ;VEILIGHEIDSAFSTAND ~
    Q204=+50   ;2E VEILIGHEIDSAFST. ~
    Q347=-2    ;1E BEGRENZING ~
    Q348=+0    ;2E BEGRENZING ~
    Q349=+0    ;3E BEGRENZING ~
    Q220=+0    ;HOEKRADIUS ~
    Q368=+0.2  ;OVERMAAT ZIJKANT ~
    Q338=+0    ;VERPLAATSING NABEW.
26 L  X-49  Y+85 R0 FMAX M99
27 ;
28 ;Rondkamer frezen
29 L  X+0  Y+50 R0 FMAX
30 CYCL DEF 252 RONDKAMER ~
   Q215=+0    ;BEWERKINGSOMVANG ~
    Q223=+60   ;CIRKEL DIAMETER ~
    Q368=+0.2  ;OVERMAAT ZIJKANT ~
    Q207= AUTO ;AANZET FREZEN ~
    Q351=+1    ;FREESWIJZE ~
    Q201=-5    ;DIEPTE ~
    Q202=+5    ;DIEPTEVERPLAATSING ~
    Q369=+0.2  ;OVERMAAT DIEPTE ~
    Q206= AUTO ;AANZET DIEPTEVERPL. ~
    Q338=+0    ;VERPLAATSING NABEW. ~
    Q200=+2    ;VEILIGHEIDSAFSTAND ~
    Q203=-14   ;COORD. OPPERVLAK ~
    Q204=+50   ;2E VEILIGHEIDSAFST. ~
    Q370=+1    ;BAANOVERLAPPING ~
    Q366=+1    ;INSTEKEN ~
    Q385= AUTO ;AANZET NABEWERKEN
31 M99
32 L  Z+100 R0 FMAX M5 ;Vrijzetten
33 ;
34 ;Gereedschapsoproep voor het voorfrezen
35 ;van de contour
36 TOOL CALL 16 Z S2000 F300
37 L  Z+100 R0 FMAX M3
38 CYCL DEF 14.0 CONTOUR
39 CYCL DEF 14.1 CONTOURLABEL1
40 CYCL DEF 25 CONTOURREEKS ~
   Q1=-7    ;FREESDIEPTE ~
    Q3=+0.5  ;OVERMAAT ZIJKANT ~
    Q5=-14   ;COORD. OPPERVLAK ~
    Q7=+50   ;VEILIGE HOOGTE ~
    Q10=-5    ;DIEPTEVERPLAATSING ~
    Q11= AUTO ;AANZET DIEPTEVERPL. ~
    Q12= AUTO ;AANZET UITRUIMEN ~
    Q15=+1    ;FREESWIJZE
41 M99
42 L  Z+100 R0 FMAX M5
43 ;
44 ;Gereedschapsoproep voor de afkanting, de
45 ;kamers en voor nabewerking van de
46 ;contour
47 TOOL CALL 5 Z S14000 F2500
48 ;
49 ;Vrijzetten naar veilige positie
50 CALL LBL "S-POS"
51 ;
52 ;Nulpunt verschuiven
53 CYCL DEF 7.0 NULPUNT
54 CYCL DEF 7.1  Y+18
55 CYCL DEF 7.2  Z-14
56 ;
57 ;Bewerkingsvlak voor zwenken
58 PLANE SPATIAL SPA-45 SPB+0 SPC+0 TURN MB MAX FMAX
59 L  Z+100 R0 FMAX M3
60 L  X-55  Y+0 R0 FMAX
61 CYCL DEF 251 RECHTHOEKIGE KAMER ~
   Q215=+0    ;BEWERKINGSOMVANG ~
    Q218=+110  ;LENGTE 1E ZIJKANT ~
    Q219=+22   ;LENGTE 2E ZIJKANT ~
    Q220=+5    ;HOEKRADIUS ~
    Q368=+0.2  ;OVERMAAT ZIJKANT ~
    Q224=+0    ;ROTATIEPOSITIE ~
    Q367=+4    ;POSITIE KAMER ~
    Q207= AUTO ;AANZET FREZEN ~
    Q351=+1    ;FREESWIJZE ~
    Q201=-10   ;DIEPTE ~
    Q202=+5    ;DIEPTEVERPLAATSING ~
    Q369=+0.2  ;OVERMAAT DIEPTE ~
    Q206= AUTO ;AANZET DIEPTEVERPL. ~
    Q338=+5    ;VERPLAATSING NABEW. ~
    Q200=+2    ;VEILIGHEIDSAFSTAND ~
    Q203=+10   ;COORD. OPPERVLAK ~
    Q204=+50   ;2E VEILIGHEIDSAFST. ~
    Q370=+1    ;BAANOVERLAPPING ~
    Q366=+2    ;INSTEKEN ~
    Q385= AUTO ;AANZET NABEWERKEN
62 M99
63 L  Z+100 R0 FMAX
64 ;
65 ;Zwenken en nulpunt terugzetten
66 CALL LBL "RESET"
67 ;
68 ;Rechthoekige kamers frezen
69 L  Z+100 R0 FMAX
70 CYCL DEF 251 RECHTHOEKIGE KAMER ~
   Q215=+0    ;BEWERKINGSOMVANG ~
    Q218=+12   ;LENGTE 1E ZIJKANT ~
    Q219=+30   ;LENGTE 2E ZIJKANT ~
    Q220=+0    ;HOEKRADIUS ~
    Q368=+0.2  ;OVERMAAT ZIJKANT ~
    Q224=+0    ;ROTATIEPOSITIE ~
    Q367=+0    ;POSITIE KAMER ~
    Q207= AUTO ;AANZET FREZEN ~
    Q351=+1    ;FREESWIJZE ~
    Q201=-5    ;DIEPTE ~
    Q202=+3    ;DIEPTEVERPLAATSING ~
    Q369=+0.2  ;OVERMAAT DIEPTE ~
    Q206= AUTO ;AANZET DIEPTEVERPL. ~
    Q338=+5    ;VERPLAATSING NABEW. ~
    Q200=+2    ;VEILIGHEIDSAFSTAND ~
    Q203=-21   ;COORD. OPPERVLAK ~
    Q204=+50   ;2E VEILIGHEIDSAFST. ~
    Q370=+1    ;BAANOVERLAPPING ~
    Q366=+2    ;INSTEKEN ~
    Q385= AUTO ;AANZET NABEWERKEN
71 L  X-41  Y+66 R0 FMAX M99
72 L  X+41  Y+66 R0 FMAX M99
73 ;
74 ;Contour nabewerken
75 CYCL DEF 14.0 CONTOUR
76 CYCL DEF 14.1 CONTOURLABEL1
77 CYCL DEF 25 CONTOURREEKS ~
   Q1=-7    ;FREESDIEPTE ~
    Q3=+0    ;OVERMAAT ZIJKANT ~
    Q5=-14   ;COORD. OPPERVLAK ~
    Q7=+50   ;VEILIGE HOOGTE ~
    Q10=-5    ;DIEPTEVERPLAATSING ~
    Q11= AUTO ;AANZET DIEPTEVERPL. ~
    Q12= AUTO ;AANZET UITRUIMEN ~
    Q15=+1    ;FREESWIJZE
78 M99
79 L  Z+100 R0 FMAX M5 ;Vrijzetten
80 ;
81 ;Gereedschapsoproep voor afbramen
82 TOOL CALL 172 Z S900 F500
83 L  Z+100 R0 FMAX M3
84 ;
85 ;Boringen afbramen
86 L  X+0  Y+50 R0 FMAX
87 CYCL DEF 240 CENTREREN ~
   Q200=+2    ;VEILIGHEIDSAFSTAND ~
    Q343=+1    ;SELECT. DIA./DIEPTE ~
    Q201=-2    ;DIEPTE ~
    Q344=-9    ;DIAMETER ~
    Q206= AUTO ;AANZET DIEPTEVERPL. ~
    Q211=+0    ;STILSTANDSTIJD ONDER ~
    Q203=-19   ;COORD. OPPERVLAK ~
    Q204=+50   ;2E VEILIGHEIDSAFST.
88 M99
89 CYCL DEF 240 CENTREREN ~
   Q200=+3    ;VEILIGHEIDSAFSTAND ~
    Q343=+1    ;SELECT. DIA./DIEPTE ~
    Q201=-2    ;DIEPTE ~
    Q344=-6    ;DIAMETER ~
    Q206= AUTO ;AANZET DIEPTEVERPL. ~
    Q211=+0    ;STILSTANDSTIJD ONDER ~
    Q203=-19   ;COORD. OPPERVLAK ~
    Q204=+50   ;2E VEILIGHEIDSAFST.
90 PATTERN DEF ~
   CIRC1( X+0 Y+50 D46 START+0 NUM4 Z+0 )
91 CYCL CALL PAT FMAX
92 ;
93 ;Gereedschapsoproep met DR voor de afkanting
94 TOOL CALL 172 Z S900 F500 DR-4.5
95 ;
96 ;Rondkamer afbramen
97 L  X+0  Y+50 R0 FMAX
98 CYCL DEF 252 RONDKAMER ~
   Q215=+2    ;BEWERKINGSOMVANG ~
    Q223=+60   ;CIRKEL DIAMETER ~
    Q368=+0.1  ;OVERMAAT ZIJKANT ~
    Q207= AUTO ;AANZET FREZEN ~
    Q351=+1    ;FREESWIJZE ~
    Q201=-0.8  ;DIEPTE ~
    Q202=+5    ;DIEPTEVERPLAATSING ~
    Q369=+0    ;OVERMAAT DIEPTE ~
    Q206= AUTO ;AANZET DIEPTEVERPL. ~
    Q338=+1    ;VERPLAATSING NABEW. ~
    Q200=+2    ;VEILIGHEIDSAFSTAND ~
    Q203=-14   ;COORD. OPPERVLAK ~
    Q204=+50   ;2E VEILIGHEIDSAFST. ~
    Q370=+1    ;BAANOVERLAPPING ~
    Q366=+1    ;INSTEKEN ~
    Q385= AUTO ;AANZET NABEWERKEN
99 M99
100 ;
101 ;Rondkamer afbramen
102 CYCL DEF 14.0 CONTOUR
103 CYCL DEF 14.1 CONTOURLABEL1
104 CYCL DEF 25 CONTOURREEKS ~
    Q1=-2.5  ;FREESDIEPTE ~
    Q3=+0    ;OVERMAAT ZIJKANT ~
    Q5=-14   ;COORD. OPPERVLAK ~
    Q7=+50   ;VEILIGE HOOGTE ~
    Q10=-2.3  ;DIEPTEVERPLAATSING ~
    Q11= AUTO ;AANZET DIEPTEVERPL. ~
    Q12= AUTO ;AANZET UITRUIMEN ~
    Q15=+1    ;FREESWIJZE
105 M99
106 L  Z+100 R0 FMAX M5 ;Vrijzetten
107 ;
108 ;Gereedschapsoproep voor centreren
109 TOOL CALL 204 Z S6000 F400
110 L  Z+100 R0 FMAX M3
111 ;
112 ;Centreren op de wijzerplaat
113 L  X+0  Y+50 R0 FMAX
114 CYCL DEF 240 CENTREREN ~
    Q200=+2    ;VEILIGHEIDSAFSTAND ~
    Q343=+1    ;SELECT. DIA./DIEPTE ~
    Q201=-2    ;DIEPTE ~
    Q344=-5    ;DIAMETER ~
    Q206= AUTO ;AANZET DIEPTEVERPL. ~
    Q211=+0    ;STILSTANDSTIJD ONDER ~
    Q203=-19   ;COORD. OPPERVLAK ~
    Q204=+50   ;2E VEILIGHEIDSAFST.
115 CC  X+0  Y+50
116 LP  PR+23  PA+30 FMAX M99
117 LP IPA+30 R0 FMAX M99
118 LP IPA+60 R0 FMAX M99
119 LP IPA+30 R0 FMAX M99
120 LP IPA+60 R0 FMAX M99
121 LP IPA+30 R0 FMAX M99
122 LP IPA+60 R0 FMAX M99
123 LP IPA+30 R0 FMAX M99
124 L  Z+100 R0 FMAX M5 ;Vrijzetten
125 ;
126 ;Centreren voor boringen D10
127 ;
128 ;Veilige positie benaderen
129 CALL LBL "S-POS"
130 ;
131 ;Nulpunt verschuiven
132 CYCL DEF 7.0 NULPUNT
133 CYCL DEF 7.1  Y+4
134 ;
135 ;Bewerkingsvlak zwenken
136 PLANE SPATIAL SPA-45 SPB+0 SPC+0 TURN MB MAX FMAX
137 L  Z+100 R0 FMAX M3
138 L  X+38  Y+9 R0 FMAX
139 CYCL DEF 240 CENTREREN ~
    Q200=+2    ;VEILIGHEIDSAFSTAND ~
    Q343=+1    ;SELECT. DIA./DIEPTE ~
    Q201=-2    ;DIEPTE ~
    Q344=-10.5 ;DIAMETER ~
    Q206= AUTO ;AANZET DIEPTEVERPL. ~
    Q211=+0    ;STILSTANDSTIJD ONDER ~
    Q203=+0    ;COORD. OPPERVLAK ~
    Q204=+50   ;2E VEILIGHEIDSAFST.
140 M99
141 L  X-38 R0 FMAX M99
142 L  Z+100 R0 FMAX M5 ;Vrijzetten
143 ;
144 ;Zwenken en nulpunt terugzetten
145 CALL LBL "RESET"
146 ;
147 ;Gereedschapsoproep boren van boring D10
148 TOOL CALL 232 Z S3000 F400
149 ;
150 ;Veilige positie benaderen
151 CALL LBL "S-POS"
152 ;
153 ;Nulpunt verschuiven
154 CYCL DEF 7.0 NULPUNT
155 CYCL DEF 7.1  Y+4
156 ;
157 ;Bewerkingsvlak zwenken
158 PLANE SPATIAL SPA-45 SPB+0 SPC+0 TURN MB MAX FMAX
159 L  Z+100 R0 FMAX M3
160 L  X+38  Y+9 R0 FMAX
161 CYCL DEF 200 BOREN ~
    Q200=+2    ;VEILIGHEIDSAFSTAND ~
    Q201=-9    ;DIEPTE ~
    Q206= AUTO ;AANZET DIEPTEVERPL. ~
    Q202=+5    ;DIEPTEVERPLAATSING ~
    Q210=+0    ;STILSTANDSTIJD BOVEN ~
    Q203=+0    ;COORD. OPPERVLAK ~
    Q204=+50   ;2E VEILIGHEIDSAFST. ~
    Q211=+0    ;STILSTANDSTIJD ONDER ~
    Q395=+1    ;REF. DIEPTE
162 M99
163 L  X-38 R0 FMAX M99
164 L  Z+100 R0 FMAX M5 ;Vrijzetten
165 ;
166 ;Zwenken en nulpunt terugzetten
167 CALL LBL "RESET"
168 ;
169 L  Z+100 R0 FMAX M30 ;Vrijzetten
170 ;
171 ;Subprogramma's
172 ;Contour
173 LBL 1
174 L  X-65  Y+22 RL
175 L  X-49
176 FL  X-34  AN+28
177 RND R10
178 L  Y+50
179 CC  X+0  Y+50
180 CP  PA+0 DR-
181 FLT  X+34  AN-90
182 FCT DR+ R10
183 FLT  X+49  Y+22  AN-28
184 L  X+65
185 LBL 0
186 ;
187 ;Veilige hoogte
188 LBL "S-POS"
189 L  Z+135 R0 FMAX M91
190 L  X+175  Y+140 R0 FMAX M91
191 LBL 0
192 ;
193 ;Zwenken terugzetten
194 LBL "RESET"
195 ;Veilige positie benaderen
196 CALL LBL "S-POS"
197 ;Zwenken terugzetten
198 PLANE RESET TURN FMAX
199 ;Nulpunt terugzetten
200 CYCL DEF 7.0 NULPUNT
201 CYCL DEF 7.1  X+0
202 CYCL DEF 7.2  Y+0
203 CYCL DEF 7.3  Z+0
204 LBL 0
205 END PGM 13_002_2_NL MM