0  BEGIN PGM 8090-nl MM 
1  ;Programma voor het vastleggen van
2  ;cordinatenpunten.
3  ;
4  BLK FORM 0.1 Z  X+0  Y+0  Z-20
5  BLK FORM 0.2  X+100  Y+100  Z+0
6  ;
7  ;Schrijf BeginPGM in het protocol
8  FN 16: F-PRINT TNC:\Database\BeginPGM.A / surface_data.txt
9  ;
10 ;Gereedschapsoproep taster
11 TOOL CALL 501 Z
12 ;
13 ;Voorpositioneren
14 FN 0: Q1 =+0 ;STARTCORDINAAT IN X VOOR HET VOORPOSITIONEREN
15 FN 0: Q2 =+0.5 ;STARTCORDINAAT IN Y
16 LBL 1
17 FN 1: Q1 =+Q1 + +5 ;Nieuwe waarde in X=actuele waarde+stap
18 TCH PROBE 0.0 REFERENTIEVLAK Q3 Z-
19 TCH PROBE 0.1  X+Q1  Y+Q2  Z+5
20 ;
21 ;Schrijf waarden in het protocol
22 FN 16: F-PRINT TNC:\Database\measure.A / surface_data.txt
23 CALL LBL 1 REP18 ;18 herhalingen, laatste cordinaat X+95
24 FN 1: Q2 =+Q2 + +1 ;Stap in Y
25 LBL 2
26 TCH PROBE 0.0 REFERENTIEVLAK Q3 Z-
27 TCH PROBE 0.1  X+Q1  Y+Q2  Z+5
28 ;
29 ;Schrijf waarden in het protocol
30 FN 16: F-PRINT TNC:\Database\measure.A / surface_data.txt
31 FN 2: Q1 =+Q1 - +5 ;Stap in X
32 CALL LBL 2 REP18 ;18 herhalingen, laatste cordinaat X+5
33 FN 1: Q2 =+Q2 + +1 ;Stap in Y
34 CALL LBL 1 REP49 ;49 herhalingen, laatste rij Y+99,5
35 ;
36 ;Schrijf EndPGM in het protocol
37 FN 16: F-PRINT TNC:\Database\ENDPGM.A / surface_data.txt
38 ;
39 ;Einde programma
40 L  Z+100 R0 FMAX M30
41 END PGM 8090-nl MM