0  BEGIN PGM 8205_NL MM 
1  ;NC-programma om op meerdere punten
2  ;de Z-coördinaat te meten en de
3  ;coördinaten van het laagste punt
4  ;in een flag te schrijven. Vervolgens
5  ;benadert de besturing de X/Y-positie
6  ;van het laagste punt en stelt daar
7  ;het Z-referentiepunt in.
8  ;De posities waarop de besturing de
9  ;Z-coördinaat moet meten, definieert
10 ;u in een tabel. Aan het begin van het
11 ;programma moet u een aantal
12 ;parameters definiëren.
13 ;
14 ;
15 BLK FORM 0.1 Z X+0 Y+0 Z-50
16 BLK FORM 0.2  X+100  Y+100  Z+0
17 ;
18 ;Invoer
19 QL1 = 9 ;AANTAL MEETPUNTEN
20 QL2 = 0 ;Z-STARTPUNT VOOR METING
21 QL3 = 0.5 ;Z-REFERENTIEPUNT DAT OP DE LAAGSTE
22 ;         ;POSITIE MOET WORDEN INGESTELD
23 QL4 = 5 ;VEILIGHEIDSAFSTAND
24 QL5 = 0 ;EERSTE REGEL VAN DE TABEL WAARUIT
25 ;       ;WORDT GELEZEN
26 ;
27 ;Gereedschapsoproep taster
28 TOOL CALL 500 Z
29 ;
30 ;Vrijzetten
31 L  Z+100 R0 FMAX
32 ;
33 ;Berekeningen
34 QL11 = QL1 - 1 ;Aantal herhalingen
35 QL42 = 999999999 ;Referentie voor de eerste vergelijking
36 ;
37 ;Tabel openen waarin de meetposities zijn gedefinieerd
38 FN 26: TABOPEN 82051_nl.tab
39 ;
40 ;Lus
41 LBL 1
42 ;
43 ;Coördinaten X en Y uit de tabel lezen
44 FN 28: TABREAD QL30 =QL5 /"X,Y"
45 ;
46 ;Meetpunt benaderen
47 L  X+QL30  Y+QL31 R0 FMAX
48 ;
49 ;Z-coördinaat meten
50 TCH PROBE 427 METEN COORDINATEN ~
    Q263=+QL30 ;1E PUNT 1E AS ~
    Q264=+QL31 ;1E PUNT IN 2E AS ~
    Q261=+QL2  ;MEETHOOGTE ~
    Q320=+QL4  ;VEILIGHEIDSAFSTAND ~
    Q272=+3    ;MEETASSEN ~
    Q267=-1    ;VERPL. RICHTING ~
    Q260=+50   ;VEILIGE HOOGTE ~
    Q281=+0    ;MEETPROTOCOL ~
    Q288=+0    ;MAXIMALE MAAT ~
    Q289=+0    ;MINIMALE MAAT ~
    Q309=+0    ;PGM-STOP BIJ FOUT ~
    Q330=+0    ;GEREEDSCHAP
51 ;
52 ;Vergelijking of het meetresultaat kleiner is dan
53 ;de tot nu toe kleinste waarde
54 FN 12: IF +Q160 LT +QL42 GOTO LBL 2
55 ;
56 ;Sprongmerkteken
57 LBL 3
58 ;
59 QL5 = QL5 + 1 ;Tabelregel verder tellen
60 ;
61 CALL LBL 1 REPQL11 ;Lus herhalen
62 ;
63 ;X/Y-positie vanaf het laagste punt benaderen
64 L  X+QL40  Y+QL41 R0 FMAX
65 ;
66 ;Z-referentiepunt op het laagste punt instellen
67 TCH PROBE 417 NULPUNT IN TS-AS ~
    Q263=+QL40 ;1E PUNT 1E AS ~
    Q264=+QL41 ;1E PUNT IN 2E AS ~
    Q294=+QL42 ;1E MEETPUNT 3E AS ~
    Q320=+QL4  ;VEILIGHEIDSAFSTAND ~
    Q260=+100  ;VEILIGE HOOGTE ~
    Q305=+0    ;NUMMER IN TABEL ~
    Q333=+QL3  ;REFERENTIEPUNT ~
    Q303=+1    ;MEETWAARDE OVERDR.
68 ;
69 ;Referentiepunt activeren
70 CYCL DEF 247 REF.PUNT VASTL. ~
    Q339=+0    ;REF.PUNT-NUMMER
71 ;
72 ;Vrijzetten en programma-einde
73 L  Z+100 R0 FMAX M30
74 ;
75 LBL 2
76 ;Coördinaten voor het laagste punt in flag
77 ;schrijven
78 QL40 = QL30 ;X-coördinaat op het laagste punt
79 QL41 = QL31 ;Y-coördinaat op het laagste punt
80 QL42 = Q160 ;Z-coördinaat op het laagste punt
81 ;Terugsprong naar de lus
82 FN 9: IF +0 EQU +0 GOTO LBL 3
83 END PGM 8205_NL MM