0 BEGIN PGM 8245_NL MM 
1 ;NC-programma om correctiewaarden voor
2 ;de optie 3D-ToolComp (optie #92) met
3 ;het tastsysteem te bepalen en in de
4 ;3DTC-tabel op te slaan.
5 ;De tabel dient u vóór het
6 ;programmaverloop aan te maken en het
7 ;aantal benodigde regels moet worden
8 ;ingevoegd. In de kolom Angle
9 ;definieert u de hoekwaarden, waarbij
10 ;de besturing de radius meet.
11 ;Het pad van de tabel moet in de functie
12 ;FN 26 worden gedefinieerd.
13 ;Aan het begin van het programma roept de
14 ;besturing een NC-programma op waarmee
15 ;aan een werkstukkant een radius van
16 ;5 mm wordt gefreesd.
17 ;Vervolgens meet de besturing met
18 ;cyclus 444 punten op de radius.
19 ;Hiertoe leest de besturing de
20 ;gedefinieerde hoek uit de tabel af en
21 ;berekent daaruit de coördinaten en de
22 ;normalen voor de meetpunten.
23 ;Houd er rekening mee dat vóór het
24 ;meten met cyclus 444 het tastsysteem
25 ;met cyclus 460 in 3D moet worden
26 ;gekalibreerd!
27 ;De gemeten correctiewaarde wordt door
28 ;de besturing in de tabel vastgelegd.
29 ;In Block Scan  en in Programmatest
30 ;slaat de besturing het programmadeel
31 ;'meten en schrijven' over om te voorkomen
32 ;dat er verkeerde waarden worden
33 ;vastgelegd.
34 ;Nadat alle punten zijn gemeten en de
35 ;waarden in de tabel zijn vastgelegd,
36 ;springt de besturing naar het
37 ;programma-einde. In het
38 ;voorbeeldprogramma worden hier twee
39 ;andere NC-programma's opgeroepen.
40 ;Allereerst bewerkt de besturing nog
41 ;een stuk met een radius van 5 mm na aan
42 ;de werkstukkant. Hierbij moet erop worden
43 ;gelet dat het nabewerkingsgereedschap aan
44 ;de correctiewaardetabel is toegewezen.
45 ;In het daaropvolgende NC-programma meet
46 ;de besturing opnieuw punten op de radius,
47 ;zodat u aan de hand van het meetprotocol
48 ;kunt controleren of de correctie werkt.
49 ;
50 ;
51 BLK FORM 0.1 Z X-50 Y+0 Z-50
52 BLK FORM 0.2  X+0  Y+50  Z+0
53 ;
54 ;Programma-oproep om de radius te frezen
55 CALL PGM 82451_nl.h
56 ;
57 ;De tabel waarin de meetresultaten
58 ;worden vastgelegd openen
59 FN 26: TABOPEN TNC:\system\3D-ToolComp\TAB_8245.3DTC
60 ;
61 ;Invoerparameters
QL20 = 0 ;EERSTE REGEL VAN DE TABEL
QL21 = 8 ;AANTAL REGELS VAN DE TABEL
QL22 = 5 ;TE METEN RADIUS
QL2 = 3 ;MEETPOSITIE IN DE Y-AS
62 ;Einde parameterinvoer
63 ;
64 ;Berekeningen
QL23 = QL21 - 1 ;Aantal herhalingen
65 ;Einde berekeningen
66 ;
67 ;Bewerkingsvlak zwenken terugzetten
68 PLANE RESET STAY
69 ;Vrijzetten
70 M140 MB MAX
71 ;
72 ;Gereedschapsoproep tastsysteem
73 TOOL CALL "TOUCH_PROBE" Z S11
74 ;
75 ;Bewerkingsvlak zwenken
76 PLANE SPATIAL SPA+0 SPB+0 SPC+0 TURN MB MAX FMAX SEQ-
77 ;
78 ;Voorpositioneren
79 L  X+0  Y+0 R0 FMAX
80 L  Z+25 R0 FMAX
81 ;
82 ;Herhaling
83 LBL "REPETITION"
84 ;Oproep subprogramma CALC
85 CALL LBL "CALC"
86 ;Oproep subprogramma PROBE
87 CALL LBL "PROBE"
88 ;Oproep herhaling
89 CALL LBL "REPETITION" REPQL23
90 ;
91 ;Sprong naar programma-einde
92 FN 9: IF +0 EQU +0 GOTO LBL "End"
93 ;
94 ;Subprogramma meten
95 LBL "PROBE"
96 FN 18: SYSREAD QL40 = ID992 NR10 ;Controleren of de regelsprong actief is
97 FN 9: IF +QL40 EQU +1 GOTO LBL "JUMP" ;Indien de regelsprong actief is, de sprong uitvoeren
98 FN 18: SYSREAD QL41 = ID992 NR16 ;Controleren of simulatie actief is
99 FN 9: IF +QL41 EQU +0 GOTO LBL "JUMP" ;Indien de simulatie actief is, sprong uitvoeren
100 TCH PROBE 444 TASTEN 3D ~
   Q263=+QL1  ;1E PUNT 1E AS ~
    Q264=+QL2  ;1E PUNT IN 2E AS ~
    Q294=+QL3  ;1E MEETPUNT 3E AS ~
    Q581=+QL11 ;NORMALEN HOOFDAS ~
    Q582=+QL12 ;NORMALEN NEVENAS ~
    Q583=+QL13 ;NORMALEN GS-AS ~
    Q320=+2    ;VEILIGHEIDSAFSTAND ~
    Q260=+25   ;VEILIGE HOOGTE ~
    QS400="0.015-0.015" ;TOLERANTIE ~
    Q309=+0    ;FOUTREACTIE
QL50 = - Q164 ;Meetresultaat in correctiewaarde omzetten
101 FN 27: TABWRITE QL20 /"DR2" = QL50 ;Correctiewaarde in tabel vastleggen
QL20 = QL20 + 1 ;Nummer van de regel verder rekenen
102 ;Spronglabel voor het overslaan van de meting
103 LBL "JUMP"
104 LBL 0
105 ;Subprogramma berekenen
106 LBL "CALC"
107 FN 28: TABREAD QL60 =QL20 /"ANGLE" ;Hoek uit tabel lezen
QL61 = ( SIN QL60 ) * QL22 ;X-coördinaat van het punt berekenen
QL1 = - QL22 + QL61 ;X-coördinaat van het punt berekenen
QL62 = COS QL60 * QL22 ;Z-coördinaat van het punt berekenen
QL3 = - QL22 + QL62 ;Z-coördinaat van het punt berekenen
QL11 = SIN QL60 * 1 ;Normale in de hoofdas berekenen
QL12 = 0 ;Normale van de nevenas definiëren
QL13 = COS QL60 * 1 ;Normale van de gereedschapsas berekenen
108 LBL 0
109 ;
110 ;Einde van programma
111 LBL "End"
112 ;NC-programma voor gecorrigeerd vlak oproepen
113 CALL PGM 82452_nl.h
114 ;NC-programma voor meting oproepen
115 CALL PGM 82453_nl.h
116 M129 M9
117 M30
118 END PGM 8245_NL MM