0 BEGIN PGM 50051_NL MM 
1 ;Programma om een ronde tap te bewerken en
2 ;vervolgens het oppervlak schuin af te
3 ;frezen.
4 ;
5 ;Gereedschapsoproep
6 TOOL CALL 15 Z S4000 F300
7 ;
8 L  Z+100 R0 FMAX M3 ;Naar veilige hoogte verplaatsen
9 L  X+Q7  Y+Q8 R0 FMAX ;Voorpositioneren
10 FN 3: Q80 =+Q1 * +2 ;Berekening van de diameter
11 ;Definitie ronde tap
12 CYCL DEF 257 KREISZAPFEN ~
   Q223=+Q80  ;FERTIGTEIL-DURCHM. ~
    Q222=+141  ;ROHTEIL-DURCHMESSER ~
    Q368=+0    ;AUFMASS SEITE ~
    Q207=+600  ;VORSCHUB FRAESEN ~
    Q351=+1    ;FRAESART ~
    Q201=-50   ;TIEFE ~
    Q202=+10   ;ZUSTELL-TIEFE ~
    Q206=+3000 ;VORSCHUB TIEFENZ. ~
    Q200=+2    ;SICHERHEITS-ABST. ~
    Q203=+0    ;KOOR. OBERFLAECHE ~
    Q204=+50   ;2. SICHERHEITS-ABST. ~
    Q370=+1    ;BAHN-UEBERLAPPUNG ~
    Q376=+0    ;STARTWINKEL
13 M99
14 L  X+Q7  Y+Q8  Z+100 R0 FMAX
15 ;Nulpunt naar het midden van de tap
16 ;schuiven. Z-verschuiving naar de positie
17 ;waarmee het bewerkingsvlak wordt gezwenkt.
18 CYCL DEF 7.0 NULLPUNKT
19 CYCL DEF 7.1  Z+Q9
20 CYCL DEF 7.2  X+Q7
21 CYCL DEF 7.3  Y+Q8
22 ;Bewerkingsvlak zwenken
23 CYCL DEF 19.0 BEARBEITUNGSEBENE
24 CYCL DEF 19.1  A+Q11  B+0  C+0
25 ;Rondassen naar positie verplaatsen
26 L  A+Q120  B+Q121  C+Q122 R0 FMAX
27 ;Cyclus voor eindvlakbewerking definiëren
28 CYCL DEF 232 PLANFRAESEN ~
   Q389=+2    ;STRATEGIE ~
    Q225=-Q1   ;STARTPUNKT 1. ACHSE ~
    Q226=-60   ;STARTPUNKT 2. ACHSE ~
    Q227=+40   ;STARTPUNKT 3. ACHSE ~
    Q386=+0    ;ENDPUNKT 3. ACHSE ~
    Q218=+Q80  ;1. SEITEN-LAENGE ~
    Q219=+120  ;2. SEITEN-LAENGE ~
    Q202=+5    ;MAX. ZUSTELL-TIEFE ~
    Q369=+0    ;AUFMASS TIEFE ~
    Q370=+1    ;MAX. UEBERLAPPUNG ~
    Q207=+600  ;VORSCHUB FRAESEN ~
    Q385=+500  ;VORSCHUB SCHLICHTEN ~
    Q253= MAX ;VORSCHUB VORPOS. ~
    Q200=+2    ;SICHERHEITS-ABST. ~
    Q357=+2    ;SI.-ABSTAND SEITE ~
    Q204=+50   ;2. SICHERHEITS-ABST.
29 M99
30 M140 MB MAX F9999 ;Vrijzetten
31 ;Bewerkingsvlak zwenken opheffen
32 CYCL DEF 19.0 BEARBEITUNGSEBENE
33 CYCL DEF 19.1  A+0  B+0  C+0
34 CYCL DEF 19.0 BEARBEITUNGSEBENE
35 CYCL DEF 19.1
36 ;Rondassen op nul terugzetten
37 L  A+Q120  B+Q121  C+Q122 R0 FMAX
38 ;Nulpuntverschuiving opheffen
39 CYCL DEF 7.0 NULLPUNKT
40 CYCL DEF 7.1  X+0
41 CYCL DEF 7.2  Y+0
42 CYCL DEF 7.3  Z+0
43 END PGM 50051_NL MM