0 BEGIN PGM 50802-NL MM 
1 ;Programma Afkanting rechthoek
2 ;Parameter 1e afkanting
Q1 = 3 ;AFKANTINGSLENGTE
Q2 = 30 ;AFKANTINGSHOEK
Q13 = 50 ;LENGTE X
Q3 = 40 ;BREEDTE Y
Q5 = 10 ;HOEKRADIUS
Q4 = 1 ;BEWERKING 1=BINNEN 2=BUITEN
3 TOOL CALL  DL-0.5 ;Overloop om een gladde onderkant van de afkanting te krijgen
4 ;
5 ;Afkanting bewerken
6 CALL LBL "afkanting"
7 ;
8 ;Zwenkassen resetten
9 PLANE RESET MOVE DIST20 FMAX
10 ;
11 ;Parameter 2e afkanting
Q1 = 3 ;AFKANTINGSLENGTE
Q2 = 30 ;AFKANTINGSHOEK
Q13 = 70 ;LENGTE X
Q3 = 60 ;BREEDTE Y
Q5 = 15 ;HOEKRADIUS
Q4 = 2 ;BEWERKING 1=BINNEN 2=BUITEN
12 TOOL CALL  DL-0.5 ;Overloop om een gladde onderkant van de afkanting te krijgen
13 ;
14 ;Afkanting bewerken
15 CALL LBL "afkanting"
16 ;
17 ;Zwenkassen resetten
18 PLANE RESET MOVE DIST20 FMAX
19 ;
20 ;Sprong naar programma-einde
21 FN 9: IF +0 EQU +0 GOTO LBL "end"
22 ;
23 ;
24 ;Bewerking
25 LBL "afkanting"
26 ;Vraag buiten of binnen
27 FN 9: IF +Q4 EQU +1 GOTO LBL "binnen"
28 FN 9: IF +Q4 EQU +2 GOTO LBL "buiten"
29 STOP
30 ;Q4 selecteren buiten of binnen
31 ;
32 LBL "binnen"
33 FUNCTION TCPM F CONT AXIS SPAT PATHCTRL VECTOR ;Functie TCPM activeren
34 FN 11: IF +Q5 GT +0 GOTO LBL "radius"
Q5 = Q108
35 LBL "radius"
Q10 = Q108 * ( COS Q2 ) ;Bereken gereedschapscorrectie radius
Q11 = ( Q3 / 2 ) - Q10 ;Breedte Y - Gereedschapscorrectie radius
Q21 = ( Q3 / 2 ) - Q5 ;MIDDEN CC Y
Q31 = ( Q13 / 2 ) - Q5 ;MIDDEN CC X
Q12 = ( Q1 / TAN Q2 ) - ( SIN Q2 * Q108 ) ;Gereedschapscorrectie Z
QL11 = Q11 - Q108 ;Benaderingspositie Y
QL12 = Q12 - 2 ;Benaderingspositie Z
36 L  X-Q108  Y-QL11  Z+50 R0 FMAX
37 L  A+Q2  B+0  C+0 R0 FMAX ;Belangrijk alle drie roterende assen vanwege TCPM... AXIS SPAT
38 L  Z-QL12 R0 F AUTO
39 CC  X+0  Y-QL11
40 CP  PA-90  Z-Q12 DR+
41 L  X+Q31
42 CC  X+Q31  Y-Q21
43 CP IPA+90 IC+90 DR+
44 L  Y+Q21
45 CC  X+Q31  Y+Q21
46 CP IPA+90 IC+90 DR+
47 L  X-Q31
48 CC  X-Q31  Y+Q21
49 CP IPA+90 IC+90 DR+
50 L  Y-Q21
51 CC  X-Q31  Y-Q21
52 CP IPA+90 IC+90 DR+
53 L  X+0
54 CC  X+0  Y-QL11
55 CP  PA+0  Z-QL12 DR+
56 L IZ+20
57 M140 MB+50
58 FN 9: IF +0 EQU +0 GOTO LBL "reset"
59 ;
60 LBL "buiten"
61 FUNCTION TCPM F CONT AXIS SPAT PATHCTRL VECTOR
Q10 = Q108 * ( COS Q2 ) ;Bereken gereedschapscorrectie radius
Q11 = ( Q3 / 2 ) + Q10 ;Breedte Y + Gereedschapscorrectie radius
Q12 = ( Q1 / TAN Q2 ) - ( SIN Q2 * Q108 ) ;Gereedschapscorrectie Z
Q21 = ( Q3 / 2 ) - Q5 ;MIDDEN CC Y
Q31 = ( Q13 / 2 ) - Q5 ;MIDDEN CC X
QL11 = Q11 + Q108 ;Benaderingspositie Y
QL12 = Q12 - 2 ;Benaderingspositie Z
62 L  X+Q108  Y-QL11  Z+50 R0 FMAX
63 L  A-Q2  B+0  C+0 R0 FMAX ;Belangrijk alle drie roterende assen vanwege TCPM... AXIS SPAT
64 L  Z-QL12 R0 F AUTO
65 CC  X+0  Y-QL11
66 CP IPA+90  Z-Q12 DR+
67 L  X-Q31
68 CC  X-Q31  Y-Q21
69 CP IPA-90 IC-90 DR-
70 L  Y+Q21
71 CC  X-Q31  Y+Q21
72 CP IPA-90 IC-90 DR-
73 L  X+Q31
74 CC  X+Q31  Y+Q21
75 CP IPA-90 IC-90 DR-
76 L  Y-Q21
77 CC  X+Q31  Y-Q21
78 CP IPA-90 IC-90 DR-
79 L  X+0
80 CC  X+0  Y-QL11
81 CP  PA+180  Z-QL12 DR+
82 L IZ+20
83 M140 MB+50
84 ;
85 LBL "reset"
86 FUNCTION RESET TCPM
87 LBL 0
88 LBL "end"
89 END PGM 50802-NL MM