0 BEGIN PGM 3045_NL MM 
1 ;Programma om een liggende afgeknotte kegel
2 ;van binnen te bewerken. De rotatie-as ligt
3 ;parallel aan de X-as. De bewerking vindt
4 ;plaats met een kogelfrees in hoogtelijnen,
5 ;waarvan u het aantal met de parameter
6 ;Deling (Q8) definieert.
7 ;
8 ;Parameter-invoer
9 FN 0: Q13 =+35 ;KEGELMIDDELPUNT OP Y
10 FN 0: Q14 =+0 ;KEGELMIDDELPUNT OP Z
11 FN 0: Q1 =+0 ;MINIMALE X-COÖRDINAAT
12 FN 0: Q5 =+100 ;MAXIMALE X-COÖRDINAAT
13 FN 0: Q6 =+30 ;RADIUS BIJ X-MINIMAAL
14 FN 0: Q7 =+20 ;RADIUS BIJ X-MAXIMAAL
15 FN 0: Q8 =+90 ;VERDELING
16 FN 0: Q10 =+30 ;VEILIGHEIDSAFSTAND
17 FN 0: Q11 =+300 ;AANZET DIEPTEVERPLAATSING
18 FN 0: Q12 =+1000 ;AANZET FREZEN
19 ;Einde parameterinvoer
20 ;
21 BLK FORM 0.1 Z X+0 Y+0 Z-35
22 BLK FORM 0.2  X+100  Y+70  Z+0
23 ;
24 ;Gereedschapsoproep kogelfrees
25 TOOL CALL 157 Z S4000
26 TOOL CALL  Z DL-Q108 ;Lengtecorrectie in het middelpunt van de kogel
27 ;
28 L  X-20  Y+0  Z+28 R0 F5555 ;Voorpositioneren
29 ;
30 CALL LBL 1 ;Bewerking oproepen
31 ;
32 ;Coördinaten omrekening terugzetten
33 CYCL DEF 7.0 NULPUNT
34 CYCL DEF 7.1  X+0
35 CYCL DEF 7.2  Y+0
36 CYCL DEF 7.3  Z+0
37 ;
38 ;Vrijzetten en programma-einde
39 L  Z+100 R0 FMAX M2
40 ;
41 LBL 1 ;Bewerking
42 ;Berekeningen
43 FN 2: Q16 =+Q6 - +Q108 ;Radius tot middelpunt van het gereedschap bij X-min
44 FN 2: Q17 =+Q7 - +Q108 ;Radius tot middelpunt van het gereedschap bij X-max
45 FN 0: Q27 =+180 ;Starthoek
Q37 = 180 / Q8 ;Hoekstap
46 FN 0: Q28 =+0 ;Teller
47 ;
48 ;Nulpunt in het kegelmiddelpunt schuiven
49 CYCL DEF 7.0 NULPUNT
50 CYCL DEF 7.1  Y+Q13
51 CYCL DEF 7.2  Z+Q14
52 ;
53 CALL LBL 10
54 L  X+Q1  Y+Q22 R0 F5555 ;Startpunt benaderen
55 L  Z+Q23 FQ11 ;Diepte naderen
56 L  X+Q5  Y+Q42  Z+Q43 ;Naar eindpunt verplaatsen
57 L IZ+Q10 ;Naar veiligheidsafstand verplaatsen
58 ;
59 LBL 2
Q27 = Q27 + Q37 ;Hoek verder rekenen
Q28 = Q28 + 1 ;Teller verder rekenen
60 FN 11: IF +Q28 GT +Q8 GOTO LBL 99
61 CALL LBL 10
62 L  X+Q1  Y+Q22 R0 F5555 ;Startpunt benaderen
63 L  Z+Q23 FQ11 ;Diepte naderen
64 L  X+Q5  Y+Q42  Z+Q43 ;Naar eindpunt verplaatsen
65 L IZ+Q10 ;Naar veiligheidsafstand verplaatsen
66 FN 9: IF +0 EQU +0 GOTO LBL 2 ;Herhaling
67 ;
68 LBL 10 ;Berekening van de coördinaten
Q22 = Q16 * COS Q27 ;Y-coördinaat X-min
Q42 = Q17 * COS Q27 ;Y-coördinaat X-max
Q23 = Q16 * SIN Q27 ;Z-coördinaat X-min
Q43 = Q17 * SIN Q27 ;Zcoördinaat X-max
69 LBL 0
70 LBL 99 ;Bewerking einde
71 LBL 0
72 END PGM 3045_NL MM