0 BEGIN PGM 8230_NL MM 
1 ;NC-programma om de exacte Z-coördinaat
2 ;te meten bij bewerkingsposities die in
3 ;een puntentabel zijn gedefinieerd en
4 ;deze in de tabel in te voeren. Vervolgens
5 ;wordt de puntentabel als pattern
6 ;gedefinieerd en werkt de besturing op de
7 ;posities een gedefinieerde
8 ;bewerkingscyclus af.
9 ;De in de tabel ingevoerde Z-coördinaat
10 ;definieert het startpunt van de cyclus,
11 ;zodat de in de cyclus gedefinieerde diepte
12 ;altijd is gerelateerd aan de vooraf
13 ;gemeten Zcoördinaat.
14 ;
15 BLK FORM 0.1 Z X-25 Y-25 Z-50
16 BLK FORM 0.2  X+25  Y+25  Z+0
17 ;
18 ;Meten
19 ;Gereedschapsoproep tastsysteem
20 TOOL CALL "TOUCH_PROBE" Z
21 ;
22 ;Tabel openen
23 FN 26: TABOPEN 82301_nl.PNT
24 ;
Q52 = 5 ;AANTAL TE METEN POSITIES
25 CALL LBL "MEASURE" ;Subprogramma-oproep meten
26 ;
27 ;Bewerken
28 ;Gereedschapsoproep boor
29 TOOL CALL "DRILL_D8.5" Z S9000 F2500
30 M3
31 CYCL DEF 200 BOREN ~
   Q200=+2    ;VEILIGHEIDSAFSTAND ~
    Q201=-2    ;DIEPTE ~
    Q206= AUTO ;AANZET DIEPTEVERPL. ~
    Q202=+5    ;DIEPTEVERPLAATSING ~
    Q210=+0    ;STILSTANDSTIJD BOVEN ~
    Q203=+0    ;COORD. OPPERVLAK ~
    Q204=+50   ;2E VEILIGHEIDSAFST. ~
    Q211=+0    ;STILSTANDSTIJD ONDER ~
    Q395=+1    ;REF. DIEPTE
32 SEL PATTERN "82301_nl.PNT"
33 L  X+0  Y+0  Z+50 R0 FMAX
34 CYCL CALL PAT FMAX
35 ;
36 CALL LBL "SAFE" ;Veilige positie benaderen
37 ;
38 ;Programma-einde
39 M30
40 ;
41 ;Subprogramma's
42 ;Veilige positie benaderen
43 LBL "SAFE"
44 M140 MB MAX F9999
45 L  X+0  Y+0 R0 FMAX M91
46 LBL 0
47 ;
48 ;Subprogramma meten
49 LBL "MEASURE"
Q50 = 0 ;Eerste regel
Q51 = Q52 - 1 ;Berekening voor aantal herhalingen
50 LBL "LOOP"
51 ;XY-coördinaten lezen voor meting
52 FN 28: TABREAD Q55 =Q50 /"X,Y"
53 TCH PROBE 427 METEN COORDINATEN ~
   Q263=+Q55  ;1E PUNT 1E AS ~
    Q264=+Q56  ;1E PUNT IN 2E AS ~
    Q261=+0    ;MEETHOOGTE ~
    Q320=+5    ;VEILIGHEIDSAFSTAND ~
    Q272=+3    ;MEETASSEN ~
    Q267=-1    ;VERPL. RICHTING ~
    Q260=+15   ;VEILIGE HOOGTE ~
    Q281=+0    ;MEETPROTOCOL ~
    Q288=+0    ;MAXIMALE MAAT ~
    Q289=+0    ;MINIMALE MAAT ~
    Q309=+0    ;PGM-STOP BIJ FOUT ~
    Q330=+0    ;GEREEDSCHAP ~
    Q498=+0    ;GEREEDSCHAP OMKEREN ~
    Q531=+0    ;INSTELHOEK
54 ;Meetresultaat in Z in het puntenbestand opslaan
55 FN 27: TABWRITE Q50 /"Z" = Q160
Q50 = Q50 + 1 ;Regelnummer verhogen
56 CALL LBL "LOOP" REPQ51
57 LBL 0
58 END PGM 8230_NL MM