0 BEGIN PGM 5025_NL MM 
1 ;Programma om een boring die in een rechte hoek
2 ;ten opzichte van de cilinderas is geboord, op
3 ;het cilindermantelvlak met een vormfrees af te
4 ;bramen.
5 ;De bewerking vindt plaats in de drie lineaire
6 ;assen, zonder het bewerkingsvlak te zwenken.
7 ;Als eerste moet u alle benodigde parameters
8 ;definiëren. Daarna volgt in dit programma een
9 ;programmadeel uit de gereedschapsoproep,
10 ;positionering en bewerkingscyclus om de boring
11 ;te maken.
12 ;Ook in dit programmadeel moeten alle parameters
13 ;worden vastgelegd, omdat de hiervoor beschreven
14 ;parameters alleen voor het afbramen actief zijn.
15 ;Na het bewerken van de boring definieert u het
16 ;gereedschap waarmee het afbramen moet worden
17 ;uitgevoerd. Vervolgens berekent de besturing de
18 ;coördinaten voor de afzonderlijke assen en
19 ;benadert deze dan.
20 ;Daarna berekent de besturing telkens het
21 ;volgende punt met zijn X-, Y- en Z-coördinaat
22 ;en benadert deze. Dit wordt net zo vaak herhaald
23 ;totdat het startpunt weer is bereikt.
24 ;In hoeveel punten de bewerking opgedeeld wordt,
25 ;definieert u met de parameter VERDELING.
26 ;Belangrijk! De besturing berekent de baanbeweging
27 ;voor het gereedschapsmiddelpunt. Met de parameter
28 ;VERSPRINGING GEREEDSCHAPSMIDDELPUNT TEN OPZICHTE
29 ;VAN RADIUS (Q7) definieert u hoever het midden
30 ;van het gereedschap van de rand van de boring
31 ;wordt verplaatst. Daarbij moet rekening worden
32 ;gehouden met het voorteken; bij een positieve
33 ;waarde wordt de middelpuntsbaan groter dan de
34 ;radius, bij een negatieve waarde kleiner.
35 ;
36 ;
37 ;Parameterinvoer
38 FN 0: Q3 =+100 ;RADIUS CILINDER
39 FN 0: Q4 =+100 ;VERDELING
40 FN 0: Q5 =+3 ;DIEPTE POSITIEF OPGEVEN
41 FN 0: Q1 =+0 ;MIDDELPUNT BORING IN X
42 FN 0: Q6 =+60 ;RADIUS BORING
43 FN 0: Q7 =-0.5 ;VERSPRINGING GEREEDSCHAPSMIDDELPUNT TEN OPZICHTE VAN RADIUS
44 FN 0: Q10 =+20 ;VEILIGHEIDSAFSTAND
45 FN 0: Q11 =+1000 ;AANZET DIEPTEVERPLAATSING
46 FN 0: Q12 =+2000 ;AANZET FREZEN
47 ;Einde parameterinvoer
48 ;
49 BLK FORM CYLINDER X RQ3 L200 DIST+100
50 ;
51 ;Nulpunt naar het midden van de boring en het
52 ;cilinderoppervlak verschuiven
53 CYCL DEF 7.0 NULLPUNKT
54 CYCL DEF 7.1  X+Q1
55 CYCL DEF 7.2  Z+Q3
56 ;
57 ;Gereedschapsoproep voor de boring
58 TOOL CALL 8 Z S3000 F800
59 ;
60 L  Z+100 R0 FMAX M3 ;Naar veilige hoogte verplaatsen
61 L  X+0  Y+0 R0 FMAX ;Midden van de boring benaderen
62 L  Z+Q10 R0 FMAX ;Naar veiligheidsafstand verplaatsen
63 FN 3: Q80 =+Q6 * +2 ;Berekening diameter boring
64 ;Cyclus voor de boring
65 CYCL DEF 252 KREISTASCHE ~
   Q215=+0    ;BEARBEITUNGS-UMFANG ~
    Q223=+Q80  ;KREISDURCHMESSER ~
    Q368=+0    ;AUFMASS SEITE ~
    Q207= AUTO ;VORSCHUB FRAESEN ~
    Q351=+1    ;FRAESART ~
    Q201=-100  ;TIEFE ~
    Q202=+10   ;ZUSTELL-TIEFE ~
    Q369=+0    ;AUFMASS TIEFE ~
    Q206=+300  ;VORSCHUB TIEFENZ. ~
    Q338=+0    ;ZUST. SCHLICHTEN ~
    Q200=+2    ;SICHERHEITS-ABST. ~
    Q203=+0    ;KOOR. OBERFLAECHE ~
    Q204=+50   ;2. SICHERHEITS-ABST. ~
    Q370=+1    ;BAHN-UEBERLAPPUNG ~
    Q366=+1    ;EINTAUCHEN ~
    Q385=+500  ;VORSCHUB SCHLICHTEN
66 M99
67 L  Z+100 R0 FMAX ;Vrijzetten
68 ;
69 ;Gereedschapsoproep voor het afbramen
70 TOOL CALL 170 Z S12000
71 ;
72 L  Z+100 R0 FMAX M3 ;Naar veilige hoogte verplaatsen
73 CALL LBL 1 ;Bewerking oproepen
74 ;
75 ;Vrijzetten en programma-einde
76 L  Z+100 R0 FMAX M30
77 ;
78 ;Subprogramma's voor de bewerking
79 LBL 1
80 FN 0: Q23 =+Q5 ;eerste diepte gelijk aan nominale diepte
81 FN 0: Q24 =+0 ;Teller
82 FN 1: Q26 =+Q6 + +Q7 ;Verrekening freesverspringing
83 FN 0: Q27 =+0 ;Starthoek
84 FN 4: Q37 =+360 DIV +Q4 ;Hoekstap
85 CALL LBL 10 ;Oproep berekeningen
86 L  X+Q21  Y+Q22 FMAX ;Eerste positie benaderen
87 L  Z+Q10 R0 FMAX ;Naar veiligheidsafstand verplaatsen
88 L  Z-Q23 FQ11 ;Naar diepte verplaatsen
89 LBL 2 ;Herhalingen
90 FN 1: Q24 =+Q24 + +1 ;Teller actualiseren
91 FN 1: Q27 =+Q27 + +Q37 ;Hoek actualiseren
92 CALL LBL 10 ;Oproep berekeningen
93 L  X+Q21  Y+Q22  Z-Q23 FQ12 ;Nieuwe positie benaderen
94 FN 12: IF +Q24 LT +Q4 GOTO LBL 2 ;Vergelijking of het aantal herhalingen bereikt is
95 LBL 0
96 LBL 10 ;Berekeningen
Q21 = Q26 * COS Q27 ;Nieuwe X-positie
Q22 = Q26 * SIN Q27 ;Nieuwe Y-positie
Q23 = Q3 - ( SQRT ( Q3 * Q3 - Q22 * Q22 ) ) + Q5 ;Nieuwe Z-positie
97 LBL 0
98 END PGM 5025_NL MM