0 BEGIN PGM 81902_NL MM 
1 ;NC-programma waarmee een meetcyclus op de
2 ;actuele gereedschapspositie wordt uitgevoerd.
3 ;Dit kan eventueel noodzakelijk zijn wanneer
4 ;de cyclus op bepaalde posities met een
5 ;cyclusoproep moet worden uitgevoerd. Daartoe
6 ;kunt u dit programma in een cyclus12
7 ;definiëren en vervolgens met een CYCL CALL
8 ;of M99 opgeroepen.
9 ;
10 ;Wachten op synchronisatie van NC en PLC,
11 ;zodat de positie definitief is bereikt,
12 ;voordat het programma verder werkt.
13 FN 20: WAIT FOR  SYNC
14 ;
15 ;Uitlezen van de actuele positie van de X-as
16 ;en opslaan van de waarde in Q1
17 FN 18: SYSREAD Q1 = ID270 NR1 IDX1
18 ;
19 ;Uitlezen van de actuele positie van de Y-as
20 ;en opslaan van de waarde in Q2
21 FN 18: SYSREAD Q2 = ID270 NR1 IDX2
22 ;
23 ;Definitie van de meetcyclus op de actuele
24 ;positie.
25 TCH PROBE 421 METEN BORING ~
   Q273=+Q1   ;MIDDEN 1E AS ~
    Q274=+Q2   ;MIDDEN 2E AS ~
    Q262=+25.2 ;NOMINALE DIAMETER ~
    Q325=+0    ;STARTHOEK ~
    Q247=+90   ;HOEKSTAP ~
    Q261=-5    ;MEETHOOGTE ~
    Q320=+0    ;VEILIGHEIDSAFSTAND ~
    Q260=+20   ;VEILIGE HOOGTE ~
    Q301=+0    ;VERPL.VEILIGH.HOOGTE ~
    Q275=+0    ;MAXIMALE MAAT ~
    Q276=+0    ;MINIMALE MAAT ~
    Q279=+0    ;TOLERANTIE 1E MIDD. ~
    Q280=+0    ;TOLERANTIE 2E MIDD. ~
    Q281=+1    ;MEETPROTOCOL ~
    Q309=+0    ;PGM-STOP BIJ FOUT ~
    Q330=+0    ;GEREEDSCHAP ~
    Q423=+4    ;AANTAL KEREN TASTEN ~
    Q365=+1    ;TYPE VERPLAATSING
26 ;
27 ;Openen van de tabel waarin moet worden geschreven
28 FN 26: TABOPEN 81903_nl.pnt
29 ;
30 ;Schrijven van de meetresultaten naar de tabel
31 FN 27: TABWRITE Q0 /"X" = Q151
32 FN 27: TABWRITE Q0 /"Y" = Q152
33 ;
34 ;Teller verder rekenen
Q0 = Q0 + 1
35 END PGM 81902_NL MM