0 BEGIN PGM 4240_nl MM 
1 ;NC-programma voor het bewerken van 
2 ;vier werkstukken met een opspanpiramide.
3 ;Op elk van de werkstukken, met de
4 ;afmetingen 60*60*60mm, freest de
5 ;besturing een afkanting van 5*45 graden.
6 ;De bewerking vindt plaats met een
7 ;gezwenkte stiftfrees.
8 ;
9 ;De werkstukken zijn onder een hoek van
10 ;45 graden op een opspanpiramide gespannen.
11 ;
12 ;De werkstukken zijn als volgt gerangschikt:
13 ;Werkstuk 1 -> PRESET 6 --> Voor
14 ;Werkstuk 2 -> PRESET 7 --> Rechts
15 ;Werkstuk 3 -> PRESET 8 --> Achter
16 ;Werkstuk 4 -> PRESET 9 --> Links
17 ;
18 ;De bewerking van het werkstuk is in het
19 ;subprogramma "MACHINING" geprogrammeerd.
20 ;Dit subprogramma werkt de besturing bij
21 ;elke preset, met een gewijzigde hoek voor
22 ;de uitlijning, af.
23 ;Het is belangrijk dat de hoeken voor de
24 ;uitlijning van de opspanpiramide in de
25 ;parameters QR170, QR171 en QR172 zijn
26 ;vastgelegd.
27 ;In het subprogramma "MACHINING" is eerst
28 ;het gereedschap gedefinieerd. Vervolgens
29 ;roept de besturing voor elk te frezen
30 ;oppervlak een LBL "TILT..." en LBL "MILL"
31 ;op.
32 ;In de subprogramma's "TILT..." is de
33 ;nulpuntverschuiving en het zwenken van
34 ;het bewerkingsvlak voor de desbetreffende
35 ;bewerking aan het werkstukcoördinatensysteem
36 ;gerelateerd, gedefinieerd.
37 ;Vervolgens roept de besturing LBL "TILT_NEW"
38 ;op.
39 ;In dit subprogramma berekent de besturing
40 ;vervolgens op basis van de hoek voor het
41 ;uitlijnen van de spanpositie, van de
42 ;nulpuntverschuiving en van het zwenken van het
43 ;bewerkingsvlak de resulterende ruimtehoek en
44 ;de nulpuntverschuiving en activeert deze.
45 ;Daarna wordt de bewerking uitgevoerd die in
46 ;LBL "MILL" is geprogrammeerd.
47 ;
48 * -Definitie van zijde 1 VOOR
49 CYCL DEF 247 REF.PUNT VASTL. ~
   Q339=+6    ;REF.PUNT-NUMMER
50 ;SPA uitgelijnd = QR170
QR170 = 45
51 ;SPB uitgelijnd = QR171
QR171 = 0
52 ;SPC uitgelijnd = QR172
QR172 = 0
53 CALL LBL "MACHINING"
54 ;
55 * -Definitie van zijde 2 RECHTS
56 CYCL DEF 247 REF.PUNT VASTL. ~
   Q339=+7    ;REF.PUNT-NUMMER
57 ;SPA uitgelijnd = QR170
QR170 = 45
58 ;SPB uitgelijnd = QR171
QR171 = 0
59 ;SPC uitgelijnd = QR172
QR172 = 90
60 CALL LBL "MACHINING"
61 ;
62 * -Definitie van zijde 3 ACHTER
63 CYCL DEF 247 REF.PUNT VASTL. ~
   Q339=+8    ;REF.PUNT-NUMMER
64 ;SPA uitgelijnd = QR170
QR170 = 45
65 ;SPB uitgelijnd = QR171
QR171 = 0
66 ;SPC uitgelijnd = QR172
QR172 = 180
67 CALL LBL "MACHINING"
68 ;
69 * -Definitie van zijde 4 LINKS
70 CYCL DEF 247 REF.PUNT VASTL. ~
   Q339=+9    ;REF.PUNT-NUMMER
71 ;SPA uitgelijnd = QR170
QR170 = 45
72 ;SPB uitgelijnd = QR171
QR171 = 0
73 ;SPC uitgelijnd = QR172
QR172 = 270
74 CALL LBL "MACHINING"
75 ;
76 ;Alle coördinatenomrekeningen terugzetten
77 CALL LBL "RESET"
78 ;
79 ;Einde programma
80 M30
81 ;
82 ;Subprogramma's
83 * - BEWERKING
84 LBL "MACHINING"
85 * - Vlak frezen 45
86 TOOL CALL "D16" Z S9000 F2000
87 CALL LBL "SAFE"
88 CALL LBL "TILT1"
89 CALL LBL "MILL"
90 CALL LBL "TILT2"
91 CALL LBL "MILL"
92 CALL LBL "TILT3"
93 CALL LBL "MILL"
94 CALL LBL "TILT4"
95 CALL LBL "MILL"
96 LBL 0
97 ;
98 * - Frezen
99 LBL "MILL"
100 L  X-20  Y+5  Z+50 R0 FMAX
101 L  Z+5 R0 FMAX
102 L  Z+0 R0 F2000
103 APPR LT  X+0  Y-1 LEN10 RL F AUTO
104 L  X+60
105 DEP LT LEN10
106 L  Z+50 R0 FMAX
107 LBL 0
108 ;
109 * - Zwenken 0 graden
110 LBL "TILT0"
111 PLANE RESET STAY
112 CYCL DEF 7.0 NULPUNT
113 CYCL DEF 7.1  X+0
114 CYCL DEF 7.2  Y+0
115 CYCL DEF 7.3  Z+0
116 CALL LBL "SAFE"
117 PLANE SPATIAL SPA+0 SPB+0 SPC+0 STAY SEQ-
118 ;Omrekenen naar vlak
119 CALL LBL "TILT_NEW"
120 LBL 0
121 ;
122 * - Zwenken 1
123 LBL "TILT1"
124 PLANE RESET STAY
125 CYCL DEF 7.0 NULPUNT
126 CYCL DEF 7.1  X-30
127 CYCL DEF 7.2  Y-30
128 CYCL DEF 7.3  Z-5
129 CALL LBL "SAFE"
130 PLANE SPATIAL SPA+45 SPB+0 SPC+0 STAY SEQ-
131 ;Omrekenen naar vlak
132 CALL LBL "TILT_NEW"
133 LBL 0
134 ;
135 * - Zwenken 2
136 LBL "TILT2"
137 PLANE RESET STAY
138 CYCL DEF 7.0 NULPUNT
139 CYCL DEF 7.1  X+30
140 CYCL DEF 7.2  Y-30
141 CYCL DEF 7.3  Z-5
142 CALL LBL "SAFE"
143 PLANE SPATIAL SPA+45 SPB+0 SPC+90 STAY SEQ-
144 ;Omrekenen naar vlak
145 CALL LBL "TILT_NEW"
146 LBL 0
147 ;
148 * - Zwenken 3
149 LBL "TILT3"
150 PLANE RESET STAY
151 CYCL DEF 7.0 NULPUNT
152 CYCL DEF 7.1  X+30
153 CYCL DEF 7.2  Y+30
154 CYCL DEF 7.3  Z-5
155 CALL LBL "SAFE"
156 PLANE SPATIAL SPA+45 SPB+0 SPC+180 STAY SEQ-
157 ;Omrekenen naar vlak
158 CALL LBL "TILT_NEW"
159 LBL 0
160 ;
161 * - Zwenken 4
162 LBL "TILT4"
163 PLANE RESET STAY
164 CYCL DEF 7.0 NULPUNT
165 CYCL DEF 7.1  X-30
166 CYCL DEF 7.2  Y+30
167 CYCL DEF 7.3  Z-5
168 CALL LBL "SAFE"
169 PLANE SPATIAL SPA+45 SPB+0 SPC+270 STAY SEQ-
170 ;Omrekenen naar vlak
171 CALL LBL "TILT_NEW"
172 LBL 0
173 ;
174 * - Veilige hoogte
175 LBL "SAFE"
176 M3
177 L  Z+300 R0 FMAX M91
178 L  X+400  Y-300 R0 FMAX M91
179 LBL 0
180 ;
181 * - Terugzetten van alle coördinatenomrekeningen
182 LBL "RESET"
183 CALL LBL "SAFE"
184 PLANE RESET TURN FMAX
185 CYCL DEF 7.0 NULPUNT
186 CYCL DEF 7.1  X+0
187 CYCL DEF 7.2  Y+0
188 CYCL DEF 7.3  Z+0
189 CYCL DEF 8.0 SPIEGELEN
190 CYCL DEF 8.1
191 CYCL DEF 10.0 ROTATIE
192 CYCL DEF 10.1  ROT+0
193 CYCL DEF 11.0 MAATFACTOR
194 CYCL DEF 11.1 SCL 1
195 LBL 0
196 ;
197 * - Omrekening van de hoeken
198 LBL "TILT_NEW"
199 ;Uitlezen 3D-ROT
200 FN 18: SYSREAD Q170 = ID210 NR5 IDX1 ;3D-ROT SPA
201 FN 18: SYSREAD Q171 = ID210 NR5 IDX2 ;3D-ROT SPB
202 FN 18: SYSREAD Q172 = ID210 NR5 IDX3 ;3D-ROT SPC
203 PLANE RESET STAY
204 ;Uitlezen nulpuntverschuiving
205 FN 18: SYSREAD Q175 = ID220 NR2 IDX1 ;NPV X
206 FN 18: SYSREAD Q176 = ID220 NR2 IDX2 ;NPV Y
207 FN 18: SYSREAD Q177 = ID220 NR2 IDX3 ;NPV Z
208 ;Uitlijning zwenken
209 CYCL DEF 7.0 NULPUNT
210 CYCL DEF 7.1  X+0
211 CYCL DEF 7.2  Y+0
212 CYCL DEF 7.3  Z+0
213 PLANE SPATIAL SPA+QR170 SPB+QR171 SPC+QR172 STAY
214 ;Nulpuntverschuiving op het ingestelde vlak
215 CYCL DEF 7.0 NULPUNT
216 CYCL DEF 7.1 IX+Q175
217 CYCL DEF 7.2 IY+Q176
218 CYCL DEF 7.3 IZ+Q177
219 ;Uitgelezen 3D-ROT erop zwenken
220 PLANE RELATIV SPC+Q172 STAY
221 PLANE RELATIV SPB+Q171 STAY
222 CALL LBL "SAFE"
223 PLANE RELATIV SPA+Q170 TURN FMAX SEQ-
224 LBL 0
225 END PGM 4240_nl MM