0 BEGIN PGM 5080-NL MM 
1 ;In dit programma worden een rechthoekige
2 ;tap en een rechthoekige kamer, evenals
3 ;een ronde tap en een rondkamer bewerkt
4 ;en vervolgens wordt met een schuin
5 ;gereedschap rondom een afkanting aan de
6 ;contouren gefreesd. De bewerking van de
7 ;contouren is in het hoofdprogramma
8 ;geprogrammeerd, voor de afkantingen
9 ;roept u bij elk een ander programma op
10 ;waarin u de desbetreffende parameters
11 ;moet invoeren.
12 ;
13 BLK FORM 0.1 Z X+0 Y+0 Z-20
14 BLK FORM 0.2  X+200  Y+100  Z+2
15 ;Gereedschapsoproep
16 TOOL CALL 12 Z S6121 F4591
17 TOOL DEF 8
18 CYCL DEF 232 VLAKFREZEN ~
   Q389=+2    ;STRATEGIE ~
    Q225=+0    ;STARTPUNT 1E AS ~
    Q226=+0    ;STARTPUNT 2E AS ~
    Q227=+2    ;STARTPUNT 3E AS ~
    Q386=+0    ;EINDPUNT 3E AS ~
    Q218=+200  ;LENGTE 1E ZIJKANT ~
    Q219=+100  ;LENGTE 2E ZIJKANT ~
    Q202=+5    ;MAX. DIEPTESTAP ~
    Q369=+0    ;OVERMAAT DIEPTE ~
    Q370=+1    ;MAX. OVERLAPPING ~
    Q207= AUTO ;AANZET FREZEN ~
    Q385= AUTO ;AANZET NABEWERKEN ~
    Q253= MAX ;AANZET VOORPOS. ~
    Q200=+2    ;VEILIGHEIDSAFSTAND ~
    Q357=+2    ;VEIL.AFST. KANT ~
    Q204=+50   ;2E VEILIGHEIDSAFST.
19 CYCL CALL M3
20 ;
21 ;Gereedschapsoproep
22 TOOL CALL 8 Z S9549 F2578
23 ;Buitencontour met SL-cyclus frezen
24 CYCL DEF 14.0 CONTOUR
25 CYCL DEF 14.1 CONTOURLABEL1 /2 /3
26 CYCL DEF 20 CONTOURDATA ~
   Q1=-15   ;FREESDIEPTE ~
    Q2=+1    ;BAANOVERLAPPING ~
    Q3=+0    ;OVERMAAT ZIJKANT ~
    Q4=+0    ;OVERMAAT DIEPTE ~
    Q5=+0    ;COORD. OPPERVLAK ~
    Q6=+2    ;VEILIGHEIDSAFSTAND ~
    Q7=+50   ;VEILIGE HOOGTE ~
    Q8=+0    ;AFRONDINGSRADIUS ~
    Q9=+1    ;ROTATIERICHTING
27 CYCL DEF 22 UITRUIMEN ~
   Q10=-7.5  ;DIEPTEVERPLAATSING ~
    Q11= AUTO ;AANZET DIEPTEVERPL. ~
    Q12= AUTO ;AANZET UITRUIMEN ~
    Q18=+0    ;VOORRUIMGEREEDSCHAP ~
    Q19=+2063 ;AANZET PENDELEN ~
    Q208=+99999 ;AANZET TERUGTREKKEN
28 CYCL CALL M3
29 ;
30 ;Kamers frezen
31 CYCL DEF 251 RECHTHOEKIGE KAMER ~
   Q215=+0    ;BEWERKINGSOMVANG ~
    Q218=+50   ;LENGTE 1E ZIJKANT ~
    Q219=+40   ;LENGTE 2E ZIJKANT ~
    Q220=+10   ;HOEKRADIUS ~
    Q368=+0    ;OVERMAAT ZIJKANT ~
    Q224=+0    ;ROTATIEPOSITIE ~
    Q367=+0    ;POSITIE KAMER ~
    Q207= AUTO ;AANZET FREZEN ~
    Q351=+1    ;FREESWIJZE ~
    Q201=-15   ;DIEPTE ~
    Q202=+8    ;DIEPTEVERPLAATSING ~
    Q369=+0    ;OVERMAAT DIEPTE ~
    Q206=+2063 ;AANZET DIEPTEVERPL. ~
    Q338=+0    ;VERPLAATSING NABEW. ~
    Q200=+2    ;VEILIGHEIDSAFSTAND ~
    Q203=+0    ;COORD. OPPERVLAK ~
    Q204=+50   ;2E VEILIGHEIDSAFST. ~
    Q370=+1    ;BAANOVERLAPPING ~
    Q366=+1    ;INSTEKEN ~
    Q385=+500  ;AANZET NABEWERKEN
32 L  X+150  Y+50 R0 FMAX M3 M99
33 ;
34 CYCL DEF 252 RONDKAMER ~
   Q215=+0    ;BEWERKINGSOMVANG ~
    Q223=+50   ;CIRKEL DIAMETER ~
    Q368=+0    ;OVERMAAT ZIJKANT ~
    Q207= AUTO ;AANZET FREZEN ~
    Q351=+1    ;FREESWIJZE ~
    Q201=-15   ;DIEPTE ~
    Q202=+8    ;DIEPTEVERPLAATSING ~
    Q369=+0    ;OVERMAAT DIEPTE ~
    Q206=+2063 ;AANZET DIEPTEVERPL. ~
    Q338=+0    ;VERPLAATSING NABEW. ~
    Q200=+2    ;VEILIGHEIDSAFSTAND ~
    Q203=+0    ;COORD. OPPERVLAK ~
    Q204=+50   ;2E VEILIGHEIDSAFST. ~
    Q370=+1    ;BAANOVERLAPPING ~
    Q366=+1    ;INSTEKEN ~
    Q385=+500  ;AANZET NABEWERKEN
35 L  X+50  Y+50 R0 FMAX M3 M99
36 ;
37 TOOL CALL 8 Z S9549 F2500
38 M3
39 ;Nulpuntverschuiving op midden cirkel 
40 CYCL DEF 7.0 NULPUNT
41 CYCL DEF 7.1  X+50
42 CYCL DEF 7.2  Y+50
43 ;Oproep programma Afkantingen cirkel
44 CALL PGM 50801-nl.h
45 ;Nulpuntverschuiving naar midden rechthoek
46 CYCL DEF 7.0 NULPUNT
47 CYCL DEF 7.1  X+150
48 CYCL DEF 7.2  Y+50
49 ;Oproep programma Afkanting rechthoek
50 CALL PGM 50802-nl.h
51 CYCL DEF 7.0 NULPUNT
52 CYCL DEF 7.1  X+0
53 CYCL DEF 7.2  Y+0
54 CYCL DEF 7.3  Z+0
55 ;
56 M30 ;Einde van programma
57 ;Subprogramma's
58 ;Buitencontour
59 LBL 1
60 L  X-20  Y-20 RL
61 L  X+220
62 L  Y+120
63 L  X-20
64 L  Y-20
65 LBL 0
66 ;Contour ronde tap
67 LBL 2
68 CC  X+50  Y+50
69 LP  PR+35  PA+0 RL
70 CP IPA-360 DR-
71 LBL 0
72 ;Contour rechthoekige tap
73 LBL 3
74 CC  X+150  Y+50
75 LP  PR+35  PA+0 RL
76 L  Y+20
77 RND R15
78 L IX-70
79 RND R15
80 L  Y+80
81 RND R15
82 L IX+70
83 RND R15
84 L  Y+50
85 LBL 0
86 END PGM 5080-NL MM