0 BEGIN PGM 7110_nl MM 
1 ;Programma voor bewerking aan buitenzijde
2 ;van een halve bol met een stiftfrees.
3 ;Gefreesd wordt in een X/Z-baan van onder
4 ;naar boven. Deze beweging wordt in
5 ;afzonderlijke lineaire banen opgedeeld.
6 ;Vervolgens wordt het coördinatensysteem
7 ;geroteerd en wordt de volgende baan
8 ;verplaatst.
9 ;Door de gedefinieerde verdelingen worden
10 ;de nauwkeurigheid en de kwaliteit van het
11 ;oppervlak bepaald.
12 ;
13 ;Invoer parameters
14 FN 0: Q1 =+55 ;MIDDELPUNT VAN DE KOGEL OP DE X-AS
15 FN 0: Q2 =+55 ;MIDDELPUNT VAN DE KOGEL OP DE Y-AS
16 FN 0: Q3 =-50 ;MIDDELPUNT VAN DE KOGEL OP DE Z-AS
17 FN 0: Q4 =+50 ;KOGELRADIUS
18 FN 0: Q5 =+60 ;VERDELING IN HET VLAK X/Y
19 ;              ;DEFINIEERT IN HOEVEEL FREESBANEN
20 ;              ;DE 360 GRADEN IN HET VLAK X/Y 
21 ;              ;WORDEN OPGEDEELD
22 FN 0: Q6 =+15 ;VERDELING IN HET VLAK X/Z
23 ;             ;DEFINIEERT IN HOEVEEL LINEAIRE 
24 ;             ;ELEMENTEN DE 3D-BEWEGING OP 
25 ;             ;DE X-, Y- EN Z-AS WORDT VERDEELD
26 FN 0: Q7 =+20 ;ZIJDELINGSE VEILIGHEIDSAFSTAND
27 ;             ;AFSTAND TUSSEN OBJECT EN GEREEDSCHAP
28 ;             ;BIJ HET VOORPOSITIONEREN
29 FN 0: Q8 =+3 ;VEILIGHEIDSAFSTAND IN Z
30 FN 0: Q9 =+2000 ;AANZET VOORPOSITIONEREN
31 FN 0: Q10 =+500 ;AANZET DIEPTEVERPLAATSING
32 FN 0: Q11 =+800 ;AANZET FREZEN
33 ;Einde parameterinvoer
34 ;
35 BLK FORM 0.1 Z X+0 Y+0 Z-55
36 BLK FORM 0.2  X+110  Y+110  Z+0
37 ;
38 ;Gereedschapsoproep schachtfrees
39 TOOL CALL 50 Z S6000
40 ;
41 ;Berekeningen
42 FN 4: Q15 =+360 DIV +Q5 ;Hoekstap vlak X/Y
43 FN 2: Q25 =+Q5 - +1 ;Aantal herhalingen in het vlak X/Y
44 FN 4: Q16 =+90 DIV +Q6 ;Hoekstap vlak X/Z
45 FN 2: Q26 =+Q6 - +1 ;Aantal herhalingen vlak X/Z.
46 FN 1: Q17 =+Q7 + +Q4 ;Positie voor het voorpositioneren
47 FN 1: Q18 =+Q4 + +Q8 ;Veilige positie in Z
48 ;Einde berekeningen
49 ;
50 ;Nulpunt naar het midden van de kogel verschuiven
51 CYCL DEF 7.0 NULLPUNKT
52 CYCL DEF 7.1  X+Q1
53 CYCL DEF 7.2  Y+Q2
54 CYCL DEF 7.3  Z+Q3
55 ;
56 ;Voorpositioneren
57 L  X+Q17  Y+0 R0 FMAX M3
58 L  Z+Q8 R0 FMAX
59 ;
60 L  Y+0  Z+0 R0 FQ10 ;1. Insteken
61 LBL 2
62 CC  Z+0  X+Q108
63 L  Y+0 R0 FQ11
64 LP  PR+Q4  PA+90 R0 FQ11 ;Contour benaderen
65 LBL 3
66 LP IPA-Q16 FQ11 ;Lineaire stap in X/Z-vlak
67 CALL LBL 3 REPQ26 ;Herhaling van lineaire stap
68 L  Z+Q18 R0 FQ9 ;Naar veiligheidsafstand verplaatsen
69 L  X+Q17 R0 FQ9 ;Opnieuw voorpositioneren
70 L  Z+0  Y+0 R0 FQ10
71 ;Coördinatensyst. roteren
72 CYCL DEF 10.0 DREHUNG
73 CYCL DEF 10.1 IROT+Q15
74 CALL LBL 2 REPQ25 ;Herhaling van cirkelbaan
75 ;Coördinatenomrekeningen terugzetten
76 CYCL DEF 10.0 DREHUNG
77 CYCL DEF 10.1  ROT+0
78 CYCL DEF 7.0 NULLPUNKT
79 CYCL DEF 7.1  X+0
80 CYCL DEF 7.2  Y+0
81 CYCL DEF 7.3  Z+0
82 ;Vrijzetten en programma-einde
83 L  Z+100 R0 FMAX M30
84 END PGM 7110_nl MM