0 BEGIN PGM 8235_NL MM 
1 ;NC-programma om de exacte Z-coördinaat te
2 ;meten bij bewerkingsposities die in een
3 ;puntentabel zijn gedefinieerd en deze in
4 ;de tabel in te voeren.
5 ;In dit voorbeeldprogramma voert de besturing
6 ;de meetroutine uit op vijf vlakken van een
7 ;dobbelsteen.
8 ;Vervolgens is voor elke zijde de
9 ;desbetreffende puntentabel als Pattern
10 ;gedefinieerd en werkt de besturing op de
11 ;posities een gedefinieerde bewerkingscyclus
12 ;af.
13 ;De in de tabel ingevoerde Z-coördinaat
14 ;definieert het startpunt van de cyclus, zodat
15 ;de in de cyclus gedefinieerde diepte altijd
16 ;is gerelateerd aan de vooraf gemeten
17 ;Z-coördinaat.
18 ;
19 BLK FORM 0.1 Z X-25 Y-25 Z-50
20 BLK FORM 0.2  X+25  Y+25  Z+0
21 ;
22 ;METEN
23 ;
24 ;Gereedschapsoproep tastsysteem
25 TOOL CALL "TOUCH_PROBE" Z
26 ;
27 ;Zijde 1
28 PLANE RESET STAY ;Zwenken resetten
29 TRANS DATUM AXIS  X+0  Y+0  Z+0 ;Nulpuntverschuiving
30 ;Subprogramma-oproep voor het benaderen van een veilige positie
31 CALL LBL "SAFE"
32 PLANE SPATIAL SPA+0 SPB+0 SPC+0 TURN FMAX ;Bewerkingsvlak zwenken
33 ;
34 ;Puntentabel zijde 1 openen
35 FN 26: TABOPEN 82351.PNT
Q52 = 1 ;AANTAL POSITIES
36 ;Oproep subprogramma voor meten
37 CALL LBL "MEASURE"
38 ;
39 ;Zijde 2
40 PLANE RESET STAY ;Zwenken resetten
41 TRANS DATUM AXIS  X+25  Y-14.1421  Z-10.8579 ;Nulpuntverschuiving
42 ;Subprogramma-oproep voor het benaderen van een veilige positie
43 CALL LBL "SAFE"
44 PLANE SPATIAL SPA+90 SPB+0 SPC+90 TURN FMAX ;Bewerkingsvlak zwenken
45 ;
46 ;Puntentabel zijde 2 openen
47 FN 26: TABOPEN 82352.PNT
Q52 = 2 ;AANTAL POSITIES
48 ;Oproep subprogramma voor meten
49 CALL LBL "MEASURE"
50 ;
51 ;Zijde 3
52 PLANE RESET STAY ;Zwenken resetten
53 TRANS DATUM AXIS  X+14.1421  Y+25  Z-10.8579 ;Nulpuntverschuiving
54 ;Subprogramma-oproep voor het benaderen van een veilige positie
55 CALL LBL "SAFE"
56 PLANE SPATIAL SPA+90 SPB+0 SPC-180 TURN FMAX ;Bewerkingsvlak zwenken
57 ;
58 ;Puntentabel zijde 3 openen
59 FN 26: TABOPEN 82353.PNT
Q52 = 3 ;AANTAL POSITIES
60 ;Oproep subprogramma voor meten
61 CALL LBL "MEASURE"
62 ;
63 ;Zijde 4
64 PLANE RESET STAY ;Zwenken resetten
65 TRANS DATUM AXIS  X-14.1421  Y-25  Z-10.8579 ;Nulpuntverschuiving
66 ;Subprogramma-oproep voor het benaderen van een veilige positie
67 CALL LBL "SAFE"
68 PLANE SPATIAL SPA+90 SPB+0 SPC+0 TURN FMAX ;Bewerkingsvlak zwenken
69 ;
70 ;Puntentabel zijde 4 openen
71 FN 26: TABOPEN 82354.PNT
Q52 = 4 ;AANTAL POSITIES
72 ;Oproep subprogramma voor meten
73 CALL LBL "MEASURE"
74 ;
75 ;Zijde 5
76 PLANE RESET STAY ;Zwenken resetten
77 TRANS DATUM AXIS  X-25  Y+14.1421  Z-10.8579 ;Nulpuntverschuiving
78 ;Subprogramma-oproep voor het benaderen van een veilige positie
79 CALL LBL "SAFE"
80 PLANE SPATIAL SPA+90 SPB+0 SPC-90 TURN FMAX ;Bewerkingsvlak zwenken
81 ;
82 ;PPuntentabel zijde 5 openen
83 FN 26: TABOPEN 82355.PNT
Q52 = 5 ;AANTAL POSITIES
84 ;Oproep subprogramma voor meten
85 CALL LBL "MEASURE"
86 ;
87 ;BEWERKEN
88 ;
89 ;Gereedschapsoproep boor
90 TOOL CALL "DRILL_D8.5" Z S9000 F2500
91 M3
92 CYCL DEF 200 BOREN ~
   Q200=+2    ;VEILIGHEIDSAFSTAND ~
    Q201=-2    ;DIEPTE ~
    Q206= AUTO ;AANZET DIEPTEVERPL. ~
    Q202=+5    ;DIEPTEVERPLAATSING ~
    Q210=+0    ;STILSTANDSTIJD BOVEN ~
    Q203=+0    ;COORD. OPPERVLAK ~
    Q204=+50   ;2E VEILIGHEIDSAFST. ~
    Q211=+0    ;STILSTANDSTIJD ONDER ~
    Q395=+1    ;REF. DIEPTE
93 ;
94 ;Zijde 1
95 PLANE RESET STAY ;Zwenken resetten
96 TRANS DATUM AXIS  X+0  Y+0  Z+0 ;Nulpuntverschuiving
97 ;Subprogramma-oproep voor het benaderen van een veilige positie
98 CALL LBL "SAFE"
99 PLANE SPATIAL SPA+0 SPB+0 SPC+0 TURN FMAX ;Bewerkingsvlak zwenken
100 ;
101 ;Definitie van de puntentabel zijde 1 als puntenpatroon
102 SEL PATTERN "82351.PNT"
103 ;Subprogramma voor bewerking oproepen
104 CALL LBL "MACHINING"
105 ;
106 ;Zijde 2
107 PLANE RESET STAY ;Zwenken resetten
108 TRANS DATUM AXIS  X+25  Y-14.1421  Z-10.8579 ;Nulpuntverschuiving
109 ;Subprogramma-oproep voor het benaderen van een veilige positie
110 CALL LBL "SAFE"
111 PLANE SPATIAL SPA+90 SPB+0 SPC+90 TURN FMAX ;Bewerkingsvlak zwenken
112 ;
113 ;Definitie van de puntentabel zijde 2 als puntenpatroon
114 SEL PATTERN "82352.PNT"
115 ;Subprogramma voor bewerking oproepen
116 CALL LBL "MACHINING"
117 ;
118 ;Zijde 3
119 PLANE RESET STAY ;Zwenken resetten
120 TRANS DATUM AXIS  X+14.1421  Y+25  Z-10.8579 ;Nulpuntverschuiving
121 ;Subprogramma-oproep voor het benaderen van een veilige positie
122 CALL LBL "SAFE"
123 PLANE SPATIAL SPA+90 SPB+0 SPC-180 TURN FMAX ;Bewerkingsvlak zwenken
124 ;
125 ;Definitie van de puntentabel zijde 3 als puntenpatroon
126 SEL PATTERN "82353.PNT"
127 ;Subprogramma voor bewerking oproepen
128 CALL LBL "MACHINING"
129 ;
130 ;Zijde 4
131 PLANE RESET STAY ;Zwenken resetten
132 TRANS DATUM AXIS  X-14.1421  Y-25  Z-10.8579 ;Nulpuntverschuiving
133 ;Subprogramma-oproep voor het benaderen van een veilige positie
134 CALL LBL "SAFE"
135 PLANE SPATIAL SPA+90 SPB+0 SPC+0 TURN FMAX ;Bewerkingsvlak zwenken
136 ;
137 ;Definitie van de puntentabel zijde 4 als puntenpatroon
138 SEL PATTERN "82354.PNT"
139 ;Subprogramma voor bewerking oproepen
140 CALL LBL "MACHINING"
141 ;
142 ;Zijde 5
143 PLANE RESET STAY ;Zwenken resetten
144 ;Nullpunktverschiebung
145 TRANS DATUM AXIS  X-25  Y+14.1421  Z-10.8579 ;Nulpuntverschuiving
146 ;Subprogramma-oproep voor het benaderen van een veilige positie
147 CALL LBL "SAFE"
148 PLANE SPATIAL SPA+90 SPB+0 SPC-90 TURN FMAX ;Bewerkingsvlak zwenken
149 ;
150 ;Definitie van de puntentabel zijde 5 als puntenpatroon
151 SEL PATTERN "82355.PNT"
152 ;Subprogramma voor bewerking oproepen
153 CALL LBL "MACHINING"
154 ;
155 ;Subprogramma-oproep voor het benaderen van een veilige positie
156 CALL LBL "SAFE"
157 PLANE RESET TURN FMAX ;Zwenken resetten
158 ;
159 ;Einde van programma
160 M30
161 ;
162 ;Subprogramma's
163 ;Verplaatsen naar een machine-afhankelijke veilige positie
164 LBL "SAFE"
165 M140 MB MAX F9999
166 L  Z+0 R0 FMAX M91
167 L  X+0  Y+0 R0 FMAX M91
168 LBL 0
169 ;
170 ;Meten
171 LBL "MEASURE"
Q50 = 0 ;Eerste regel
Q51 = Q52 - 1 ;Berekening voor aantal herhalingen
172 LBL "LOOP"
173 ;XY-coördinaten lezen voor meting
174 FN 28: TABREAD Q55 =Q50 /"X,Y"
175 TCH PROBE 427 METEN COORDINATEN ~
    Q263=+Q55  ;1E PUNT 1E AS ~
    Q264=+Q56  ;1E PUNT IN 2E AS ~
    Q261=+0    ;MEETHOOGTE ~
    Q320=+5    ;VEILIGHEIDSAFSTAND ~
    Q272=+3    ;MEETASSEN ~
    Q267=-1    ;VERPL. RICHTING ~
    Q260=+15   ;VEILIGE HOOGTE ~
    Q281=+0    ;MEETPROTOCOL ~
    Q288=+0    ;MAXIMALE MAAT ~
    Q289=+0    ;MINIMALE MAAT ~
    Q309=+0    ;PGM-STOP BIJ FOUT ~
    Q330=+0    ;GEREEDSCHAP ~
    Q498=+0    ;GEREEDSCHAP OMKEREN ~
    Q531=+0    ;INSTELHOEK
176 ;Meetresultaat in Z in het puntenbestand opslaan
177 FN 27: TABWRITE Q50 /"Z" = Q160
Q50 = Q50 + 1 ;Regelnummer verhogen
178 CALL LBL "LOOP" REPQ51
179 LBL 0
180 ;
181 ;Bewerking
182 LBL "MACHINING"
183 L  X+0  Y+0  Z+50 R0 FMAX ;Voorpositioneren
184 CYCL CALL PAT FMAX ;Cyclus op de posities van de puntentabel oproepen
185 LBL 0
186 END PGM 8235_NL MM