BEGIN PGM 50801-NL MM 
;Programma Afkanting cirkel
;Parameter 1e afkanting
Q1 = 3 ;AFKANTINGSLENGTE
Q2 = 30 ;AFKANTINGSHOEK
Q3 = 70 ;CIRKELDIAMETER
Q4 = 2 ;BEWERKING 1=BINNEN 2=BUITEN
TOOL CALL  DL-0.5 ;Overloop om een gladde onderkant van de afkanting te krijgen
;Afkanting bewerken
CALL LBL "afkanting"
;
;Zwenkassen resetten
PLANE RESET MOVE DIST20 FMAX
;
;Parameter 2e Afkanting
Q1 = 3 ;AFKANTINGSLENGTE
Q2 = 30 ;AFKANTINGSHOEK
Q3 = 50 ;CIRKELDIAMETER
Q4 = 1 ;BEWERKING 1=BINNEN 2=BUITEN
;
;Afkanting bewerken
CALL LBL "afkanting"
;
;Zwenkassen resetten
PLANE RESET MOVE DIST20 FMAX
;
;Sprong naar programma-einde
FN 9: IF +0 EQU +0 GOTO LBL "end"
;
;
;Bewerking
LBL "afkanting"
;Vraag buiten of binnen
FN 9: IF +Q4 EQU +1 GOTO LBL "binnen"
FN 9: IF +Q4 EQU +2 GOTO LBL "buiten"
STOP
;Q4 selecteren buiten of binnen
;
LBL "binnen"
FUNCTION TCPM F CONT AXIS SPAT PATHCTRL VECTOR ;Functie TCPM activeren
Q10 = Q108 * ( COS Q2 ) ;Bereken gereedschapscorrectie radius
Q11 = ( Q3 / 2 ) - Q10 ;Diameter - Gereedschapscorrectie radius
Q12 = ( Q1 / TAN Q2 ) - ( SIN Q2 * Q108 ) ;Gereedschapscorrectie Z
QL11 = Q11 - Q108 ;Benaderingspositie Y
QL12 = Q12 - 2 ;Benaderingspositie Z
L  X-Q108  Y-QL11  Z+50 R0 FMAX
L  A+Q2  B+0  C+0 R0 FMAX ;Belangrijk alle drie roterende assen vanwege TCPM... AXIS SPAT
L  Z-QL12 R0 F AUTO
CC  X+0  Y-QL11
CP  PA-90  Z-Q12 DR+
CC  X+0  Y+0
CP IPA+90 IC+90 DR+ F AUTO
CP IPA+90 IC+90 DR+
CP IPA+90 IC+90 DR+
CP IPA+90 IC+90 DR+
CC  X+0  Y-QL11
CP  PA+0  Z-QL12 DR+
L IZ+20
FN 9: IF +0 EQU +0 GOTO LBL "reset"
;
LBL "buiten"
FUNCTION TCPM F CONT AXIS SPAT PATHCTRL VECTOR
Q10 = Q108 * ( COS Q2 ) ;Bereken gereedschapscorrectie radius
Q11 = ( Q3 / 2 ) + Q10 ;Diameter + gereedschapscorrectie radius
Q12 = ( Q1 / TAN Q2 ) - ( SIN Q2 * Q108 ) ;Gereedschapscorrectie Z
QL11 = Q11 + Q108 ;Benaderingspositie Y
QL12 = Q12 - 2 ;Benaderingspositie Z
L  X+Q108  Y-QL11  Z+50 R0 FMAX
L  A-Q2  B+0  C+0 R0 FMAX ;Belangrijk alle drie roterende assen vanwege TCPM... AXIS SPAT
L  Z-QL12 R0 F AUTO
CC  X+0  Y-QL11
CP IPA+90  Z-Q12 DR+
CC  X+0  Y+0
CP IPA-90 IC-90 DR- F AUTO
CP IPA-90 IC-90 DR-
CP IPA-90 IC-90 DR-
CP IPA-90 IC-90 DR-
CC  X+0  Y-QL11
CP  PA+180  Z-QL12 DR+
L IZ+20
;
LBL "reset"
FUNCTION RESET TCPM
LBL 0
LBL "end"
END PGM 50801-NL MM