0 BEGIN PGM 5085-NL MM 
1 ;In dit programma worden, op een gezwenkt vlak,
2 ;een ronde tap en een rondkamer bewerkt en
3 ;vervolgens wordt met een schuin ingesteld
4 ;gereedschap rondom een afkanting op de
5 ;contouren gefreesd. De contouren programmeert u
6 ;met cycli. Voor de afkantingen moet u de
7 ;parameters definiëren waaruit de besturing de
8 ;gereedschapsbanen berekent.
9 ;
10 BLK FORM 0.1 Z X-50 Y-50 Z-40
11 BLK FORM 0.2  X+50  Y+50  Z+10
12 TOOL CALL 8 Z S12000 F5000 ;Frees D16
13 ;Bewerkingsvlak zwenken
14 PLANE SPATIAL SPA+10 SPB+0 SPC+0 TURN MB100 FMAX
15 CYCL DEF 232 VLAKFREZEN ~
   Q389=+1    ;STRATEGIE ~
    Q225=-50   ;STARTPUNT 1E AS ~
    Q226=-60   ;STARTPUNT 2E AS ~
    Q227=+20   ;STARTPUNT 3E AS ~
    Q386=+0    ;EINDPUNT 3E AS ~
    Q218=+100  ;LENGTE 1E ZIJKANT ~
    Q219=+120  ;LENGTE 2E ZIJKANT ~
    Q202=+20   ;MAX. DIEPTESTAP ~
    Q369=+0    ;OVERMAAT DIEPTE ~
    Q370=+1    ;MAX. OVERLAPPING ~
    Q207= AUTO ;AANZET FREZEN ~
    Q385= AUTO ;AANZET NABEWERKEN ~
    Q253= MAX ;AANZET VOORPOS. ~
    Q200=+2    ;VEILIGHEIDSAFSTAND ~
    Q357=+2    ;VEIL.AFST. KANT ~
    Q204=+50   ;2E VEILIGHEIDSAFST.
16 M3 M99
17 CYCL DEF 252 RONDKAMER ~
   Q215=+0    ;BEWERKINGSOMVANG ~
    Q223=+60   ;CIRKEL DIAMETER ~
    Q368=+0    ;OVERMAAT ZIJKANT ~
    Q207=+500  ;AANZET FREZEN ~
    Q351=+1    ;FREESWIJZE ~
    Q201=-10   ;DIEPTE ~
    Q202=+10   ;DIEPTEVERPLAATSING ~
    Q369=+0    ;OVERMAAT DIEPTE ~
    Q206=+150  ;AANZET DIEPTEVERPL. ~
    Q338=+0    ;VERPLAATSING NABEW. ~
    Q200=+2    ;VEILIGHEIDSAFSTAND ~
    Q203=+0    ;COORD. OPPERVLAK ~
    Q204=+50   ;2E VEILIGHEIDSAFST. ~
    Q370=+1    ;BAANOVERLAPPING ~
    Q366=+1    ;INSTEKEN ~
    Q385=+500  ;AANZET NABEWERKEN
18 L  X+0  Y+0 R0 FMAX M3 M99
19 CYCL DEF 257 RONDE TAP ~
   Q223=+100  ;DIAMETER EINDPRODUCT ~
    Q222=+142  ;DIAMETER RUWDEEL ~
    Q368=+0    ;OVERMAAT ZIJKANT ~
    Q207=+500  ;AANZET FREZEN ~
    Q351=+1    ;FREESWIJZE ~
    Q201=-10   ;DIEPTE ~
    Q202=+10   ;DIEPTEVERPLAATSING ~
    Q206=+3000 ;AANZET DIEPTEVERPL. ~
    Q200=+2    ;VEILIGHEIDSAFSTAND ~
    Q203=+0    ;COORD. OPPERVLAK ~
    Q204=+50   ;2E VEILIGHEIDSAFST. ~
    Q370=+1    ;BAANOVERLAPPING ~
    Q376=-1    ;STARTHOEK
20 L  X+0  Y+0 R0 FMAX M3 M99
21 ;
22 * - Parameter afkanting
Q1 = 5 ;AFKANTINGSLENGTE
Q2 = 45 ;AFKANTINGSHOEK
Q3 = 100 ;CIRKELDIAMETER
Q4 = 1 ;BEWERKING: 1=BUITEN 2=BINNEN
23 TOOL CALL  DL-0.5 ;Overloop om een zuivere onderkant van de afkanting te verkrijgen
24 CALL LBL "afkanting"
25 PLANE SPATIAL SPA+10 SPB+0 SPC+0 TURN MB100 FMAX
26 ;
27 * - Parameter afkanting
Q1 = 5 ;AFKANTINGSLENGTE
Q2 = 45 ;AFKANTINGSHOEK
Q3 = 60 ;CIRKELDIAMETER
Q4 = 2 ;BEWERKING: 1=BUITEN 2=BINNEN
28 TOOL CALL  DL-0.5 ;Overloop om een zuivere onderkant van de afkanting te verkrijgen
29 CALL LBL "afkanting"
30 ;
31 M2
32 LBL "afkanting"
33 ;Vraag buiten of binnen
34 FN 9: IF +Q4 EQU +2 GOTO LBL "binnen"
35 FN 9: IF +Q4 EQU +1 GOTO LBL "buiten"
36 STOP
37 ;Q4 selecteren buiten of binnen
38 ;
39 LBL "binnen"
40 FUNCTION TCPM F TCP AXIS SPAT PATHCTRL VECTOR
Q10 = Q108 * ( COS Q2 ) ;Bereken gereedschapscorrectie radius
Q11 = ( Q3 / 2 ) - Q10 ;Diameter - Gereedschapscorrectie radius
Q12 = ( Q1 / TAN Q2 ) - ( SIN Q2 * Q108 ) ;Gereedschapscorrectie Z
QL11 = Q11 - Q108 ;Benaderingspositie Y
QL12 = Q12 - 2 ;Benaderingspositie Z
41 L  X-Q108  Y-QL11  Z+50 R0 FMAX
42 L  A+Q2  B+0  C+0 R0 FMAX ;Belangrijk alle drie roterende assen vanwege TCPM... AXIS SPAT
43 L  Z-QL12 R0 F AUTO
44 CC  X+0  Y-QL11
45 CP  PA-90  Z-Q12 DR+
QL1 = 270
46 LBL 1
QL1 = QL1 + 1
QL2 = Q11 * COS QL1
QL3 = Q11 * SIN QL1
47 L  X+QL2  Y+QL3 IC+1
48 CALL LBL 1 REP359
49 CC  X+0  Y-QL11
50 CP  PA+0  Z-QL12 DR+
51 M140 MB+20
52 FN 9: IF +0 EQU +0 GOTO LBL "reset"
53 ;
54 LBL "buiten"
55 FUNCTION TCPM F TCP AXIS SPAT PATHCTRL VECTOR
Q10 = Q108 * ( COS Q2 ) ;Bereken WZR-correctie radius
Q11 = ( Q3 / 2 ) + Q10 ;Diameter+ Gereedschapscorrectie radius
Q12 = ( Q1 / TAN Q2 ) - ( SIN Q2 * Q108 ) ;Gereedschapscorrectie Z
QL11 = Q11 + Q108 ;Benaderingspositie Y
QL12 = Q12 - 2 ;Benaderingspositie Z
56 L  X+Q108  Y-QL11  Z+50 R0 FMAX
57 L  A-Q2  B+0  C+0 R0 FMAX ;Belangrijk alle drie roterende assen vanwege TCPM... AXIS SPAT
58 L  Z-QL12 R0 F AUTO
59 CC  X+0  Y-QL11
60 CP IPA+90  Z-Q12 DR+
QL1 = 270
61 LBL 2
QL1 = QL1 - 1
QL2 = Q11 * COS QL1
QL3 = Q11 * SIN QL1
62 L  X+QL2  Y+QL3 IC-1
63 CALL LBL 2 REP359
64 CC  X+0  Y-QL11
65 CP  PA+180  Z-QL12 DR+
66 M140 MB+20
67 ;
68 LBL "reset"
69 FUNCTION RESET TCPM
70 * - Ga naar een veilige positie
71 L  Z+500 R0 FMAX M91
72 L  X+800  Y+600 R0 FMAX M91
73 * - Coördinatensysteem resetten
74 PLANE RESET TURN FMAX
75 LBL 0
76 END PGM 5085-NL MM