0 BEGIN PGM 5005_NL MM 
1 ;Programma om een tap of een boring op een schuin
2 ;oppervlak met een vormfrees af te bramen.
3 ;De bewerking vindt plaats in de drie lineaire assen,
4 ;zonder het bewerkingsvlak te zwenken. Als eerste moet
5 ;u alle benodigde parameters definiëren. Daarna volgt
6 ;in dit programma een programma-oproep om het werkstuk
7 ;voor te frezen. In het opgeroepen programma dient u
8 ;eventueel ook wijzigingen aan te brengen. Na de
9 ;programma-oproep definieert u het gereedschap waarmee
10 ;het afbramen moet worden uitgevoerd. De besturing
11 ;positioneert het gereedschap dan op de startpositie.
12 ;Vervolgens berekent de besturing de coördinaten voor de
13 ;afzonderlijke assen en benadert deze dan.
14 ;Daarna berekent de besturing telkens het volgende punt
15 ;met zijn X-, Y- en Z-coördinaat en benadert deze. Dit
16 ;wordt zo vaak herhaald totdat de eindhoek is bereikt.
17 ;In hoeveel punten de bewerking opgedeeld wordt, definieert
18 ;u met de parameter VERDELING.
19 ;
20 ;Belangrijk! De besturing berekent de gereedschapsbaan zo,
21 ;dat het gereedschapsmiddelpunt de gedefinieerde radius
22 ;volgt.
23 ;
24 BLK FORM 0.1 Z X+0 Y+0 Z-60
25 BLK FORM 0.2  X+100  Y+100  Z+0
26 ;
27 ;Invoer parameter
28 FN 0: Q1 =+50 ;RADIUS
29 FN 0: Q3 =+0 ;STARTHOEK
30 FN 0: Q4 =+360 ;EINDHOEK
31 FN 0: Q7 =+50 ;CIRKELMIDDELPUNT X
32 FN 0: Q8 =+50 ;CIRKELMIDDELPUNT Y
33 FN 0: Q9 =-20 ;CIRKELMIDDELPUNT Z
34 FN 0: Q11 =+10 ;INVALSHOEK MET A
35 FN 0: Q12 =-2 ;FREESDIEPTE
36 FN 0: Q13 =+0 ;ROTATIE
37 FN 0: Q20 =+50 ;AANZET DIEPTEVERPLAATSING
38 FN 0: Q21 =+500 ;AANZET FREZEN
39 FN 0: Q25 =+5 ;VEILIGE POSITIE Z
40 FN 0: Q26 =+360 ;VERDELING
41 ;Einde parameterinvoer
42 ;
43 ;Onbewerkt werkstuk frezen
44 CALL PGM 50051_nl.h
45 ;
46 ;Gereedschapsoproep afbraamgereedschap
47 TOOL CALL 170 Z S3000
48 ;
49 L  Z+100 R0 F9998 M3 ;Naar veilige hoogte verplaatsen
50 CC  X+Q7  Y+Q8 ;Cirkelmiddelpunt definiëren
51 LP  PR+Q1  PA+Q3 ;Naar startpunt verplaatsen
52 L  Z+Q25 ;Voorpositioneren in Z
53 CALL LBL 10 ;Oproep van de bewerking
54 ;
55 L  Z+100 R0 F9998 M2 ;Vrijzetten en programma-einde
56 ;
57 ;Subprogramma's voor bewerking
58 LBL 10
59 ;Nulpunt naar het midden van de bewerking verschuiven
60 CYCL DEF 7.0 NULLPUNKT
61 CYCL DEF 7.1  X+Q7
62 CYCL DEF 7.2  Y+Q8
63 CYCL DEF 7.3  Z+Q9
64 ;Gedefinieerde rotatie activeren
65 CYCL DEF 10.0 DREHUNG
66 CYCL DEF 10.1  ROT+Q13
67 FN 0: Q36 =+Q3 ;Actuele hoek gelijk aan starthoek
68 FN 2: Q35 =+Q4 - +Q3 ;Openingshoek
69 FN 4: Q35 =+Q35 DIV +Q26 ;Hoekstap
Q38 = TAN Q11 ;Invalshoek omrekenen
70 FN 0: Q46 =+0 ;Teller
71 CALL LBL 2 ;Berekening oproepen
72 L  X+Q41  Y+Q42 R0 FQ20 M3 ;eerste punt in X en Y benaderen
73 L  Z+Q43 R0 FQ20 ;eerste punt in Z benaderen
74 LBL 1 ;Herhalingen
75 FN 1: Q36 =+Q36 + +Q35 ;Nieuwe hoek berekenen
76 FN 1: Q46 =+Q46 + +1 ;Teller cycli
77 CALL LBL 2 ;Berekeningen oproepen
78 L  X+Q41  Y+Q42  Z+Q43 FQ21 ;Nieuw punt naderen
79 FN 12: IF +Q46 LT +Q26 GOTO LBL 1 ;Teller vergelijken
80 ;Rotatie terugzetten
81 CYCL DEF 10.0 DREHUNG
82 CYCL DEF 10.1  ROT+0
83 ;Nulpuntverschuiving terugzetten
84 CYCL DEF 7.0 NULLPUNKT
85 CYCL DEF 7.1  X+0
86 CYCL DEF 7.2  Y+0
87 CYCL DEF 7.3  Z+0
88 LBL 0 ;Terugsprong
89 ;
90 LBL 2 ;Berekeningen
91 FN 7: Q31 = COS +Q36 ;Nieuwe X-coördinaat berekenen
92 FN 3: Q31 =+Q31 * +Q1 ;Nieuwe X-coördinaat berekenen
93 FN 3: Q41 =+Q31 * +1 ;Nieuwe X-coördinaat berekenen
94 FN 6: Q32 = SIN +Q36 ;Nieuwe Y-coördinaat berekenen
95 FN 3: Q32 =+Q32 * +Q1 ;Nieuwe Y-coördinaat berekenen
96 FN 3: Q42 =+Q32 * +1 ;Nieuwe Y-coördinaat berekenen
97 FN 3: Q43 =+Q42 * +Q38 ;Nieuwe Z-coördinaat berekenen
98 FN 1: Q43 =+Q43 + +Q12 ;Nieuwe Z-coördinaat berekenen
99 LBL 0
100 END PGM 5005_NL MM