0  BEGIN PGM 4225_NL MM 
1  ;Programma om meerdere bewerkingen die op
2  ;een rechte liggen, met schuin ingesteld
3  ;gereedschap uit te voeren.
4  ;In dit voorbeeld worden eerst kamers met
5  ;een frees gefreesd om een vlak te maken.
6  ;In een tweede bewerking worden haaks op
7  ;het basisvlak van de kamer gaten geboord.
8  ;Vervolgens moet u alle noodzakelijke
9  ;parameters definiëren. Ook de
10 ;gereedschapsgegevens en eventueel de
11 ;cycli moet u aanpassen.
12 ;BELANGRIJK! Het programma is gemaakt voor
13 ;machines die voor het zwenken van het
14 ;bewerkingsvlak met ruimtehoeken zijn
15 ;ingesteld. Als uw machine alleen met
16 ;ashoeken werkt, moet u ook de invoer in
17 ;cyclus 19 wijzigen. Ook moet de besturing
18 ;voor het zwenken van het bewerkingsvlak
19 ;naar een machineafhankelijke, veilige
20 ;positie verplaatsen, zodat er bij het
21 ;verplaatsen van de rondassen geen
22 ;botsing plaatsvindt.
23 ;
24 BLK FORM 0.1 Z X+0 Y+0 Z-30
25 BLK FORM 0.2  X+100  Y+100  Z+0
26 ;
27 ;Parameterinvoer
28 ;Positie van de boringen
29 FN 0: Q10 =+15 ;COÖRDINAAT 1E BORING IN X
30 FN 0: Q11 =+15 ;COÖRDINAAT 1E BORING IN Y
31 FN 0: Q12 =+10 ;AFSTAND VAN DE BORINGEN IN
32 ;              ;DE X-AS
33 FN 0: Q13 =+10 ;AFSTAND VAN DE BORINGEN IN
34 ;              ;DE Y-AS
35 FN 0: Q14 =+8 ;AANTAL BORINGEN
36 FN 0: Q15 =+30 ;RUIMTEHOEK A VAN DE BEWERKING
37 FN 0: Q16 =+0 ;RUIMTEHOEK B VAN DE BEWERKING
38 FN 0: Q17 =-150 ;RUIMTEHOEK C VAN DE BEWERKING
39 ;Parameters voor frezen van de kamer
40 FN 0: Q2 =+3 ;DIEPTE VAN DE KAMER
41 FN 0: Q3 =+8 ;DIAMETER VAN DE KAMER
42 FN 0: Q18 =+400 ;AANZET KAMER FREZEN
43 ;Parameters voor het boren
44 FN 0: Q4 =+20 ;DIEPTE BORING
45 FN 0: Q19 =+500 ;AANZET BOREN
46 ;Einde parameterinvoer
47 ;
48 ;Berekeningen
49 FN 2: Q1 =+Q14 - +2 ;Aantal herhalingen
50 ;Einde berekeningen
51 ;
52 M3
53 ;Gereedschapsoproep stiftfrees voor centrering
54 TOOL CALL 2 Z S2000 F300
55 ;Subprogramma-oproep voor reset
56 CALL LBL 10
57 ;Cyclus voor het maken van een
58 ;eindvlak/centrering
59 CYCL DEF 252 RONDKAMER ~
    Q215=+0    ;BEWERKINGSOMVANG ~
    Q223=+Q3   ;CIRKEL DIAMETER ~
    Q368=+0    ;OVERMAAT ZIJKANT ~
    Q207=+Q18  ;AANZET FREZEN ~
    Q351=+1    ;FREESWIJZE ~
    Q201=-Q2   ;DIEPTE ~
    Q202=+5    ;DIEPTEVERPLAATSING ~
    Q369=+0    ;OVERMAAT DIEPTE ~
    Q206=+Q18  ;AANZET DIEPTEVERPL. ~
    Q338=+0    ;VERPLAATSING NABEW. ~
    Q200=+2    ;VEILIGHEIDSAFSTAND ~
    Q203=+0    ;COORD. OPPERVLAK ~
    Q204=+50   ;2E VEILIGHEIDSAFST. ~
    Q370=+1    ;BAANOVERLAPPING ~
    Q366=+1    ;INSTEKEN ~
    Q385=+500  ;AANZET NABEWERKEN
60 ;Subprogramma-oproep voor positionering en bewerking
61 CALL LBL 3
62 ;Vrijzetten
63 L  Z+50 F2222
64 ;
65 ;Gereedschapsoproep boor
66 TOOL CALL 227 Z S1000 F300
67 ;Definitie boorcyclus
68 CYCL DEF 200 BOREN ~
    Q200=+5    ;VEILIGHEIDSAFSTAND ~
    Q201=-Q4   ;DIEPTE ~
    Q206=+Q19  ;AANZET DIEPTEVERPL. ~
    Q202=+5    ;DIEPTEVERPLAATSING ~
    Q210=+0    ;STILSTANDSTIJD BOVEN ~
    Q203=+0    ;COORD. OPPERVLAK ~
    Q204=+50   ;2E VEILIGHEIDSAFST. ~
    Q211=+0    ;STILSTANDSTIJD ONDER ~
    Q395=+0    ;REF. DIEPTE
69 ;Subprogramma-oproep voor positionering en bewerking
70 CALL LBL 3
71 ;Vrijzetten en programma-einde
72 L  Z+50 F2222 M30
73 ;
74 ;Subprogramma voor positionering en bewerking
75 LBL 3
76 ;Nulpuntverschuiving naar de eerste bewerking
77 CYCL DEF 7.0 NULPUNT
78 CYCL DEF 7.1  Y+Q10
79 CYCL DEF 7.2  X+Q11
80 ;Zwenken van het bewerkingsvlak
81 CYCL DEF 19.0 BEWERKINGSVLAK
82 CYCL DEF 19.1  A+Q15  B+Q16  C+Q17
83 ;Veilige positie benaderen
84 M140 MB MAX F9999
85 ;Positioneren van de rondassen
86 L  A+Q120  B+Q121  C+Q122 R0 FMAX
87 ;Benaderen van de eerste bewerkingspositie
88 L  X+0  Y+0  Z+50 R0 FMAX M3
89 ;Cyclusoproep
90 M99
91 ;Herhaling van programmadelen voor de verdere
92 ;bewerkingen
93 LBL 2
94 ;Subprogramma-oproep voor verdere bewerkingen
95 CALL LBL 1
96 ;Oproepen van de herhalingen
97 CALL LBL 2 REPQ1
98 ;Vrijzetten
99 M140 MB MAX F9999
100 ;Subprogramma-oproep voor reset
101 CALL LBL 10
102 ;Terugzwenken van de rondassen
103 L  A+Q120  B+Q121  C+Q122 R0 FMAX
104 ;Nulpuntverschuiving resetten
105 CYCL DEF 7.0 NULPUNT
106 CYCL DEF 7.1  Y+0
107 CYCL DEF 7.2  X+0
108 LBL 0
109 ;
110 ;Subprogramma voor verdere bewerkingen
111 LBL 1
112 ;Subprogramma-oproep voor reset
113 CALL LBL 10
114 ;Nulpuntverschuiving incrementeel naar
115 ;de volgende positie
116 CYCL DEF 7.0 NULPUNT
117 CYCL DEF 7.1 IX+Q12
118 CYCL DEF 7.2 IY+Q13
119 ;Bewerkingsvlak zwenken
120 CYCL DEF 19.0 BEWERKINGSVLAK
121 CYCL DEF 19.1  A+Q15  B+Q16  C+Q17
122 ;Bewerkingspositie benaderen
123 L  X+0  Y+0  Z+50 R0 FMAX
124 ;Cyclusoproep
125 M99
126 ;Subprogramma-oproep voor reset
127 CALL LBL 10
128 LBL 0
129 ;
130 ;Subprogramma voor reset
131 LBL 10
132 ;Bewerkingsvlak terugzwenken
133 CYCL DEF 19.0 BEWERKINGSVLAK
134 CYCL DEF 19.1  A+0  B+0  C+0
135 ;Bewerkingsvlak zwenken deselecteren
136 CYCL DEF 19.0 BEWERKINGSVLAK
137 CYCL DEF 19.1
138 ;Reset maatfactor
139 CYCL DEF 11.0 MAATFACTOR
140 CYCL DEF 11.1 SCL 1
141 ;Reset rotatie
142 CYCL DEF 10.0 ROTATIE
143 CYCL DEF 10.1  ROT+0
144 LBL 0
145 END PGM 4225_NL MM