0 BEGIN PGM 3120_NL MM 
1 ;Programma om een contour te frezen en
2 ;aansluitend aan de bovenkant met een radius
3 ;verder af te ronden. In het voorbeeld is
4 ;een contour als eiland geprogrammeerd. Nadat
5 ;u de benodigde parameters hebt gedefinieerd,
6 ;wordt de contour door de besturing uitgenomen.
7 ;Vervolgens berekent de besturing de
8 ;contourwijzigingen overeenkomstig de
9 ;desbetreffende diepte. Deze gebruikt de
10 ;besturing dan als overmaat aan de zijkant in
11 ;de cyclus om de radius in hoogtelijnen af te
12 ;frezen.
13 ;
14 BLK FORM 0.1 Z X+0 Y+0 Z-20
15 BLK FORM 0.2  X+100  Y+100  Z+0
16 ;
17 ;Parameter-invoer
18 FN 0: Q31 =+15 ;DIEPTE CONTOUR
19 FN 0: Q32 =+5 ;DIEPTE-INSTELLING CONTOURFREZEN
20 FN 0: Q33 =+1200 ;AANZET CONTOURFREZEN
21 FN 0: Q34 =+300 ;AANZET DIEPTEVERPLAATSING
22 FN 0: Q41 =+8 ;AFRONDINGSRADIUS
23 FN 0: Q42 =+0.1 ;DIEPTE-INSTELLING AFFREZEN RADIUS
24 FN 0: Q48 =+3000 ;AANZET FREZEN RADIUS
25 ;Einde parameterinvoer
26 ;
27 ;Gereedschapsoproep schachtfrees
28 TOOL CALL 13 Z S1000
29 ;
30 ;Verplaatsen naar veilige hoogte
31 L  Z+100 R0 FMAX M3
32 ;
33 ;Contour frees
34 CYCL DEF 14.0 CONTOUR
35 CYCL DEF 14.1 CONTOURLABEL1 /2
36 CYCL DEF 20 CONTOURDATA ~
   Q1=-Q31  ;FREESDIEPTE ~
    Q2=+1    ;BAANOVERLAPPING ~
    Q3=+0    ;OVERMAAT ZIJKANT ~
    Q4=+0    ;OVERMAAT DIEPTE ~
    Q5=+0    ;COORD. OPPERVLAK ~
    Q6=+0    ;VEILIGHEIDSAFSTAND ~
    Q7=+0    ;VEILIGE HOOGTE ~
    Q8=+0    ;AFRONDINGSRADIUS ~
    Q9=+1    ;ROTATIERICHTING
37 CYCL DEF 22 UITRUIMEN ~
   Q10=-Q32  ;DIEPTEVERPLAATSING ~
    Q11=+Q34  ;AANZET DIEPTEVERPL. ~
    Q12=+Q33  ;AANZET UITRUIMEN ~
    Q18=+0    ;VOORRUIMGEREEDSCHAP ~
    Q19=+Q33  ;AANZET PENDELEN
38 CYCL CALL M13
39 ;
40 ;Affrezen radius
41 FN 0: Q44 =+Q42
42 LBL 3
43 ;Berekeningen van contourwijziging bij nieuwe diepte
Q43 = Q41 * Q41
Q45 = Q41 - Q42
44 FN 3: Q45 =+Q45 * +Q45
Q43 = Q43 - Q45
Q43 = SQRT Q43
45 FN 2: Q50 =+Q41 - +Q43
46 ;Einde berekeningen
47 ;Definitie cyclus
48 CYCL DEF 14.0 CONTOUR
49 CYCL DEF 14.1 CONTOURLABEL1
50 CYCL DEF 25 CONTOURREEKS ~
   Q1=-Q42  ;FREESDIEPTE ~
    Q3=-Q50  ;OVERMAAT ZIJKANT ~
    Q5=+0    ;COORD. OPPERVLAK ~
    Q7=+2    ;VEILIGE HOOGTE ~
    Q10=-Q42  ;DIEPTEVERPLAATSING ~
    Q11=+Q34  ;AANZET DIEPTEVERPL. ~
    Q12=+Q48  ;AANZET UITRUIMEN ~
    Q15=+1    ;FREESWIJZE
51 CYCL CALL M13
52 ;
53 FN 1: Q42 =+Q42 + +Q44 ;Diepte actualiseren
54 ;Vergelijking of er nu nog andere banen nodig zijn
55 FN 12: IF +Q42 LT +Q41 GOTO LBL 3
56 FN 9: IF +Q42 EQU +Q41 GOTO LBL 3
57 ;
58 ;Vrijzetten en programma-einde
59 L  Z+100 R0 FMAX M30
60 ;
61 ;Subprogramma's contouren
62 LBL 1 ; PGM-CONTOUR
63 L  X+5  Y+30 RL
64 CC  X+15  Y+30
65 C  X+6.645  Y+35.495 DR-
66 CT  X+55.505  Y+69.488
67 CT  X+58.995  Y+30.025
68 CT  X+19.732  Y+21.191
69 CT  X+5  Y+30
70 LBL 0
71 ;
72 LBL 2 ;PGM-frame
73 L  X-30  Y-20 RR
74 L  Y+120
75 L  X+120
76 L  Y-20
77 L  X-30
78 LBL 0
79 END PGM 3120_NL MM