0 BEGIN PGM 7120_nl MM 
1 ;Programma voor bewerking aan buitenzijde
2 ;van een halve bol met een kogelfrees. De
3 ;bewerking vindt plaats in een
4 ;spiraalvormige beweging. Deze beweging
5 ;wordt in afzonderlijke lineaire
6 ;bewegingen opgedeeld. De verdelingen
7 ;definiëren in hoeveel lineaire bewegingen
8 ;de baan wordt opgedeeld, en beïnvloeden
9 ;daardoor de nauwkeurigheid.
10 ;
11 BLK FORM 0.1 Z X-35 Y-35 Z-36
12 BLK FORM 0.2  X+35  Y+35  Z+1
13 ;
14 ;Invoer parameters
15 FN 0: Q1 =+0 ;MIDDELPUNT VAN DE KOGEL OP DE X-AS
16 FN 0: Q2 =+0 ;MIDDELPUNT VAN DE KOGEL OP DE Y-AS
17 FN 0: Q3 =-35 ;MIDDELPUNT VAN DE KOGEL OP DE Z-AS
18 FN 0: Q4 =+30 ;VERDELING VERTICAAL
19 ;             ;DEFINIEERT HOEVEEL SPIRAALBANEN 
20 ;             ;VAN 360 GRADEN VAN BOVEN NAAR 
21 ;             ;BENEDEN WORDEN VERPLAATST
22 FN 0: Q5 =+90 ;VERDELING HORIZONTAAL
23 ;             ;DEFINIEERT IN HOEVEEL LINEAIRE 
24 ;             ;BANEN EEN CIRKELBAAN VAN 360 GRADEN 
25 ;             ;WORDT OPGEDEELD.
26 FN 0: Q6 =+35 ;KOGELRADIUS
27 FN 0: Q7 =+90 ;STARTHOEK IN DE VERTICAAL
28 FN 0: Q8 =+0 ;STARTHOEK IN HET X/Y-VLAK
29 FN 0: Q9 =+1 ;ROTATIERICHTING
30 ;            ;+1 = LINKSOM
31 ;            ;-1 = RECHTSOM
32 FN 0: Q10 =+150 ;AANZET DIEPTEVERPLAATSING
33 FN 0: Q11 =+3000 ;AANZET SPIRAALBAAN
34 FN 0: Q12 =+3 ;VEILIGHEIDSAFSTAND
35 FN 0: Q13 =+0 ;OVERMAAT
36 FN 0: Q14 =+8 ;KOGELRADIUS GEREEDSCHAP
37 FN 0: Q17 =+0 ;EINDHOEK IN DE VERTICAAL
38 ;Einde parameterinvoer
39 ;
40 ;Gereedschapsoproep kogelfrees
41 TOOL CALL 159 Z S9000 DL-Q14
42 ;
43 ;Voorpositioneren
44 FN 1: Q18 =+Q12 + +Q14 ;Z-positie berekenen
45 L  X+Q1  Y+Q2 R0 FMAX M3
46 L  Z+Q18 FMAX
47 CALL LBL 1 ;Oproep spiraalbeweging
48 ;
49 ;Einde programma
50 L  Z+100 R0 F9999 M30
51 ;
52 ;Spiraalbeweging
53 LBL 1
Q26 = Q6 + Q13 + Q14 ;Effectieve radius tot het middelpunt van het gereedschap
54 FN 0: Q27 =+Q7 ;Actuele hoek verticaal=starthoek verticaal
55 FN 0: Q28 =+Q8 ;Actuele hoek vlak X/Y=starthoek vlak X/Y
Q37 = ( Q17 - Q7 ) / Q4 / Q5 ;Hoekstap verticaal
Q38 = 360 / Q5 * Q9 ;Hoekstap vlak X/Y
Q39 = Q38 * Q26 ;Stapfactor
56 CALL LBL 10
Q40 = Q39 / Q20 ; ACT. STAPGROOTTE
57 L  X+Q21  Y+Q22  Z+Q23 R0 FQ10 ;Verplaatsen naar 1e positie
58 ;
59 ;Oproep berekeningen, hoekvergelijking en
60 ;aan het einde een baan met volledige cirkel
61 LBL 2
62 CALL LBL 10
63 L  X+Q21  Y+Q22  Z+Q23 FQ11 ;Nieuwe positie benaderen
64 FN 11: IF +Q27 GT +Q17 GOTO LBL 2
65 CC  X+Q1  Y+Q2
66 FN 9: IF +Q9 EQU -1 GOTO LBL 5
67 CP IPA+360 DR+ FQ11 ;Baan met volledige cirkel
68 FN 9: IF +0 EQU +0 GOTO LBL 6 ;Sprong naar terugtrekken en programma-einde
69 ;
70 LBL 5
71 CP IPA-360 DR- FQ11
72 ;
73 LBL 6
74 L  Z+Q18 R0 F5555 ;Vrijzetten
75 LBL 0
76 ;
77 ;Berekening X-,Y-,Z-positie en nieuwe hoeken
78 LBL 10
Q20 = COS Q27 * Q26 + Q13 + 0.0001
Q40 = Q39 / Q20
79 CC  X+Q38  Y+Q40
Q21 = COS Q28 * Q20 + Q1
Q22 = SIN Q28 * Q20 + Q2
Q23 = SIN Q27 * Q26 + Q3
Q27 = Q27 + Q37
Q28 = Q28 + Q40
80 LBL 0
81 END PGM 7120_nl MM