0 BEGIN PGM 8200_NL MM 
1 ;NC-programma waarbij de besturing aan
2 ;de hand van een gemeten coördinaat
3 ;automatisch bepaalt welk NC-programma
4 ;bij het gemeten werkstuk kan worden
5 ;afgewerkt.
6 ;Eerst definieert u de programmapaden
7 ;van de NCprogramma's die moeten worden
8 ;afgewerkt. Daarna ook nog bij welke
9 ;gemeten Z-coördinaat het betreffende
10 ;programma moet worden opgeroepen.
11 ;Verder kunt u een tolerantie
12 ;definiëren waarmee het meetresultaat
13 ;van de opgegeven coördinaat in het
14 ;positieve en negatieve mag afwijken.
15 ;Daarnaast kunt u een aantal
16 ;programmaruns definiëren.
17 ;
18 ;
19 ;Functie om tijdens de programma-afloop
20 ;de programmadefinitie te overspringen
21 FN 9: IF +0 EQU +0 GOTO LBL 201
22 ;
23 ;Definitie van de programma's die
24 ;afhankelijk van het meetresultaat
25 ;moeten worden gebruikt.
26 LBL 11
27 CALL PGM 82005_nl.h ;Programma NR.1
28 LBL 0
29 ;
30 LBL 12
31 CALL PGM 82004_nl.h ;Programma NR.2
32 LBL 0
33 ;
34 LBL 13
35 CALL PGM 82003_nl.h ;Programma NR.3
36 LBL 0
37 ;
38 LBL 14
39 CALL PGM 82002_nl.h ;Programma NR.4
40 LBL 0
41 ;
42 LBL 15
43 CALL PGM 82001_nl.h ;Programma NR.5
44 LBL 0
45 ;
46 LBL 201 ;Programmavoortzetting
47 ;Invoer van de te onderscheiden
48 ;Z-coördinaten
49 ;Z-coördinaat voor programma 1
50 FN 0: Q81 =+25
51 ;Z-coördinaat voor programma 2
52 FN 0: Q82 =+20
53 ;Z-coördinaat voor programma 3
54 FN 0: Q83 =+15
55 ;Z-coördinaat voor programma 4
56 FN 0: Q84 =+10
57 ;Z-coördinaat voor programma 5
58 FN 0: Q85 =+5
59 ;
60 ;Verdere invoer
61 FN 0: Q91 =+1 ;TOLERANTIE VAN DE Z-COÖRDINAAT
62 FN 0: Q94 =+10 ;AANTAL PROGRAMMADEELHERHALINGEN
63 ;
64 LBL 200 ;Begin van de herhaling
65 ;
66 CALL PGM 82006_nl.h ;Programma-oproep palletwissel
67 ;
68 ;Resetten van het bewerkingsvlak zwenken
69 PLANE RESET TURN FMAX
70 ;
71 ;Gereedschapsoproep taster
72 TOOL CALL 500 Z
73 ;
74 ;Referentiepunt activeren
75 CYCL DEF 247 REF.PUNT VASTL. ~
   Q339=+5    ;REF.PUNT-NUMMER
76 ;Midden onderdeel, onderkant werkstuk
77 ;
78 L  X+0  Y+0 R0 F5000 ;Voorpositioneren
79 L  Z+300 ;Naar veilige hoogte verplaatsen
80 ;
81 ;Definitie van de meetcyclus
82 ;!Hier moet u de coördinaten aanpassen!
/83 TCH PROBE 0.0 REFERENTIEVLAK Q90 Z-
84 TCH PROBE 0.1  X+0  Y+0  Z+300
85 ;
86 ;Voor de programmatest wordt hier het
87 ;meetresultaat als waarde ingesteld.
88 ;!BELANGRIJK! Deze NC-regel moet in de
89 ;programmaafloop worden gewist, omdat
90 ;hij anders het werkelijke
91 ;meetresultaat overschrijft!
92 FN 0: Q90 =+15.1
93 ; 
94 ;Automatische selectie welk programma bij
95 ;het meetresultaat past.
96 ;Programma NR.1
97 FN 2: Q31 =+Q81 - +Q91 ;Z-coördinaat - tolerantie
98 FN 11: IF +Q90 GT +Q31 GOTO LBL "PROG_01" ;Wanneer gemeten hoogte groter coördinaat sprong naar "PROG_01"
99 ;
100 ;Programma NR.2
101 FN 2: Q32 =+Q82 - +Q91 ;Z-coördinaat - tolerantie
102 FN 11: IF +Q90 GT +Q32 GOTO LBL "PROG_02" ;Wanneer gemeten hoogte groter coördinaat sprong naar "PROG_02"
103 ;
104 ;Programma NR.3
105 FN 2: Q33 =+Q83 - +Q91 ;Z-coördinaat - tolerantie
106 FN 11: IF +Q90 GT +Q33 GOTO LBL "PROG_03" ;Wanneer gemeten hoogte groter coördinaat sprong naar "PROG_03"
107 ;
108 ;Programma NR.4
109 FN 2: Q34 =+Q84 - +Q91 ;Z-coördinaat - tolerantie
110 FN 11: IF +Q90 GT +Q34 GOTO LBL "PROG_04" ;Wanneer gemeten hoogte groter coördinaat sprong naar "PROG_04"
111 ;
112 ;Programma NR.5
113 FN 2: Q35 =+Q85 - +Q91 ;Z-coördinaat - tolerantie
114 FN 11: IF +Q90 GT +Q35 GOTO LBL "PROG_05" ;Wanneer gemeten hoogte groter coördinaat sprong naar "PROG_05"
115 ;
116 ;Wanneer er geen selectie kon worden gemaakt,
117 ;sprong naar het programma-einde
118 FN 9: IF +0 EQU +0 GOTO LBL "end"
119 ;
120 ;
121 LBL "PROG_01"
122 CALL LBL 1 ;Sprong naar controle van de maximale coördinaat
123 FN 9: IF +0 EQU +0 GOTO LBL "end" ;Sprong naar programma-einde
124 ;
125 LBL "PROG_02"
126 CALL LBL 2 ;Sprong naar controle van de maximale coördinaat
127 FN 9: IF +0 EQU +0 GOTO LBL "end" ;Sprong naar programma-einde
128 ;
129 LBL "PROG_03"
130 CALL LBL 3 ;Sprong naar controle van de maximale coördinaat
131 FN 9: IF +0 EQU +0 GOTO LBL "end" ;Sprong naar programma-einde
132 ;
133 LBL "PROG_04"
134 CALL LBL 4 ;Sprong naar controle van de maximale coördinaat
135 FN 9: IF +0 EQU +0 GOTO LBL "end" ;Sprong naar programma-einde
136 ;
137 LBL "PROG_05"
138 CALL LBL 5 ;Sprong naar controle van de maximale coördinaat
139 FN 9: IF +0 EQU +0 GOTO LBL "end" ;Sprong naar programma-einde
140 ;
141 ;Einde van programma
142 LBL "end"
143 ;
144 LBL 0
145 ;Oproep van de herhaling
146 CALL LBL 200 REPQ94
147 ;Wanneer het aantal herhalingen is bereikt,
148 ;is het programma-einde
149 M30
150 ;
151 ;
152 ;Controle of het meetresultaat ook in het
153 ;positieve bereik binnen de tolerantie ligt.
154 LBL 1 ;Programma Nr.1
155 FN 1: Q41 =+Q81 + +Q91 ;Z-coördinaat + tolerantie
156 FN 11: IF +Q90 GT +Q41 GOTO LBL "end" ;Wanneer gemeten coördinaat groter dan maximum sprong naar het programma-einde
157 CALL LBL 11 ;Sprong naar programmadefinitie
158 LBL 0
159 ;
160 LBL 2 ;Programma Nr.2
161 FN 1: Q42 =+Q82 + +Q91 ;Z-coördinaat + tolerantie
162 FN 11: IF +Q90 GT +Q42 GOTO LBL "end" ;Wanneer gemeten coördinaat groter dan maximum sprong naar het programma-einde
163 CALL LBL 12 ;Sprong naar programmadefinitie
164 LBL 0
165 ;
166 LBL 3 ;Programma Nr.3
167 FN 1: Q43 =+Q83 + +Q91 ;Z-coördinaat + tolerantie
168 FN 11: IF +Q90 GT +Q43 GOTO LBL "end" ;Wanneer gemeten coördinaat groter dan maximum sprong naar het programma-einde
169 CALL LBL 13 ;Sprong naar programmadefinitie
170 LBL 0
171 ;
172 LBL 4 ;Programma Nr.4
173 FN 1: Q44 =+Q84 + +Q91 ;Z-coördinaat + tolerantie
174 FN 11: IF +Q90 GT +Q44 GOTO LBL "end" ;Wanneer gemeten coördinaat groter dan maximum sprong naar het programma-einde
175 CALL LBL 14 ;Sprong naar programmadefinitie
176 LBL 0
177 ;
178 LBL 5 ;Programma Nr.5
179 FN 1: Q45 =+Q85 + +Q91 ;Z-coördinaat + tolerantie
180 FN 11: IF +Q90 GT +Q45 GOTO LBL "end" ;Wanneer gemeten coördinaat groter dan maximum sprong naar het programma-einde
181 CALL LBL 15 ;Sprong naar programmadefinitie
182 LBL 0
183 ;
184 END PGM 8200_NL MM