0 BEGIN PGM 2125_NL MM 
1 ;Programma om een kamer met de contour van
2 ;een ellips te maken.
3 BLK FORM 0.1 Z X+0 Y+0 Z-20
4 BLK FORM 0.2  X+100  Y+100  Z+0
5 ;
6 ;Gereedschapsoproep schachtfrees D10
7 TOOL CALL 5 Z S5000
8 ;
9 ;Snijgegevens
Q50 = 20 ;FREESDIEPTE
Q51 = 3 ;DIEPTE-INSTELLING
Q52 = 2 ;VEILIGHEIDSAFSTAND
Q53 = 150 ;AANZET DIEPTEVERPLAATSING
Q54 = 500 ;AANZET FREZEN
10 ;
11 ;Parameter voor ellips
Q31 = 50 ;GROTE RADIUS
Q32 = 25 ;KLEINE RADIUS
Q33 = 1 ;HOEKSTAP
Q38 = 50 ;MIDDELPUNT ELLIPS X
Q39 = 50 ;MIDDELPUNT ELLIPS Y
Q40 = 45 ;ROTATIE
12 ;***Reset parameter
Q41 = 0 ;RESET HOEKWAARDE
13 ;
14 ;===========================================
15 CYCL DEF 7.0 NULPUNT
16 CYCL DEF 7.1  X+Q38
17 CYCL DEF 7.2  Y+Q39
18 CYCL DEF 10.0 ROTATIE
19 CYCL DEF 10.1  ROT+Q40
20 CYCL DEF 14.0 CONTOUR
21 CYCL DEF 14.1 CONTOURLABEL1
22 CYCL DEF 20 CONTOURDATA ~
   Q1=-Q50  ;FREESDIEPTE ~
    Q2=+1    ;BAANOVERLAPPING ~
    Q3=+0    ;OVERMAAT ZIJKANT ~
    Q4=+0    ;OVERMAAT DIEPTE ~
    Q5=+0    ;COORD. OPPERVLAK ~
    Q6=+Q52  ;VEILIGHEIDSAFSTAND ~
    Q7=+50   ;VEILIGE HOOGTE ~
    Q8=+0    ;AFRONDINGSRADIUS ~
    Q9=+1    ;ROTATIERICHTING
23 CYCL DEF 22 UITRUIMEN ~
   Q10=-Q51  ;DIEPTEVERPLAATSING ~
    Q11=+Q53  ;AANZET DIEPTEVERPL. ~
    Q12=+Q54  ;AANZET UITRUIMEN ~
    Q18=+0    ;VOORRUIMGEREEDSCHAP ~
    Q19=+Q53  ;AANZET PENDELEN ~
    Q208=+99999 ;AANZET TERUGTREKKEN
24 M3 M99
25 CYCL DEF 7.0 NULPUNT
26 CYCL DEF 7.1  X+0
27 CYCL DEF 7.2  Y+0
28 CYCL DEF 10.0 ROTATIE
29 CYCL DEF 10.1  ROT+0
30 ;
31 ;Einde van programma
32 L  Z+50 R0 FMAX M30
33 ;
34 ;Subprogramma
35 ;***Contourbeschrijving
36 LBL 1
Q42 = COS Q41 * Q31 ;BEREKENING NIEUWE X-WAARDE
Q43 = SIN Q41 * Q32 ;BEREKENING NIEUWE Y-WAARDE
37 L  X+Q42  Y+Q43 RL
Q41 = Q41 + Q33 ;BEREKENING NIEUWE HOEKWAARDE
38 FN 12: IF +Q41 LT +360 GOTO LBL 1
39 LBL 0
40 END PGM 2125_NL MM