0 BEGIN PGM 2145_NL MM 
1 ;NC-programma waarin een SL-cyclus
2 ;gedefinieerd is. Het kenmerkende is,
3 ;dat door een Q-parameter kan worden
4 ;geselecteerd welk subprogrammanummer
5 ;als contour moet worden gebruikt.
6 ;Hiervoor definieert u aan het begin van
7 ;het programma een parameter met het nummer
8 ;van het te gebruiken subprogramma, in het
9 ;voorbeeld 11 of 12. In cyclus 14 is dan
10 ;het subprogrammanummer van het eiland en
11 ;het andere subprogramma opgegeven. Dit tweede
12 ;subprogramma bestaat alleen uit een CALL LBL
13 ;met de aan het begin gedefinieerde
14 ;Q-parameter, zodat het geselecteerde
15 ;programma wordt gebruikt.
16 ;
17 BLK FORM 0.1 Z X+200 Y-50 Z-10
18 BLK FORM 0.2  X+300  Y+50  Z+30
19 ;
20 ;Gereedschapsoproep
21 TOOL CALL 4 Z S8000
22 ;
23 L  Z+100 R0 F9999 M3 ;Vrijzetten
24 ;
25 FN 0: Q30 =+12 ;KEUZE VAN DE KAMERCONTOUR
26 ;
27 ;Definitie van het contourlabel
28 CYCL DEF 14.0 CONTOUR
29 CYCL DEF 14.1 CONTOURLABEL10 /2
30 ;
31 ;Bewerkingscycli
32 CYCL DEF 20 CONTOURDATA ~
   Q1=-34   ;FREESDIEPTE ~
    Q2=+1    ;BAANOVERLAPPING ~
    Q3=+0    ;OVERMAAT ZIJKANT ~
    Q4=+0    ;OVERMAAT DIEPTE ~
    Q5=+30   ;COORD. OPPERVLAK ~
    Q6=+2    ;VEILIGHEIDSAFSTAND ~
    Q7=+5    ;VEILIGE HOOGTE ~
    Q8=+0    ;AFRONDINGSRADIUS ~
    Q9=+1    ;ROTATIERICHTING
33 CYCL DEF 22 UITRUIMEN ~
   Q10=-4    ;DIEPTEVERPLAATSING ~
    Q11=+300  ;AANZET DIEPTEVERPL. ~
    Q12=+1500 ;AANZET UITRUIMEN ~
    Q18=+0    ;VOORRUIMGEREEDSCHAP ~
    Q19=+500  ;AANZET PENDELEN ~
    Q208=+99999 ;AANZET TERUGTREKKEN ~
    Q401=+70   ;AANZETFACTOR ~
    Q404=+0    ;NARUIMSTRATEGIE
34 CYCL CALL M3
35 L  Z+100 R0 F99999 ;Vrijzetten
36 M30 ;Einde van programma
37 ;
38 ;Subprogramma's
39 ;
40 LBL 2 ;Contour eiland
41 L  X+200  Y+26 RL
42 L  X+300  Y+36
43 L  Y-36
44 L  X+200  Y-26
45 L  X+200  Y+26
46 LBL 0
47 ;
48 LBL 10 ;Subprogramma selectie kamer
49 CALL LBL Q30
50 LBL 0
51 ;
52 LBL 11 ;Contour kamer 1
53 L  X+194  Y-56 RR
54 L  Y+46
55 L  X+306
56 L  Y-46
57 L  X+194
58 LBL 0
59 ;
60 LBL 12 ;Contour kamer 2
61 L  X+194  Y-56 RR
62 L  Y+56
63 L  X+306
64 L  Y-56
65 L  X+194
66 LBL 0
67 END PGM 2145_NL MM