0 BEGIN PGM 4040_NL MM 
1 BLK FORM 0.1 Z X-100 Y-100 Z-100
2 BLK FORM 0.2  X+100  Y+100  Z+0
3 ;Ronde tap frezen
4 ;Gereedschapsoproep
5 TOOL CALL 10 Z S3000 F800
6 L  X+0  Y+0  Z+100 R0 FMAX M3
7 CYCL DEF 257 RONDE TAP ~
   Q223=+200  ;DIAMETER EINDPRODUCT ~
    Q222=+283  ;DIAMETER RUWDEEL ~
    Q368=+0    ;OVERMAAT ZIJKANT ~
    Q207= AUTO ;AANZET FREZEN ~
    Q351=+1    ;FREESWIJZE ~
    Q201=-80   ;DIEPTE ~
    Q202=+5    ;DIEPTEVERPLAATSING ~
    Q206= AUTO ;AANZET DIEPTEVERPL. ~
    Q200=+2    ;VEILIGHEIDSAFSTAND ~
    Q203=+0    ;COORD. OPPERVLAK ~
    Q204=+50   ;2E VEILIGHEIDSAFST. ~
    Q370=+1    ;BAANOVERLAPPING
8 M99
9 L  Z+100 R0 FMAX M5
10 ;Sleuven op cilindermantel frezen
11 ;Gereedschapsoproep
12 TOOL CALL 2 Z S5000 F500
13 ;Naar een veilige positie verplaatsen om de A-as te zwenken
14 L  X+0  Y+0 R0 FMAX M3
15 M140 MB MAX F5000
16 ;A-as zwenken
17 PLANE AXIAL  A-90 TURN FMAX
18 CALL LBL "Bewerking"
19 LBL "Loop"
20 ;Incrementele beweging van de C-as
21 PLANE AXIAL IC+10 TURN FMAX
22 CALL LBL "Bewerking"
23 ;Herhaling van de cyclus
24 CALL LBL "Loop" REP34
25 M140 MB MAX F5000
26 PLANE RESET TURN FMAX
27 M30 ;Einde programma
28 ;Subprogramma
29 LBL "Bewerking"
30 ;Bewerkingscyclus
31 ;Belangrijk Coördinaten oppervlak = radius van de cilinder!!!
32 CYCL DEF 253 SLEUFFREZEN ~
   Q215=+0    ;BEWERKINGSOMVANG ~
    Q218=+20   ;SLEUFLENGTE ~
    Q219=+5    ;SLEUFBREEDTE ~
    Q368=+0    ;OVERMAAT ZIJKANT ~
    Q374=+100  ;ROTATIEPOSITIE ~
    Q367=+0    ;SLEUF POSITIE ~
    Q207=+500  ;AANZET FREZEN ~
    Q351=+1    ;FREESWIJZE ~
    Q201=-5    ;DIEPTE ~
    Q202=+5    ;DIEPTEVERPLAATSING ~
    Q369=+0    ;OVERMAAT DIEPTE ~
    Q206=+150  ;AANZET DIEPTEVERPL. ~
    Q338=+0    ;VERPLAATSING NABEW. ~
    Q200=+2    ;VEILIGHEIDSAFSTAND ~
    Q203=+100  ;COORD. OPPERVLAK ~
    Q204=+50   ;2E VEILIGHEIDSAFST. ~
    Q366=+0    ;INSTEKEN ~
    Q385=+500  ;AANZET NABEWERKEN
33 ;Positie met cyclusoproep
34 L  X+0  Y+25 R0 FMAX M99
35 LBL 0
36 END PGM 4040_NL MM