0 BEGIN PGM 82251_NL MM 
1 ;NC-programma om de teller verder te
2 ;rekenen, de actuele tijd uit te lezen
3 ;en met de door u in het programma
4 ;8220_nl.h gedefinieerde tijd te
5 ;vergelijken.
6 ;Als de door u gedefinieerde tijd is
7 ;bereikt of overschreden, dan reset de
8 ;besturing de teller automatisch naar nul.
9 ;
10 ;Waarde in de teller met één verhogen
QR1 = QR1 + 1
11 ;
12 ;Actuele tijd uitlezen en in QS1 opslaan
QS1 = SYSSTR( ID321 NR13 )
13 ;
14 ;Uren uit QS1 scheiden en in QS20 opslaan
QS20 = SUBSTR( SRC_QS1 BEG0 LEN2 )
15 ;
16 ;Minuten uit QS1 scheiden en in QS21 opslaan
QS21 = SUBSTR( SRC_QS1 BEG3 LEN2 )
17 ;
18 ;String in QS20 in aantal converteren en in QL20 opslaan (uren)
QL20 = TONUMB( SRC_QS20 )
19 ;
20 ;String uit QS21 in aantal converteren en in QL21 opslaan (minuten)
QL21 = TONUMB( SRC_QS21 )
21 ;
22 ;Controleren of uren voor het resetten zijn bereikt
23 FN 11: IF +QL20 GT +QR10 GOTO LBL "RESET"
24 FN 12: IF +QL20 LT +QR10 GOTO LBL "NOT_RESET"
25 ;
26 ;Controleren of minuten voor het resetten zijn bereikt
27 FN 12: IF +QL21 LT +QR11 GOTO LBL "NOT_RESET"
28 ;
29 ;Teller resetten
30 LBL "RESET"
QR1 = 0
31 ;
32 STOP
33 LBL "NOT_RESET"
34 END PGM 82251_NL MM