0 BEGIN PGM 9035_nl MM 
1 ;NC-programma om de bestandsnaam
2 ;automatisch tebepalen en met behulp van
3 ;een cyclus in het werkstuk te graveren.
4 ;De besturing roept een maskerbestand op.
5 ;Dit schrijft het bestandspad in een
6 ;tekstbestand.
7 ;Vervolgens roept de besturing een
8 ;programma op waarmee uit het bestandspad
9 ;de programmanaam wordt geselecteerd. De
10 ;bestandsnaam wordt door de besturing in
11 ;QS1 opgeslagen. Deze neemt de besturing
12 ;over bij het terugspringen in dit
13 ;programma en gebruikt de naam in de
14 ;graveercyclus 225.
15 ;Wanneer de drie gebruikte bestanden niet
16 ;in dezelfde directory staan, moet u de
17 ;padopgaven in oproepen aanpassen!
18 ;BELANGRIJK! Het programma draait niet in
19 ;de programmatest, omdat daar het kopiëren
20 ;van een tekstbestand in een NC-programma
21 ;niet is toegestaan!
22 ;
23 BLK FORM 0.1 Z  X+0  Y+0  Z-20
24 BLK FORM 0.2  X+100  Y+100  Z+0
25 ;
26 ;Gereedschapsoproep graveergereedschap
27 TOOL CALL 151 Z S6000
28 M3
29 ;
30 L  Z+100 R0 FMAX
31 ;
32 ;Inhoud van het bestand "mask" in het
33 ;bestand "File" schrijven. Daarbij wordt
34 ;door de syntaxis van de programmanaam
35 ;ingevoerd.
36 FN 16: F-PRINT mask.a / FILE.a
37 ;
38 ;Programma voor het vormen van de
39 ;tekststrings oproepen
40 CALL PGM 90351_nl.H
41 ;
42 ;
43 ;Bestandsnaam graveren die in QS1 staat
44 CYCL DEF 225 GRAVEREN ~
   QS500= QS1     ;GRAVEERTEKST ~
    Q513=+10   ;TEKENHOOGTE ~
    Q514=+0    ;FACTOR AFSTAND ~
    Q515=+0    ;LETTERTYPE ~
    Q516=+0    ;TEKSTLAY-OUT ~
    Q374=+0    ;ROTATIEPOSITIE ~
    Q517=+50   ;CIRKELRADIUS ~
    Q207=+500  ;AANZET FREZEN ~
    Q201=-0.3  ;DIEPTE ~
    Q206=+150  ;AANZET DIEPTEVERPL. ~
    Q200=+2    ;VEILIGHEIDSAFSTAND ~
    Q203=+0    ;COORD. OPPERVLAK ~
    Q204=+50   ;2E VEILIGHEIDSAFST.
45 ;
46 ;Cyclus bij startpunt oproepen
47 L  X+20  Y+40 R0 FMAX M99
48 ;
49 ;Vrijzetten
50 L  Z+100 R0 FMAX
51 ;
52 ;Einde van programma
53 M30
54 END PGM 9035_nl MM