0  BEGIN PGM 5100_NL MM 
1  ;Programma om een schuine boring op een
2  ;vlak oppervlak met een vormfrees af te
3  ;bramen.
4  ;De bewerking vindt plaats in de drie
5  ;lineaire assen, zonder het
6  ;bewerkingsvlak te zwenken.
7  ;Als eerste moet u alle benodigde
8  ;parameters definiëren. Daarna volgt in
9  ;dit programma een programma-oproep om
10 ;het werkstuk voor te frezen. In het
11 ;opgeroepen programma dient u eventueel
12 ;ook wijzigingen aan te brengen.
13 ;Na de programma-oproep definieert u het
14 ;gereedschap waarmee het afbramen moet
15 ;worden uitgevoerd. De besturing
16 ;positioneert het gereedschap dan op
17 ;de startpositie. Vervolgens berekent de
18 ;besturing de coördinaten voor de
19 ;afzonderlijke assen en benadert deze
20 ;dan. Daarna berekent de besturing
21 ;telkens het volgende punt met zijn
22 ;X-, Y- en Z-coördinaat en benadert deze.
23 ;Dit wordt zo vaak herhaald totdat de
24 ;eindhoek is bereikt.
25 ;In hoeveel punten de bewerking opgedeeld
26 ;wordt, definieert u met de parameter
27 ;VERDELING.
28 ;Belangrijk! De besturing berekent de
29 ;gereedschapsbaan zo, dat het
30 ;gereedschapsmidden de gedefinieerde radius
31 ;volgt.
32 ;
33 BLK FORM 0.1 Z X+0 Y+0 Z-60
34 BLK FORM 0.2  X+100  Y+100  Z+0
35 ;
36 ;Invoer parameter
37 FN 0: Q1 =+20 ;BORINGSRADIUS
38 FN 0: Q3 =+0 ;STARTHOEK
39 FN 0: Q4 =+360 ;EINDHOEK
40 FN 0: Q7 =+50 ;BORINGSMIDDEN X
41 FN 0: Q8 =+50 ;BORINGSMIDDEN Y
42 FN 0: Q9 =+0 ;COÖRDINATEN OPPERVLAK
43 FN 0: Q11 =+35 ;INVALSHOEK MET A
44 FN 0: Q12 =-2 ;FREESDIEPTE
45 FN 0: Q13 =+0 ;ROTATIE
46 FN 0: Q20 =+50 ;AANZET DIEPTEVERPLAATSING
47 FN 0: Q21 =+500 ;AANZET FREZEN
48 FN 0: Q25 =+5 ;VEILIGE POSITIE Z
49 FN 0: Q26 =+360 ;VERDELING
50 ;Einde parameterinvoer
51 ;
52 ;Onbewerkt werkstuk frezen
53 CALL PGM 51001_nl.h
54 ;
55 ;Gereedschapsoproep afbraamgereedschap
56 TOOL CALL 170 Z S3000
57 ;
58 L  Z+100 R0 F9998 M3 ;Naar veilige hoogte verplaatsen
59 CC  X+Q7  Y+Q8 ;Cirkelmiddelpunt definiëren
60 LP  PR+Q1  PA+Q3 ;Naar startpunt verplaatsen
61 L  Z+Q25 ;Voorpositioneren in Z
62 CALL LBL 10 ;Oproep van de bewerking
63 ;
64 L  Z+100 R0 F9998 M2 ;Vrijzetten en programma-einde
65 ;
66 ;Subprogramma's voor bewerking
67 LBL 10
68 ;Nulpunt naar het midden van de bewerking verschuiven
69 CYCL DEF 7.0 NULPUNT
70 CYCL DEF 7.1  X+Q7
71 CYCL DEF 7.2  Y+Q8
72 CYCL DEF 7.3  Z+Q9
73 ;Gedefinieerde rotatie activeren
74 CYCL DEF 10.0 ROTATIE
75 CYCL DEF 10.1  ROT+Q13
76 FN 0: Q36 =+Q3 ;Actuele hoek gelijk aan starthoek
77 FN 2: Q35 =+Q4 - +Q3 ;Openingshoek
78 FN 4: Q35 =+Q35 DIV +Q26 ;Hoekstap
79 Q38 = COS Q11 ;Invalshoek omrekenen
80 FN 4: Q2 =+Q1 DIV +Q38 ;Y - halve as
81 FN 0: Q46 =+0 ;Teller
82 CALL LBL 2 ;Berekening oproepen
83 L  X+Q41  Y+Q42 R0 FQ20 M3 ;Eerste punt in X en Y benaderen
84 L  Z+Q43 R0 FQ20 ;Eerste punt in Z benaderen
85 LBL 1 ;Herhalingen
86 FN 1: Q36 =+Q36 + +Q35 ;Nieuwe hoek berekenen
87 FN 1: Q46 =+Q46 + +1 ;Teller naar volgende cyclus
88 CALL LBL 2 ;Berekeningen oproepen
89 L  X+Q41  Y+Q42  Z+Q43 FQ21 ;Nieuw punt naderen
90 FN 12: IF +Q46 LT +Q26 GOTO LBL 1 ;Teller vergelijken
91 ;Rotatie terugzetten
92 CYCL DEF 10.0 ROTATIE
93 CYCL DEF 10.1  ROT+0
94 ;Nulpuntverschuiving terugzetten
95 CYCL DEF 7.0 NULPUNT
96 CYCL DEF 7.1  X+0
97 CYCL DEF 7.2  Y+0
98 CYCL DEF 7.3  Z+0
99 LBL 0 ;Terugsprong
100 ;
101 LBL 2 ;Berekeningen
102 FN 7: Q31 = COS +Q36 ;Nieuwe X-coördinaat berekenen
103 FN 3: Q31 =+Q31 * +Q1 ;Nieuwe X-coördinaat berekenen
104 FN 3: Q41 =+Q31 * +1 ;Nieuwe X-coördinaat berekenen
105 FN 6: Q32 = SIN +Q36 ;Nieuwe Y-coördinaat berekenen
106 FN 3: Q32 =+Q32 * +Q2 ;Nieuwe Y-coördinaat berekenen
107 FN 3: Q42 =+Q32 * +1 ;Nieuwe Y-coördinaat berekenen
108 FN 0: Q43 =+Q12 ;Z-coördinaat
109 LBL 0
110 END PGM 5100_NL MM