0  BEGIN PGM 7030_NL MM 
1  ;Programma voor de bewerking aan de binnenzijde van
2  ;een object in de vorm van een liggende torus.
3  ;De bewerking wordt uitgevoerd met een kogelfrees
4  ;in hoogtelijnen, zodat de freesbaan in het
5  ;vlak X/Y en de aanzet in vlak X/Z wordt verplaatst.
6  ;
7  ;Parameterinvoer
8  FN 0: Q1 =+50 ;MIDDELPUNT EERSTE AS
9  FN 0: Q2 =+50 ;MIDDELPUNT TWEEDE AS
10 FN 0: Q3 =+25 ;TORUSRADIUS R
11 FN 0: Q4 =+0 ;Z-COÖRDINAAT TORUSMIDDELPUNT
12 FN 0: Q5 =+20 ;TORUSRADIUS r
13 FN 0: Q10 =+20 ;VEILIGE HOOGTE
14 FN 0: Q11 =+90 ;AANTAL HOOGTELIJNEN
15 FN 0: Q14 =+600 ;AANZET FREZEN
16 FN 0: Q15 =+9999 ;AANZET VOORPOSITIONEREN
17 FN 0: Q16 =+300 ;AANZET INSTEKEN
18 ;Einde parameterinvoer
19 ;
20 BLK FORM 0.1 Z X+0 Y+0 Z-30
21 BLK FORM 0.2  X+100  Y+100  Z+0
22 ;
23 ;Gereedschapsoproep kogelfrees
24 TOOL CALL 155 Z S8000
25 TOOL CALL  DL-Q108 ;Lengtecorrectie met kogelradius
26 ;
27 ;Berekeningen
28 FN 2: Q6 =+Q5 - +Q108 ;Gecompenseerde radius
29 FN 1: Q7 =+Q1 + +Q3 ;Coördinaat X torusmiddelpunt
30 FN 4: Q12 =+180 DIV +Q11 ;Hoekstap
31 FN 2: Q13 =+Q11 - +1 ;Aantal herhalingen
32 ;Berekeningen voltooid
33 ;
34 L  X+Q1  Y+Q2 R0 FQ15 M3 ;In het middelpunt voorpositioneren
35 L  Z+Q10 FQ15 ;Verplaatsen naar veilige hoogte
36 CC  Z+Q4  X+Q7 ;Middelpunt vlak X/Z vastleggen
37 LP  PR+Q6  PA-90 R0 FQ16 ;Eerste radius en diepte benaderen
38 CC  X+Q1  Y+Q2 ;Middelpunt vlak X/Y vastleggen
39 CP IPA-360 DR- FQ14 ;Cirkelbaan verplaatsen
40 LBL 1 ;Herhaling
41 CC  Z+Q4  X+Q7 ;Middelpunt vlak X/Z vastleggen
42 CP IPA-Q12 DR- FQ14 ;Hoekstap naderen
43 CC  X+Q1  Y+Q2 ;Middelpunt vlak X/Y vastleggen
44 CP IPA-360 DR- FQ14 ;Cirkelbaan verplaatsen
45 CALL LBL 1 REPQ13 ;Herhaling oproepen
46 L  Z+100 R0 FQ15 M2 ;Vrijzetten en programma-einde
47 END PGM 7030_NL MM