0  BEGIN PGM 51051_NL MM 
1  ;NC-programma om de gereedschapsbaan voor
2  ;het afbramen van een spiebaan te berekenen.
3  ;Dit NC-programma is zo opgebouwd dat het
4  ;uit een bewerkingsprogramma als cyclus
5  ;wordt opgeroepen. De definitie van de
6  ;benodigde parameters vindt plaats in het
7  ;oproepende bewerkingsprogramma. Zo hoeft
8  ;u in dit NCprogramma geen wijzigingen
9  ;door te voeren.
10 ;
11 FN 18: SYSREAD Q1 = ID270 NR1 IDX1 ;Actuele X-positie uitlezen
12 FN 18: SYSREAD Q2 = ID270 NR1 IDX2 ;Actuele Y-positie uitlezen
13 Q5 = Q203 + ABS Q200 ;Veiligheidsafstand
14 Q6 = Q203 + ABS Q204 ;2e veiligheidsafstand
15 CYCL DEF 7.0 NULPUNT
16 CYCL DEF 7.1 IX+Q1
17 CYCL DEF 7.2 IY+Q2
18 CYCL DEF 10.0 ROTATIE
19 CYCL DEF 10.1 IROT+Q374
20 ;Sleufpositie
21 Q7 = 0
22 FN 9: IF +Q367 EQU +0 GOTO LBL "END"
23 Q7 = ABS Q218 / 2
24 FN 9: IF +Q367 EQU +1 GOTO LBL "END"
25 Q7 = ( ABS Q218 - ABS Q219 ) / 2
26 FN 9: IF +Q367 EQU +2 GOTO LBL "END"
27 Q7 = NEG ( ABS Q218 - ABS Q219 ) / 2
28 FN 9: IF +Q367 EQU +3 GOTO LBL "END"
29 Q7 = NEG ABS Q218 / 2
30 LBL "END"
31 CYCL DEF 7.0 NULPUNT
32 CYCL DEF 7.1 IX+Q7
33 ;
34 Q10 = ( ABS Q218 - ABS Q219 ) / 2 ;X-MIN
35 Q11 = SQRT ( SQ ( Q222 / 2 ) - SQ ( Q219 / 2 ) )
36 Q12 = Q203 - ( Q222 / 2 - Q11 ) - ABS Q201
37 Q13 = Q219 / 2 - Q108
38 L  X+0  Y+0  Z+Q6 R0 FMAX
39 L  Z+Q5 R0 FMAX
40 L  X+0  Y+0  Z+Q12 FQ207
41 APPR LCT  X+0  Y+Q13 R1 FQ207
42 L  X-Q10
43 Q20 = 90 ;Starthoek
44 LBL 1
45 Q20 = Q20 + 1
46 Q21 = - Q10 + COS Q20 * Q13
47 Q22 = SIN Q20 * Q13
48 Q23 = SIN Q20 * Q219 / 2
49 Q11 = SQRT ( SQ ( Q222 / 2 ) - SQ ( Q23 ) )
50 Q12 = Q203 - ( Q222 / 2 - Q11 ) - ABS Q201
51 L  X+Q21  Y+Q22  Z+Q12
52 CALL LBL 1 REP179
53 L  X+Q10
54 Q20 = - 90 ;Starthoek
55 LBL 2
56 Q20 = Q20 + 1
57 Q21 = Q10 + COS Q20 * Q13
58 Q22 = SIN Q20 * Q13
59 Q23 = SIN Q20 * Q219 / 2
60 Q11 = SQRT ( SQ ( Q222 / 2 ) - SQ ( Q23 ) )
61 Q12 = Q203 - ( Q222 / 2 - Q11 ) - ABS Q201
62 L  X+Q21  Y+Q22  Z+Q12
63 CALL LBL 2 REP179
64 L  X+0
65 DEP LCT  X+0  Y+0 R1
66 ;
67 CYCL DEF 7.0 NULPUNT
68 CYCL DEF 7.1  X+0
69 CYCL DEF 7.2  Y+0
70 CYCL DEF 7.3  Z+0
71 CYCL DEF 10.0 ROTATIE
72 CYCL DEF 10.1  ROT+0
73 L  Z+Q6 R0 FMAX
74 END PGM 51051_NL MM