0 BEGIN PGM 42301_NL MM 
1 ;NC-programma voor berekening en bewerking van
2 ;de transportschroef.
3 ;Bovendien is in het programmadeel "SUBLOOP" de
4 ;contour in het vlak X/Y geprogrammeerd. Omdat het
5 ;in dit geval om een contour gaat die uit drie
6 ;dezelfde gedeeltes bestaat, is deze eenmaal
7 ;geprogrammeerd en vervolgens twee keer 120
8 ;graden geroteerd herhaald.
9 ;Om de ondersnijdingen bij het werkstuk te kunnen
10 ;maken, moet het gereedschap nog worden ingesteld.
11 ;Hiervoor gebruikt u de functie TCPM; hierbij blijft
12 ;het coördinatensysteem ongewijzigd. Maar bij het
13 ;verplaatsen van de rondassen houdt de besturing
14 ;rekening met de kinematica en gebruikt het
15 ;Tool Center Point, in dit geval het midden van de
16 ;kogelfrees, op de geprogrammeerde.
17 ;De compensatiebewegingen van de C-as die bij de
18 ;cirkelbanen van de contour in dit programma
19 ;geprogrammeerd zijn, zijn zo geselecteerd dat er
20 ;geen beschadigingen van de contour ontstaan.
21 ;
22 ;Programmabegin
Q10 = Q9 ;Actuele diepte
Q12 = Q2 / Q1 ;Rotatie per millimeter diepte
Q20 = 5 + Q108 + Q7 ;Eerste radius inclusief gereedschapsradius en overmaat
Q30 = Q6 - ( ( Q6 - ( 25 + Q20 ) ) / 2 ) ;Cirkelmiddelpunt voor voorzichtig benaderen
23 PLANE RESET STAY ;Zwenken resetten
24 L  Z+Q5 R0 FMAX M3 ;Veilige hoogte benaderen
25 FUNCTION TCPM F TCP AXIS SPAT PATHCTRL AXIS ;Funktie TCPM activeren
26 CC  X+0  Y+0 ;Cirkelmiddelpunt voor het voorpositioneren
27 LP  PR+Q6  PA+0 R0 FMAX ;Voorpositioneren
28 L  B+Q4  A+0  C+0 R0 FMAX ;Invalshoek van de B-as benaderen
29 ;
30 ;Spronglabel voor herhaling
31 LBL "MAINLOOP"
Q11 = Q10 * Q12 ;Actuele rotatie berekenen
32 ;
33 ;Coördinatensyst. roteren
34 CYCL DEF 10.0 DREHUNG
35 CYCL DEF 10.1  ROT+Q11
36 ;
37 L  C+Q11 R0 FMAX ;Compensatiebeweging van de C-as
38 L  Z+Q10 R0 FMAX ;Nieuwe Z-coördinaten benaderen
39 CC  X+0  Y+0 ;Middelpunt voor voorpositionering
40 LP  PR+Q6  PA+0 R0 FMAX ;Op een veilige radius voorpositioneren
41 CC  X+Q30  Y+0 ;Cirkelmiddelpunt voor benaderingsbeweging
42 CP  PA+180 DR- F AUTO ;Benaderingsbeweging
43 CC  X+25  Y+0 ;Cirkelmiddelpunt radius 5
44 ;
45 ;Herhaling van programmadelen
46 ;waarin de contour is beschreven
47 LBL "SUBLOOP"
48 CP  PA+123.5 IC+33.5 DR+
49 CC  X+15.82  Y+13.86
50 CP IPA-102.6 IC+29.3 DR-
51 CC  X-23.05  Y-1.02
52 CP IPA+44.1 IC+48.8 DR+
53 CYCL DEF 10.0 DREHUNG
54 CYCL DEF 10.1 IROT+120
55 CC  X+25  Y+0
56 CP  PA+0 IC+8.4 DR+
57 CALL LBL "SUBLOOP" REP2
58 ;
59 CC  X+Q30  Y+0 ;Cirkelmiddelpunt voor vrijzetbeweging
60 CP  PA+0 DR- F AUTO ;Naar veilige positie verplaatsen
61 L  Z+Q5 R0 FMAX ;Naar veilige hoogte verplaatsen
62 LBL 0
63 ;
Q10 = Q10 + Q3 ;Nieuwe Z-coördinaat berekenen
64 FN 11: IF +Q10 GT +Q1 GOTO LBL "MAINLOOP" ;Vergelijking of diepte is bereikt en eventueel sprong
65 FN 0: Q10 =+Q1 ;Y-coördinaat gelijk aan diepte
66 ;Sprong naar contourfrezen
67 CALL LBL "MAINLOOP"
68 L  B+0  C+0  A+0 R0 FMAX M5 ;Alle rondassen terugzwenken
69 FUNCTION RESET TCPM ;Functie TCPM resetten
70 ;Einde programma
71 END PGM 42301_NL MM